build.gradle

buildscript {
    repositories {
        maven { url = "https://maven.fabricmc.net/" }
        mavenCentral()
        gradlePluginPortal()
    }
    dependencies {
        classpath "net.fabricmc:fabric-loom:${property('loom_version')}"
    }
}

def minecraft_version = property("minecraft_version")
def minecraft_version_range = findProperty("minecraft_version_range") ?: ">=1.21.1"
def version_suffix = findProperty("version_suffix") ?: minecraft_version
def isUnobfuscated = (findProperty("minecraft_version")?.toString() ?: "").startsWith("26")

// Numeric semver compare for Stonecutter-style gating in resources.
// Stonecutter handles per-file directives in .java, but its default config
// doesn't process .json — so version-gated mixin entries get templated in
// via the ProcessResources `expand(...)` step below.
def isAtLeast = { String currentVer, String minVer ->
    def cur = currentVer.tokenize('.').collect { (it as String).isInteger() ? (it as int) : 0 }
    def min = minVer.tokenize('.').collect { (it as String).isInteger() ? (it as int) : 0 }
    for (int i = 0; i < Math.max(cur.size(), min.size()); i++) {
        int a = i < cur.size() ? cur[i] : 0
        int b = i < min.size() ? min[i] : 0
        if (a != b) return a > b
    }
    return true
}

// KnownPacksManager class first ships in MC 1.20.5. On older targets we
// strip the mixin entry so the (no-op stub) class doesn't get loaded by
// Mixin and crash with "no @Mixin annotation".
def hasKnownPacksManager = isAtLeast(minecraft_version.toString(), "1.20.5")
def knownPacksMixinEntry = hasKnownPacksManager ? '\n\t\t"KnownPacksManagerMixin",' : ''

// Fabric's typed payload system (PayloadTypeRegistryImpl) first exists on MC 1.20.5.
// On older targets the inbound strict-decode fingerprint vector doesn't apply, so the
// (no-op stub) mixin is stripped to avoid Mixin loading a class with no @Mixin target.
def hasPayloadTypeRegistry = isAtLeast(minecraft_version.toString(), "1.20.5")
def payloadTypeRegistryMixinEntry = hasPayloadTypeRegistry ? '\n\t\t"PayloadTypeRegistryImplMixin",\n\t\t"AbstractChanneledNetworkAddonMixin",' : ''

// Apply the correct Loom plugin variant per version target:
// - net.fabricmc.fabric-loom (non-remap) for unobfuscated MC 26.1+
// - fabric-loom (legacy/remap) for obfuscated MC <=1.21.11
if (isUnobfuscated) {
    apply plugin: "net.fabricmc.fabric-loom"
} else {
    apply plugin: "fabric-loom"
}
apply plugin: "maven-publish"

group = property("maven_group")
version = property("mod_version")

base {
    archivesName = "opsec-$version_suffix"
}

tasks.named("jar") {
    archiveFileName = "${base.archivesName.get()}+v${project.version}.jar"
}

def remapJarTask = tasks.findByName("remapJar")
if (remapJarTask != null) {
    remapJarTask.archiveFileName = "${base.archivesName.get()}+v${project.version}.jar"
}

loom {
    splitEnvironmentSourceSets()
    mods {
        create("opsec") {
            sourceSet(sourceSets.main)
            sourceSet(sourceSets.client)
        }
    }
    if (!isUnobfuscated) {
        mixin {
            useLegacyMixinAp = true
            defaultRefmapName = "opsec.refmap.json"
        }
    }
}

sourceSets {
    main {
        resources.srcDirs("src/main/resources")
    }
    client {
        java.srcDirs("src/client/java")
        resources.srcDirs("src/client/resources")
    }
}

repositories {
    mavenCentral()
    maven { url = "https://maven.terraformersmc.com/"; name = "Terraformers" }
    maven { url = "https://repo.spongepowered.org/repository/maven-public/"; name = "Sponge" }
    maven { url = "https://maven.bawnorton.com/releases"; name = "Bawnorton" }
}

dependencies {
    minecraft("com.mojang:minecraft:${minecraft_version}")
    if (!isUnobfuscated) {
        mappings(loom.officialMojangMappings())
    }

    def loaderCoord = "net.fabricmc:fabric-loader:${loader_version}"
    def apiCoord = "net.fabricmc.fabric-api:fabric-api:${fabric_version}"
    def modmenuCoord = "com.terraformersmc:modmenu:${modmenu_version}"

    if (isUnobfuscated) {
        implementation(loaderCoord)
        implementation(apiCoord)
        implementation("com.terraformersmc:modmenu:${modmenu_version}") {
            exclude group: "eu.pb4", module: "placeholder-api"
        }
    } else {
        modImplementation(loaderCoord)
        modImplementation(apiCoord)
        modImplementation("com.terraformersmc:modmenu:${modmenu_version}") {
            exclude group: "eu.pb4", module: "placeholder-api"
        }
    }

    // MixinSquared for cancelling other mods' mixins (Meteor Client fix)
    include(implementation(annotationProcessor("com.github.bawnorton.mixinsquared:mixinsquared-fabric:0.3.7-beta.1")))
}

def javaVersion = (findProperty("java_version") ?: (isUnobfuscated ? "25" : "21")) as int

tasks.withType(ProcessResources).configureEach {
    def mixinCompatLevel = "JAVA_${javaVersion}"
    inputs.property("version", project.version)
    inputs.property("minecraft_version_range", minecraft_version_range)
    inputs.property("mixin_compat_level", mixinCompatLevel)
    inputs.property("java_version", javaVersion.toString())
    inputs.property("known_packs_mixin_entry", knownPacksMixinEntry)
    inputs.property("payload_type_registry_mixin_entry", payloadTypeRegistryMixinEntry)
    filesMatching(["fabric.mod.json", "opsec.client.mixins.json"]) {
        expand(
            "version": project.version,
            "minecraft_version_range": minecraft_version_range,
            "mixin_compat_level": mixinCompatLevel,
            "java_version": javaVersion.toString(),
            "known_packs_mixin_entry": knownPacksMixinEntry,
            "payload_type_registry_mixin_entry": payloadTypeRegistryMixinEntry
        )
    }
}

tasks.withType(JavaCompile).configureEach {
    options.release = javaVersion
}

java {
    withSourcesJar()
    sourceCompatibility = JavaVersion.toVersion(javaVersion)
    targetCompatibility = JavaVersion.toVersion(javaVersion)
}

tasks.jar {
    from("LICENSE") {
        rename { "${it}_${base.archivesName.get()}" }
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifactId = "opsec-$minecraft_version"
            from(components.java)
        }
    }
}