Initial commit: div. It works.

Author: Julian

Diff for: .travis.yml

@@ -0,0 +1,4 @@
+language: ruby
+rvm:
+  - 1.9.3
+script: rake ci

Diff for: COPYING

@@ -0,0 +1,19 @@
+Copyright (c) 2013 Julian Berman
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in
+all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
+THE SOFTWARE.

Diff for: Gemfile

@@ -0,0 +1,3 @@
+source 'https://rubygems.org'
+
+gem 'vim-flavor', '~> 1.1'

Diff for: README.md

@@ -0,0 +1,26 @@
+# vim-textobj-variable-segment
+
+A vim plugin providing a single text object (on `iv`) for
+variable segments. A variable segment is defined to be a substring in
+an identifier followed by an underscore for snake cased variables or a
+substring in an identifier followed by an uppercase character for camel
+cased variables.
+
+E.g.:
+
+    foo_ba|r_baz   -> div -> foo_baz
+    QU|UX_SPAM     -> div -> SPAM
+    eggsAn|dCheese -> div -> eggsCheese
+    _privat|e_quux -> div -> _quux
+
+It will also preserve case for small camels when initial segments are deleted:
+
+    _g|etJiggyYo   -> div -> _jiggyYo
+
+
+`av` right now does the same thing as `iv`, but if you have ideas for how it
+should differ feel free to open a ticket (with a most welcome Pull Request if
+possible :D ).
+
+
+Requires [vim-textobj-user](https://github.com/kana/vim-textobj-user).

Diff for: Rakefile

@@ -0,0 +1,11 @@
+#!/usr/bin/env rake
+
+task :ci => [:dump, :test]
+
+task :dump do
+  sh 'vim --version'
+end
+
+task :test do
+  sh 'bundle exec vim-flavor test'
+end

Diff for: VimFlavor

@@ -0,0 +1 @@
+flavor 'kana/vim-textobj-user', '~> 0.3'

Diff for: plugin/textobj/variable-segment.vim

@@ -0,0 +1,63 @@
+" textobj-variable-segment: a text object for segments of variable names
+" Author: Julian Berman
+" Version: 0.1.0
+
+if exists('g:loaded_textobj_variable_segment')
+    finish
+endif
+
+call textobj#user#plugin('variable', {
+    \ '-': {
+    \     '*sfile*': expand('<sfile>:p'),
+    \     'select-a': 'av',  '*select-a-function*': 's:select_a',
+    \     'select-i': 'iv',  '*select-i-function*': 's:select_i',
+    \ }})
+
+function! s:select(object_type)
+    let variable = expand('<cword>')
+
+    if variable =~# '\i_\i'
+        let [left_boundary, right_boundary] = ['_\i', '_']
+        let was_small_camel = 0
+    else
+        let [left_boundary, right_boundary] = ['_\i\|\u', '\i\u']
+        let was_small_camel = match(variable, '^_*\l') != -1
+    endif
+
+    call search(left_boundary . '\|\<', 'bce')
+    let start_position = getpos('.')
+
+    call search(right_boundary . '\|\i\>', 'c')
+    let end_position = getpos('.')
+
+    call search('\i\>', 'c')
+    if end_position == getpos('.')
+        if getline(start_position[1])[start_position[2] - 2] =~# '_'
+            let start_position[2] -= 1
+        endif
+    endif
+
+    if was_small_camel
+        let [_, line_number, column, _] = start_position
+
+        call search('\<', 'bc')
+        let [_, _, word_start, _] = getpos('.')
+
+        if column - 2 <= word_start || getline(line_number)[:column - 2] =~# '^_*$'
+            call setpos('.', end_position)
+            normal! l~
+        endif
+    endif
+
+    return ['v', start_position, end_position]
+endfunction
+
+function! s:select_a()
+    return s:select('a')
+endfunction
+
+function! s:select_i()
+    return s:select('i')
+endfunction
+
+let g:loaded_textobj_variable_segment = 1

Diff for: t/variable-segment.vim

@@ -0,0 +1,158 @@
+filetype plugin on
+runtime! plugin/textobj/variable-segment.vim
+
+
+describe 'snake case' 
+    after
+        bwipeout!
+    end
+
+    it 'selects between underscores'
+        put! = 'foo_bar_baz'
+        normal! 6|
+        normal div
+        Expect getline(1) == 'foo_baz'
+    end
+
+    it 'selects leading sections'
+        put! = 'BAG_OF_SPAM'
+        normal! 2|
+        normal div
+        Expect getline(1) == 'OF_SPAM'
+    end
+
+    it 'selects ending sections'
+        put! = 'BAG_OF_SPAM'
+        normal! 9|
+        normal div
+        Expect getline(1) == 'BAG_OF'
+    end
+
+    it 'ignores leading underscores'
+        put! = '_SPAM_EGGS'
+        normal! 3|
+        normal div
+        Expect getline(1) == '_EGGS'
+    end
+
+    it 'can match on the left boundary'
+        put! = 'hello_world'
+        normal! 0
+        normal div
+        Expect getline(1) == 'world'
+    end
+
+    it 'can match on the right boundary'
+        put! = 'hello_world'
+        normal! $
+        normal div
+        Expect getline(1) == 'hello'
+    end
+
+    it 'does not cross left word boundaries'
+        put! = 'foo_bar baz_quux'
+        normal! 10|
+        normal div
+        Expect getline(1) == 'foo_bar quux'
+    end
+
+    it 'does not cross right word boundaries'
+        put! = 'foo_bar baz_quux'
+        normal! 6|
+        normal div
+        Expect getline(1) == 'foo baz_quux'
+    end
+
+    it 'can match on the underscore'
+    end
+end
+
+
+describe 'camel case' 
+    after
+        bwipeout!
+    end
+
+    it 'selects between small camels'
+        put! = 'eggsAndCheese'
+        normal! 6|
+        normal div
+        Expect getline(1) == 'eggsCheese'
+    end
+
+    it 'selects leading small camels and swaps case'
+        put! = 'greatQuuxThings'
+        normal! 3|
+        normal div
+        Expect getline(1) == 'quuxThings'
+    end
+
+    it 'selects leading small camels and swaps case even with underscores'
+        put! = '_greatQuuxThings'
+        normal! 3|
+        normal div
+        Expect getline(1) == '_quuxThings'
+    end
+
+    it 'selects leading large camels and preserves case'
+        put! = '_ThingDoer'
+        normal! 3|
+        normal div
+        Expect getline(1) == '_Doer'
+    end
+
+    it 'selects ending sections'
+        put! = 'ohNoWhatsThis'
+        normal 12|
+        normal div
+        Expect getline(1) == 'ohNoWhats'
+    end
+
+    it 'ignores leading underscores'
+        put! = '_doCoolThings'
+        normal! 5|
+        normal div
+        Expect getline(1) == '_doThings'
+    end
+
+    it 'can match on the left boundary'
+        put! = 'helloWorld'
+        normal! 0
+        normal div
+        Expect getline(1) == 'world'
+    end
+
+    it 'can match on the right boundary'
+        put! = 'helloWorld'
+        normal! $
+        normal div
+        Expect getline(1) == 'hello'
+    end
+
+    it 'does not cross left word boundaries'
+        put! = 'fooBar bazQuux'
+        normal! 10|
+        normal div
+        Expect getline(1) == 'fooBar quux'
+    end
+
+    it 'does not cross right word boundaries'
+        put! = 'fooBar bazQuux'
+        normal! 6|
+        normal div
+        Expect getline(1) == 'foo bazQuux'
+    end
+end
+
+
+describe 'degenerate case'
+    after
+        bwipeout!
+    end
+
+    it 'works'
+        put! = 'thing'
+        normal div
+        Expect getline(1) == ''
+    end
+end