Matcher-old/build.gradle at master · FabricMC/Matcher-old · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
plugins {
    id 'java'
	id 'application'
	id 'maven-publish'
    id 'com.github.johnrengelman.shadow' version '7.0.0'
	id 'org.openjfx.javafxplugin' version '0.0.10'
	id 'de.jjohannes.extra-java-module-info' version '0.5'
}

repositories {
    mavenCentral()
    maven {
        name "Fabric"
        url 'https://maven.fabricmc.net/'
    }
}

archivesBaseName = 'matcher'
group = 'net.fabricmc'

sourceSets {
    main {
        java.srcDirs = ['src']
		resources.srcDirs = ['res']
    }
}

javafx {
	version = "11.0.2"
	modules = [ 'javafx.controls', 'javafx.web' ]
}

java {
	sourceCompatibility = JavaVersion.VERSION_11
	targetCompatibility = JavaVersion.VERSION_11

	if (!JavaVersion.current().isCompatibleWith(JavaVersion.VERSION_11)) {
		toolchain {
			languageVersion = JavaLanguageVersion.of(11)
		}
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = "UTF-8"
	it.options.release = 11
}

dependencies {
    implementation "com.github.javaparser:javaparser-core:3.8.3"
	implementation "org.bitbucket.mstrobel:procyon-compilertools:0.5.33.6"
	implementation "org.ow2.asm:asm:9.1"
	implementation "org.ow2.asm:asm-commons:9.1"
	implementation "org.ow2.asm:asm-tree:9.1"
	implementation "org.ow2.asm:asm-util:9.1"
	implementation "org.benf:cfr:0.151"
	implementation "net.fabricmc:fabric-fernflower:1.3.0"
}

extraJavaModuleInfo {
	automaticModule("cfr-0.151.jar", "cfr")
	automaticModule("procyon-compilertools-0.5.33.6.jar", "procyon.compilertools")
	automaticModule("procyon-core-0.5.33.6.jar", "procyon.core")
	automaticModule("fabric-fernflower-1.3.0.jar", "intellij.fernflower")
}

application {
	mainModule = 'matcher'
	mainClass = 'matcher.Main'
}

build.dependsOn(shadowJar)

publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
		}
	}
}