[Documentation] - Missende documentatie velden

[DannyGJdeJong]

The currently implemented properties can be found here.

Describe the bug and/or desired behavior

Veel velden uit de documentatie tab van adlib komen niet door.

De velden “Dl./p./afb.” en "Catalogusnummer" uit Adlib worden nu niet getoond, maar dit zou wel moeten.

Relevant examples

Collectie Online links:

1. https://id.rijksmuseum.nl/200106153 / RP-P-1994-86B

<documentation>
  <documentation.catalogue_number>cat.nr. 141</documentation.catalogue_number>
  <documentation.copy_number>249004</documentation.copy_number>
  <documentation.koha_id>238197</documentation.koha_id>
  <documentation.pagination.catalogue>p. 122 (afb. p. 123)</documentation.pagination.catalogue>
  <documentation.place>Utrecht :</documentation.place>
  <documentation.publication.year>©2014</documentation.publication.year>
  <documentation.publisher>Begijnekade 18 Uitgevers</documentation.publisher>
  <documentation.title>Leven in lijnen : Debora Duyvis, grafica, 1886-1974</documentation.title>
</documentation>

---

Screenshots

[DannyGJdeJong]

Dit is al beschikbaar in de access store met het volgende patroon:

PREFIX crm: <http://www.cidoc-crm.org/cidoc-crm/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX schema: <http://schema.org/>

SELECT ?objectUri ?instanceTitle ?catalogNumber ?pageNumber 
WHERE {
    ?objectUri rdf:type crm:E22_Human-Made_Object.
    ?objectUri crm:P141i_was_assigned_by ?assignment.
    ?assignment rdf:type crm:E13_Attribute_Assignment.
    # Getty AAT: references
    ?assignment crm:P2_has_type <http://vocab.getty.edu/aat/300311954>.
    
    ?assignment crm:P141_assigned ?linguisticAppellation.
    ?linguisticAppellation rdf:type crm:E33_Linguistic_Object.
    ?linguisticAppellation crm:P106i_forms_part_of ?libraryProductModel.
    ?libraryProductModel rdf:type schema:ProductModel.
    ?libraryProductModel schema:name ?instanceTitle.
    
    ?linguisticAppellation crm:P1_is_identified_by ?documentationIdentifier.
    ?documentationIdentifier rdf:type crm:E42_Identifier.
    
    ?documentationIdentifier crm:P106_is_composed_of ?pageNumberIdentifier.
    # Getty AAT: page numbers
    ?pageNumberIdentifier crm:P2_has_type <http://vocab.getty.edu/aat/300445022>.
    ?pageNumberIdentifier crm:P190_has_symbolic_content ?pageNumber.
    
    ?documentationIdentifier crm:P106_is_composed_of ?catalogNumberIdentifier.
    # Getty AAT: catalog numbers
    ?catalogNumberIdentifier crm:P2_has_type <http://vocab.getty.edu/aat/300404620>.
    ?catalogNumberIdentifier crm:P190_has_symbolic_content ?catalogNumber.
    
    FILTER(?objectUri = <https://id.rijksmuseum.nl/200106153>)
}

objectUri	instanceTitle	catalogNumber	pageNumber
https://id.rijksmuseum.nl/200106153	"Leven in lijnen: Debora Duyvis, grafica, 1886-1974"	"141"	"p. 122 (afb. p. 123)"

Het is alleen de vraag hoe we dit in de front-end willen presenteren. We laten nu namelijk de gelinkte documentatie (hasLibraryDocumentation) als node zien.