PACProfile/build.gradle at main · PeaceAndCubeMC/PACProfile · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
import java.nio.charset.StandardCharsets

plugins {
    id 'java'
    id 'checkstyle'
    id 'maven-publish'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
}

group = "fr.peaceandcube"
version = "1.7.1"

repositories {
    // LuckPerms
    mavenCentral()
    // Paper
    maven { url = "https://repo.papermc.io/repository/maven-public/" }
    // Essentials
    maven { url = "https://repo.essentialsx.net/releases/" }
    // GriefPrevention
    maven { url = "https://jitpack.io" }

    flatDir { dirs 'libs' }
}

configurations {
    include.canBeResolved = true
    compileOnly.extendsFrom(include)
}

dependencies {
    implementation "io.papermc.paper:paper-api:1.21.11-R0.1-SNAPSHOT"

    compileOnly "net.luckperms:api:5.5"
    compileOnly "net.essentialsx:EssentialsX:2.21.2"
    compileOnly "com.github.TechFortress:GriefPrevention:16.18.4"

    compileOnly name: "pacutilities-1.3.2"
    compileOnly name: "pacbirthday-1.5.0"

    testImplementation "org.mockbukkit.mockbukkit:mockbukkit-v1.21:4.110.0"
    testImplementation "org.junit.jupiter:junit-jupiter:6.1.0"
    testRuntimeOnly "org.junit.platform:junit-platform-launcher:6.1.0"
}

build {
    dependsOn(shadowJar)
}

shadowJar {
    configurations = [project.configurations.include]

    archiveFileName = "${rootProject.name}-${version}.jar"
}

java {
    toolchain.languageVersion = JavaLanguageVersion.of(21)
}

tasks {
    compileJava {
        options.release = 21
        options.encoding = StandardCharsets.UTF_8.name()
    }

    checkstyle {
        configFile = rootProject.file("checkstyle.xml")
        toolVersion = "10.21.4"
    }

    test {
        useJUnitPlatform()
    }
}

processResources {
    filesMatching('plugin.yml') {
        expand(version: version)
    }
}

publishing {
    publications {
        maven(MavenPublication) {
            from components.java
        }
    }
    repositories {
        maven {
            name = "GitHubPackages"
            url = "https://maven.pkg.github.com/PeaceAndCubeMC/PACProfile"
            credentials {
                username = System.getenv("GITHUB_ACTOR")
                password = System.getenv("GITHUB_TOKEN")
            }
        }
    }
}