Inplace! Operations?

[drizk1]

Wondering if there's any need/interest for in place operations such as @select!

Should be super easy to do them for all the basic verbs select, filter, mutate/transmute, rename, joins

[kdpsingh]

Yes, definitely on the roadmap. I want to implement a better way to process keyboard arguments in our macros so that we don't have to completely duplicate functionality. This will also support other keyboard arguments like _by. This isn't hard to do, happy to discuss more offline if you have bandwidth.

[drizk1]

I was playing around with some options to avoid duplicating functionality and i think this might be one possibility with minimal changes

macro _select(df, _inplace, exprs...)
    exprs = parse_blocks(exprs...)
    interpolated_exprs = parse_interpolation.(exprs)

    tidy_exprs = [i[1] for i in interpolated_exprs]
    any_found_n = any([i[2] for i in interpolated_exprs])
    any_found_row_number = any([i[3] for i in interpolated_exprs])

    tidy_exprs = parse_tidy.(tidy_exprs)

    df_expr = quote
        local inplace = $_inplace
        local _df = $(esc(df))
        local needs_copy = $any_found_n || $any_found_row_number

        local df_copy = if inplace
            _df
        else
            if needs_copy
                _df isa GroupedDataFrame ? transform(_df; ungroup=false) : copy(_df)
            else
                _df
            end
        end

        if _df isa GroupedDataFrame
            if $any_found_n
                transform!(df_copy, nrow => :TidierData_n; ungroup=false)
            end
            if $any_found_row_number
                transform!(df_copy, eachindex => :TidierData_row_number; ungroup=false)
            end

            local df_output = inplace ?
                select!(df_copy, $(tidy_exprs...); ungroup=false) :
                select(df_copy, $(tidy_exprs...); ungroup=false)

            if $any_found_n || $any_found_row_number
                select!(df_output, Cols(Not(r"^(TidierData_n|TidierData_row_number)$")); ungroup=false)
            end
        else
            if $any_found_n
                transform!(df_copy, nrow => :TidierData_n)
            end
            if $any_found_row_number
                transform!(df_copy, eachindex => :TidierData_row_number)
            end

            local df_output = inplace ?
                select!(df_copy, $(tidy_exprs...)) :
                select(df_copy, $(tidy_exprs...))

            if $any_found_n || $any_found_row_number
                select!(df_output, Cols(Not(r"^(TidierData_n|TidierData_row_number)$")))
            end
        end

        log[] && @info generate_log(
            df_copy, df_output;
            name = inplace ? "@select!" : "@select",
            modes = [:colchange]
        )

        df_output
    end

    if code[]
        @info MacroTools.prettify(df_expr) # COV_EXCL_LINE
    end
    return df_expr
end