feat(new_class,ts): to not overwrite existing file, cancel when file already exists

Author: alquerci

autoload/refactoring_toolbox/new_class/adapters/spy_filesystem.vim

@@ -20,12 +20,17 @@ let s:constructed = v:false
 function s:constuct()
     let s:self.writtenFiles = []
     let s:self.writtenLines = []
+    let s:self.filesystemList = []
 
     let s:constructed = v:true
 
     return s:self
 endfunction
 
+function s:self.filepathExists(filepath)
+    return s:LIST_ITEM_NOT_FOUND != index(s:self.filesystemList, a:filepath)
+endfunction
+
 function s:self.writeFileWithLines(filepath, lines)
     call add(s:self.writtenFiles, a:filepath)
     call add(s:self.writtenLines, a:lines)
@@ -39,6 +44,10 @@ function s:self.writtenLinesOnFilepath(filepath)
     return s:self.writtenLines[s:findFileIndex(a:filepath)]
 endfunction
 
+function s:self.setFilesystemList(list)
+    let s:self.filesystemList = a:list
+endfunction
+
 function s:findFileIndex(filepath)
     return index(s:self.writtenFiles, a:filepath)
 endfunction

autoload/refactoring_toolbox/new_class/adapters/vim_filesystem.vim

@@ -10,4 +10,8 @@ function s:self.writeFileWithLines(filepath, lines)
     call writefile(a:lines, a:filepath)
 endfunction
 
+function s:self.filepathExists(filepath)
+    return filereadable(a:filepath) || isdirectory(a:filepath)
+endfunction
+
 call refactoring_toolbox#adapters#vim#end_script()

autoload/refactoring_toolbox/new_class/class_maker.vim

@@ -1,16 +1,21 @@
 call refactoring_toolbox#adapters#vim#begin_script()
 
-function refactoring_toolbox#new_class#class_maker#execute(filesystem, texteditor, language)
+function refactoring_toolbox#new_class#class_maker#execute(filesystem, texteditor, language, output)
     let s:filesystem = a:filesystem
     let s:texteditor = a:texteditor
     let s:language = a:language
+    let s:output = a:output
 
     let l:newClassName = s:texteditor.getWordOnCursor()
     let l:newFilepath = s:getFilePathOfNewClassNamed(l:newClassName, s:language.getFileExtension())
 
-    call s:filesystem.writeFileWithLines(l:newFilepath, s:language.makeClassFileLines(l:newClassName))
+    if s:filesystem.filepathExists(l:newFilepath)
+        call s:output.echoWarning('Going to create new class "'.l:newClassName.'" on file "'.l:newFilepath.'" but that file already exists.')
+    else
+        call s:filesystem.writeFileWithLines(l:newFilepath, s:language.makeClassFileLines(l:newClassName))
 
-    call s:texteditor.openFileAside(l:newFilepath)
+        call s:texteditor.openFileAside(l:newFilepath)
+    endif
 endfunction
 
 function s:getFilePathOfNewClassNamed(className, extension)

autoload/refactoring_toolbox/new_class/main.vim

@@ -16,6 +16,7 @@ function refactoring_toolbox#new_class#main#executeForTypescript()
         \ refactoring_toolbox#new_class#adapters#filesystem_factory#make(),
         \ refactoring_toolbox#new_class#adapters#texteditor_factory#make(),
         \ refactoring_toolbox#new_class#adapters#ts_language#make(),
+        \ refactoring_toolbox#adapters#output#make(),
     \ )
 endfunction
 

tests/new_class/adapters/vim_filesystem/filepathExists.vader

@@ -0,0 +1,21 @@
+Before:
+  call mkdir(g:test_tmpdir, 'p')
+
+After:
+  call delete(g:test_tmpdir, 'rf')
+
+Execute (filepathExists(not_exists_file) == v:false):
+  Assert ! refactoring_toolbox#new_class#adapters#vim_filesystem#make().filepathExists(g:test_tmpdir.'/not_existing')
+
+Execute (filepathExists(file) == v:true):
+  call writefile([], g:test_tmpdir.'/file')
+  Assert refactoring_toolbox#new_class#adapters#vim_filesystem#make().filepathExists(g:test_tmpdir.'/file')
+
+Execute (filepathExists(directory) == v:true):
+  Assert refactoring_toolbox#new_class#adapters#vim_filesystem#make().filepathExists(g:test_tmpdir)
+
+Execute (filepathExists(symlink) == v:true):
+  call writefile([], g:test_tmpdir.'/file')
+  call system('ln -sr '.shellescape(g:test_tmpdir.'/file').' '.shellescape(g:test_tmpdir.'/symlink'))
+
+  Assert refactoring_toolbox#new_class#adapters#vim_filesystem#make().filepathExists(g:test_tmpdir.'/symlink')

tests/new_class/adapters/vim_filesystem.vader tests/new_class/adapters/vim_filesystem/writeFileWithLines.vader

@@ -1,9 +1,9 @@
 Before:
   call mkdir(g:test_tmpdir, 'p')
 
+After:
+  call delete(g:test_tmpdir, 'rf')
+
 Execute:
   call refactoring_toolbox#new_class#adapters#vim_filesystem#make().writeFileWithLines(g:test_tmpdir.'/new_class.ext', ['some line'])
-
-Then:
   AssertEqual ['some line'], readfile(g:test_tmpdir.'/new_class.ext')
-  call delete(g:test_tmpdir, 'rf')

tests/new_class/ts/will_cancel_when_file_already_exists.vader

@@ -0,0 +1,18 @@
+Given typescript:
+  NewClass
+
+Before:
+  call refactoring_toolbox#new_class#adapters#texteditor_factory#setTexteditor(
+    \ refactoring_toolbox#new_class#adapters#stub_texteditor#makeWithCurrentFileDirectory('some/current')
+  \ )
+  call refactoring_toolbox#new_class#adapters#filesystem_factory#setFilesystem(
+    \ refactoring_toolbox#new_class#adapters#spy_filesystem#make()
+  \ )
+  call refactoring_toolbox#new_class#adapters#spy_filesystem#get().setFilesystemList(['some/current/NewClass.ts'])
+
+Do:
+  /NewClass\<Enter>
+  ;nc
+
+Then:
+  AssertEqual [], refactoring_toolbox#new_class#adapters#spy_filesystem#get().writtenFiles