Add maven publish task

Author: frankfliu

gradle.properties

@@ -1,2 +1,8 @@
 org.gradle.daemon=true
 org.gradle.jvmargs=-Xmx1024M
+
+systemProp.org.gradle.internal.http.socketTimeout=120000
+systemProp.org.gradle.internal.http.connectionTimeout=60000
+
+# FIXME: Workaround gradle publish issue: https://github.com/gradle/gradle/issues/11308
+systemProp.org.gradle.internal.publish.checksums.insecure=true

jsr381/build.gradle

@@ -1,9 +1,12 @@
 plugins {
     id "java-library"
+    id "maven-publish"
+    id "signing"
 }
 
 group "ai.djl.jsr381"
-version "0.3.0"
+boolean isRelease = project.hasProperty("release") || project.hasProperty("staging")
+version = "0.3.0" + (isRelease ? "" : "-SNAPSHOT")
 
 dependencies {
     api "javax.visrec:visrec-api:1.0-SNAPSHOT"
@@ -21,9 +24,95 @@ dependencies {
     }
 }
 
+java {
+    withJavadocJar()
+    withSourcesJar()
+}
+
 test {
     // Use TestNG for unit tests
     useTestNG()
 }
 
 apply from: file("${rootProject.projectDir}/tools/gradle/formatter.gradle")
+
+project.tasks.withType(GenerateModuleMetadata) {
+    enabled = false
+}
+
+signing {
+    required(project.hasProperty("staging") || project.hasProperty("snapshot"))
+    def signingKey = findProperty("signingKey")
+    def signingPassword = findProperty("signingPassword")
+    useInMemoryPgpKeys(signingKey, signingPassword)
+    sign publishing.publications
+}
+
+if (JavaVersion.current() != JavaVersion.VERSION_1_8) {
+    if (gradle.startParameter.taskNames.contains("publish")) {
+        throw new GradleException("JDK 1.8 is required to run publish task.")
+    }
+    return
+}
+
+publishing {
+    publications {
+        maven(MavenPublication) {
+            from components.java
+            artifacts = [jar, javadocJar, sourcesJar]
+            pom {
+                name = "Deep Java Library implementation of JSR-381"
+                description = "Deep Java Library implementation of JSR-381"
+                url = "http://www.djl.ai/"
+
+                packaging = "jar"
+
+                licenses {
+                    license {
+                        name = 'The Apache License, Version 2.0'
+                        url = 'https://www.apache.org/licenses/LICENSE-2.0'
+                    }
+                }
+
+                scm {
+                    connection = "scm:git:[email protected]:awslabs/djl.git"
+                    developerConnection = "scm:git:[email protected]:awslabs/djl.git"
+                    url = "https://github.com/awslabs/djl"
+                    tag = "HEAD"
+                }
+
+                developers {
+                    developer {
+                        name = "DJL.AI Team"
+                        email = "[email protected]"
+                        organization = "Amazon AI"
+                        organizationUrl = "https://amazon.com"
+                    }
+                }
+            }
+        }
+    }
+
+    repositories {
+        maven {
+            if (project.hasProperty("snapshot")) {
+                name = "snapshot"
+                url = "https://oss.sonatype.org/content/repositories/snapshots/"
+                credentials {
+                    username = findProperty("ossrhUsername")
+                    password = findProperty("ossrhPassword")
+                }
+            } else if (project.hasProperty("staging")) {
+                name = "staging"
+                url = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
+                credentials {
+                    username = findProperty("ossrhUsername")
+                    password = findProperty("ossrhPassword")
+                }
+            } else {
+                name = "local"
+                url = "build/repo"
+            }
+        }
+    }
+}

settings.gradle

@@ -1,2 +1 @@
-rootProject.name = "visrec"
 include "jsr381", "examples"