flake.nix

{
  description = "Terminal-based Sefaria query tool";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    flake-compat = {
      url = "github:edolstra/flake-compat";
      flake = false;
    };
  };

  outputs =
    inputs:
    let
      forEachSystem =
        f:
        inputs.nixpkgs.lib.genAttrs [
          "x86_64-linux"
          "x86_64-darwin"
          "aarch64-linux"
          "aarch64-darwin"
        ] (system: f (import inputs.nixpkgs { inherit system; }));
    in
    {
      packages = forEachSystem (pkgs: {
        default = pkgs.callPackage (
          {
            lib,
            openssl,
            pkg-config,
            rustPlatform,
          }:
          let
            manifest = (lib.importTOML ./Cargo.toml).package;
          in
          rustPlatform.buildRustPackage {
            pname = manifest.name;
            inherit (manifest) version;
            src = lib.cleanSource ./.;
            cargoLock.lockFile = ./Cargo.lock;
            nativeBuildInputs = [ pkg-config ];
            buildInputs = [ openssl ];
          }
        ) { };
      });
      devShells = forEachSystem (pkgs: {
        default = pkgs.callPackage (
          {
            cargo,
            clippy,
            mkShellNoCC,
            rust-analyzer,
            rustc,
            rustfmt,
            rustPlatform,
          }:
          mkShellNoCC {
            packages = [
              cargo
              clippy
              rust-analyzer
              rustc
              rustfmt
            ];
            RUST_SRC_PATH = "${rustPlatform.rustLibSrc}";
          }
        ) { };
      });
    };
}