IBPSA

Author: Kodsgr

BuildSysPro/IBPSA/Airflow/Multizone/BaseClasses/Door.mo

@@ -0,0 +1,127 @@
+within BuildSysPro.IBPSA.Airflow.Multizone.BaseClasses;
+partial model Door
+  "Partial door model for bi-directional flow"
+  extends IBPSA.Fluid.Interfaces.PartialFourPortInterface(
+    redeclare final package Medium1 = Medium,
+    redeclare final package Medium2 = Medium,
+    final allowFlowReversal1=true,
+    final allowFlowReversal2=true,
+    final m1_flow_nominal=10/3600*1.2,
+    final m2_flow_nominal=m1_flow_nominal,
+    final m1_flow_small=1E-4*abs(m1_flow_nominal),
+    final m2_flow_small=1E-4*abs(m2_flow_nominal));
+
+  replaceable package Medium =
+    Modelica.Media.Interfaces.PartialMedium "Medium in the component"
+      annotation (choices(
+        choice(redeclare package Medium = IBPSA.Media.Air "Moist air")));
+
+  parameter Modelica.Units.SI.Length wOpe=0.9 "Width of opening"
+    annotation (Dialog(group="Geometry"));
+  parameter Modelica.Units.SI.Length hOpe=2.1 "Height of opening"
+    annotation (Dialog(group="Geometry"));
+
+  parameter Modelica.Units.SI.PressureDifference dp_turbulent(
+    min=0,
+    displayUnit="Pa") = 0.01
+    "Pressure difference where laminar and turbulent flow relation coincide"
+    annotation (Dialog(tab="Advanced"));
+
+  Modelica.Units.SI.VolumeFlowRate VAB_flow(nominal=0.001)
+    "Volume flow rate from A to B if positive";
+  Modelica.Units.SI.VolumeFlowRate VBA_flow(nominal=0.001)
+    "Volume flow rate from B to A if positive";
+
+  input Modelica.Units.SI.Velocity vAB(nominal=0.01)
+    "Average velocity from A to B";
+  input Modelica.Units.SI.Velocity vBA(nominal=0.01)
+    "Average velocity from B to A";
+
+protected
+  final parameter Modelica.Units.SI.Area AOpe=wOpe*hOpe "Open aperture area";
+
+  constant Real conTP=IBPSA.Media.Air.dStp  *Modelica.Media.IdealGases.Common.SingleGasesData.Air.R_s
+    "Conversion factor for converting temperature difference to pressure difference";
+
+  parameter Medium.ThermodynamicState sta_default=Medium.setState_pTX(
+      T=Medium.T_default,
+      p=Medium.p_default,
+      X=Medium.X_default);
+
+  parameter Modelica.Units.SI.Density rho_default=Medium.density(sta_default)
+    "Density";
+
+  Modelica.Units.SI.VolumeFlowRate VABp_flow(nominal=0.001)
+    "Volume flow rate from A to B if positive due to static pressure difference";
+  Modelica.Units.SI.MassFlowRate mABt_flow(nominal=0.001)
+    "Mass flow rate from A to B if positive due to buoyancy";
+
+equation
+  // Net flow rate
+  port_a1.m_flow = (rho_default * VABp_flow/2 + mABt_flow);
+  port_b2.m_flow = (rho_default * VABp_flow/2 - mABt_flow);
+
+  // Average velocity (using the whole orifice area)
+  VAB_flow = (max(port_a1.m_flow, 0) + max(port_b2.m_flow, 0))/rho_default;
+  VBA_flow = (max(port_a2.m_flow, 0) + max(port_b1.m_flow, 0))/rho_default;
+
+  // Energy balance (no storage, no heat loss/gain)
+  port_a1.h_outflow = inStream(port_b1.h_outflow);
+  port_b1.h_outflow = inStream(port_a1.h_outflow);
+  port_a2.h_outflow = inStream(port_b2.h_outflow);
+  port_b2.h_outflow = inStream(port_a2.h_outflow);
+
+  // Mass balance (no storage)
+  port_a1.m_flow = -port_b1.m_flow;
+  port_a2.m_flow = -port_b2.m_flow;
+
+  port_a1.Xi_outflow = inStream(port_b1.Xi_outflow);
+  port_b1.Xi_outflow = inStream(port_a1.Xi_outflow);
+  port_a2.Xi_outflow = inStream(port_b2.Xi_outflow);
+  port_b2.Xi_outflow = inStream(port_a2.Xi_outflow);
+
+  // Transport of trace substances
+  port_a1.C_outflow = inStream(port_b1.C_outflow);
+  port_b1.C_outflow = inStream(port_a1.C_outflow);
+  port_a2.C_outflow = inStream(port_b2.C_outflow);
+  port_b2.C_outflow = inStream(port_a2.C_outflow);
+
+  annotation (
+    Icon(graphics={
+        Rectangle(
+          extent={{-60,80},{60,-84}},
+          lineColor={0,0,255},
+          pattern=LinePattern.None,
+          fillColor={85,75,55},
+          fillPattern=FillPattern.Solid),
+        Rectangle(
+          extent={{-54,72},{56,-84}},
+          lineColor={0,0,0},
+          fillColor={215,215,215},
+          fillPattern=FillPattern.Solid),
+        Polygon(
+          points={{56,72},{-36,66},{-36,-90},{56,-84},{56,72}},
+          lineColor={0,0,0},
+          fillColor={95,95,95},
+          fillPattern=FillPattern.Solid),
+        Polygon(
+          points={{-30,-10},{-16,-8},{-16,-14},{-30,-16},{-30,-10}},
+          lineColor={0,0,255},
+          pattern=LinePattern.None,
+          fillColor={0,0,0},
+          fillPattern=FillPattern.Solid)}),
+    Documentation(info="<html>
+<p>
+This is a partial model for the bi-directional air flow through a door.
+</p>
+</html>",
+revisions="<html>
+<ul>
+<li>
+October 6, 2020, by Michael Wetter:<br/>
+First implementation for
+<a href=\"https://github.com/ibpsa/modelica-ibpsa/issues/1353\">#1353</a>.
+</li>
+</ul>
+</html>"));
+end Door;

BuildSysPro/IBPSA/Airflow/Multizone/BaseClasses/DoorDiscretized.mo

@@ -0,0 +1,174 @@
+within BuildSysPro.IBPSA.Airflow.Multizone.BaseClasses;
+partial model DoorDiscretized
+  "Door model using discretization along height coordinate"
+  extends
+    IBPSA.Airflow.Multizone.BaseClasses.TwoWayFlowElementBuoyancy;
+
+  parameter Integer nCom=10 "Number of compartments for the discretization";
+
+  parameter Modelica.Units.SI.PressureDifference dp_turbulent(
+    min=0,
+    displayUnit="Pa") = 0.01
+    "Pressure difference where laminar and turbulent flow relation coincide. Recommended: 0.01";
+
+  Modelica.Units.SI.PressureDifference dpAB[nCom](each nominal=1)
+    "Pressure difference between compartments";
+  Modelica.Units.SI.Velocity v[nCom](each nominal=0.01)
+    "Velocity in compartment from A to B";
+  Modelica.Units.SI.Velocity vTop "Velocity at top of opening from A to B";
+  Modelica.Units.SI.Velocity vBot "Velocity at bottom of opening from A to B";
+
+protected
+  parameter Modelica.Units.SI.Length dh=hOpe/nCom "Height of each compartment";
+
+  parameter Medium.ThermodynamicState sta_default=Medium.setState_pTX(
+      T=Medium.T_default,
+      p=Medium.p_default,
+      X=Medium.X_default);
+
+  parameter Modelica.Units.SI.Density rho_default=Medium.density(sta_default)
+    "Density, used to compute fluid volume";
+
+  parameter Real hAg[nCom](each unit="m2/s2")=
+    {Modelica.Constants.g_n*(hA - (i - 0.5)*dh) for i in 1:nCom}
+    "Product g*h_i for each compartment";
+
+  parameter Real hBg[nCom](each unit="m2/s2")=
+    {Modelica.Constants.g_n*(hB - (i - 0.5)*dh) for i in 1:nCom}
+    "Product g*h_i for each compartment";
+  Modelica.Units.SI.AbsolutePressure pA[nCom](each nominal=101325)
+    "Pressure in compartments of room A";
+  Modelica.Units.SI.AbsolutePressure pB[nCom](each nominal=101325)
+    "Pressure in compartments of room B";
+
+  Modelica.Units.SI.VolumeFlowRate dV_flow[nCom]
+    "Volume flow rate through compartment from A to B";
+  Modelica.Units.SI.VolumeFlowRate dVAB_flow[nCom]
+    "Volume flow rate through compartment from A to B if positive";
+  Modelica.Units.SI.VolumeFlowRate dVBA_flow[nCom]
+    "Volume flow rate through compartment from B to A if positive";
+  Modelica.Units.SI.VolumeFlowRate VZerCom_flow=VZer_flow/nCom
+    "Small flow rate for regularization";
+
+  Real m(min=0.5, max=1) "Flow exponent, m=0.5 for turbulent, m=1 for laminar";
+  Real CVal "Flow coefficient for each compartment, C = V_flow/ dp^m";
+  Modelica.Units.SI.Area dA "Compartment area";
+  Real gaiFlo[nCom] "Gain to sum up the positive flows and set the negative to zero in a differentiable way";
+equation
+  dA = A/nCom;
+
+  for i in 1:nCom loop
+    // pressure drop in each compartment
+    pA[i] = port_a1.p + rho_a1_inflow*hAg[i];
+    pB[i] = port_a2.p + rho_a2_inflow*hBg[i];
+    dpAB[i] = pA[i] - pB[i];
+    v[i] = dV_flow[i]/dA;
+    // assignment of net volume flows
+    gaiFlo[i] = IBPSA.Utilities.Math.Functions.smoothHeaviside(x=dV_flow[i],
+      delta=VZerCom_flow);
+    dVAB_flow[i] =  dV_flow[i] * gaiFlo[i];
+    dVBA_flow[i] = -dV_flow[i] * (1-gaiFlo[i]);
+  end for;
+  // add positive and negative flows
+  VAB_flow = sum(dVAB_flow);
+  VBA_flow = sum(dVBA_flow);
+  vTop = v[nCom];
+  vBot = v[1];
+  annotation (
+    Icon(graphics={
+        Rectangle(
+          extent={{-60,80},{60,-84}},
+          lineColor={0,0,255},
+          pattern=LinePattern.None,
+          fillColor={85,75,55},
+          fillPattern=FillPattern.Solid),
+        Rectangle(
+          extent={{-54,72},{56,-84}},
+          lineColor={0,0,0},
+          fillColor={215,215,215},
+          fillPattern=FillPattern.Solid),
+        Polygon(
+          points={{56,72},{-36,66},{-36,-90},{56,-84},{56,72}},
+          lineColor={0,0,0},
+          fillColor={95,95,95},
+          fillPattern=FillPattern.Solid),
+        Polygon(
+          points={{-30,-10},{-16,-8},{-16,-14},{-30,-16},{-30,-10}},
+          lineColor={0,0,255},
+          pattern=LinePattern.None,
+          fillColor={0,0,0},
+          fillPattern=FillPattern.Solid),
+        Line(points={{-54,48},{-36,48}}, color={0,0,0}),
+        Line(points={{-54,20},{-36,20}}, color={0,0,0}),
+        Line(points={{-54,-6},{-36,-6}}, color={0,0,0}),
+        Line(points={{-54,-58},{-36,-58}}, color={0,0,0}),
+        Line(points={{-54,-32},{-36,-32}}, color={0,0,0})}),
+    Documentation(info="<html>
+<p>
+This is a partial model for the bi-directional air flow through a door.
+</p>
+<p>
+To compute the bi-directional flow,
+the door is discretize along the height coordinate, and uses
+an orifice equation to compute the flow for each compartment.
+</p>
+<p>
+The compartment area <code>dA</code> is a variable, which allows
+using the model for a door that can be open or closed.
+</p>
+</html>",
+revisions="<html>
+<ul>
+<li>
+January 8, 2019, by Michael Wetter:<br/>
+Moved parameter <code>CD</code> from
+<a href=\"modelica://BuildSysPro.IBPSA.Airflow.Multizone.BaseClasses.DoorDiscretized\">
+IBPSA.Airflow.Multizone.BaseClasses.DoorDiscretized</a>
+to
+<a href=\"modelica://BuildSysPro.IBPSA.Airflow.Multizone.DoorDiscretizedOpen\">
+IBPSA.Airflow.Multizone.DoorDiscretizedOpen</a>.<br/>
+This is for
+<a href=\"https://github.com/ibpsa/modelica-ibpsa/issues/971\">#971</a>.
+</li>
+<li>
+June 27, 2018, by Michael Wetter:<br/>
+Corrected old parameter annotation.
+</li>
+<li>
+June 6, 2018, by Michael Wetter:<br/>
+Removed term that assures non-zero flow rate in each path, and
+reformulated flow balance to ensure that model is symmetric.
+This is
+for <a href=\"https://github.com/ibpsa/modelica-ibpsa/issues/937\">#937</a>.
+</li>
+<li>
+January 22, 2016, by Michael Wetter:<br/>
+Corrected type declaration of pressure difference.
+This is
+for <a href=\"https://github.com/ibpsa/modelica-ibpsa/issues/404\">#404</a>.
+</li>
+<li>
+September 26, 2013 by Michael Wetter:<br/>
+Added missing <code>each</code> keyword.
+</li>
+<li>
+December 14, 2012 by Michael Wetter:<br/>
+Renamed protected parameters for consistency with the naming conventions.
+</li>
+<li><i>December 6, 2011</i> by Michael Wetter:<br/>
+       Removed protected variable <code>rhoAve</code>.
+</li>
+<li><i>August 12, 2011</i> by Michael Wetter:<br/>
+       Changed model to use the new function
+       <a href=\"modelica://BuildSysPro.IBPSA.Airflow.Multizone.BaseClasses.powerLawFixedM\">
+       Buildings.Airflow.Multizone.BaseClasses.powerLawFixedM</a>.
+</li>
+<li><i>July 20, 2010</i> by Michael Wetter:<br/>
+       Migrated model to Modelica 3.1 and integrated it into the Buildings library.
+</li>
+<li><i>February 8, 2005</i> by Michael Wetter:<br/>
+       Released first version.
+</li>
+</ul>
+</html>"));
+end DoorDiscretized;

BuildSysPro/IBPSA/Airflow/Multizone/BaseClasses/ErrorControl.mo

@@ -0,0 +1,44 @@
+within BuildSysPro.IBPSA.Airflow.Multizone.BaseClasses;
+model ErrorControl "Interface that defines parameters for error control"
+  parameter Boolean forceErrorControlOnFlow = true
+    "Flag to force error control on m_flow. Set to true if interested in flow rate"
+    annotation(Dialog(tab="Advanced"));
+
+  annotation (Documentation(info="<html>
+<p>
+This is an interface that defines parameters used for error control.
+</p>
+<p>
+Dymola does error control on state variables, such as temperature, pressure and
+species concentration.
+Flow variables such as <code>m_flow</code> are typically not checked during the error control.
+This can give large errors in flow variables, as long as the error on the volume's state variables
+that are coupled to the flow variables is small.
+Obtaining accurate flow variables can be achieved by imposing an error control
+on the exchanged mass, which can be defined as
+</p>
+<pre>
+  dm/dt = m_flow.
+</pre>
+<p>
+By setting <code>forceErrorControlOnFlow = true</code>, such an equation is imposed
+by models that extend this class.
+</p>
+</html>",
+revisions="<html>
+<ul>
+<li>
+June 27, 2018, by Michael Wetter:<br/>
+Moved parameter <code>forceErrorControlOnFlow</code> to the Advanced tab.
+</li>
+<li>
+July 20, 2010 by Michael Wetter:<br/>
+Integrated model into the Buildings library.
+</li>
+<li>
+November 1, 2005 by Michael Wetter:<br/>
+Released first version.
+</li>
+</ul>
+</html>"));
+end ErrorControl;