librelane: init at dev 2026-01-12

Co-authored-by: Mohamed Gaber <me@donn.website>
Co-authored-by: Gaétan Lepage <gaetan@glepage.com>

Author: 3 people

pkgs/by-name/li/librelane/package.nix

@@ -0,0 +1,105 @@
+{
+  lib,
+  python3Packages,
+  fetchFromGitHub,
+  fetchpatch,
+
+  # nativeBuildInputs
+  makeWrapper,
+
+  # dependencies
+  pdk-ciel,
+
+  # wrapper runtime dependencies
+  abc-verifier,
+  klayout,
+  magic-vlsi,
+  netgen-vlsi,
+  openroad,
+  ruby,
+  verilator,
+  yosys,
+}:
+
+python3Packages.buildPythonApplication (finalAttrs: {
+  pname = "librelane";
+  version = "3.0.0.dev47-unstable-2026-01-12";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "librelane";
+    repo = "librelane";
+    rev = "b38f7d33a4fb9f5fb8b99715e9d6595c35df0d98";
+    hash = "sha256-//gG1W6JWRJoZl1tPQmq3BwEGepXY0m4gWa/JmAvYDs=";
+  };
+
+  patches = [
+    (fetchpatch {
+      name = "fix-click-compatibility";
+      url = "https://github.com/librelane/librelane/pull/844.patch";
+      hash = "sha256-n8VDzvIlPp3mbuZQobxwYQWjCvftpob8op8vSt6d3NA=";
+    })
+  ];
+
+  build-system = [
+    python3Packages.poetry-core
+  ];
+
+  nativeBuildInputs = [
+    makeWrapper
+  ];
+
+  pythonRelaxDeps = [
+    "click"
+  ];
+
+  dependencies = with python3Packages; [
+    click
+    cloup
+    deprecated
+    httpx
+    libparse-python
+    lxml
+    numpy
+    pandas
+    pdk-ciel
+    psutil
+    python3Packages.klayout
+    pyyaml
+    rapidfuzz
+    rich
+    semver
+    tkinter
+    yamlcore
+  ];
+
+  postInstall = ''
+    cp -r librelane/scripts $out/${python3Packages.python.sitePackages}/librelane/
+    cp -r librelane/examples $out/${python3Packages.python.sitePackages}/librelane/
+  '';
+
+  postFixup = ''
+    wrapProgram $out/bin/librelane \
+      --suffix PYTHONPATH : "$PYTHONPATH" \
+      --prefix PATH : ${
+        lib.makeBinPath [
+          abc-verifier
+          klayout
+          magic-vlsi
+          netgen-vlsi
+          openroad
+          ruby
+          verilator
+          yosys
+        ]
+      }
+  '';
+
+  meta = {
+    description = "ASIC implementation flow infrastructure";
+    homepage = "https://github.com/librelane/librelane";
+    license = lib.licenses.asl20;
+    maintainers = [ lib.maintainers.gonsolo ];
+    mainProgram = "librelane";
+  };
+})