build.gradle

plugins {
    id 'dev.architectury.loom' version '1.7-SNAPSHOT' apply false
    id 'architectury-plugin' version '3.4-SNAPSHOT'
    id 'com.github.johnrengelman.shadow' version '8.1.1' apply false
    id "io.github.pacifistmc.forgix" version "1.2.9-local.10"
    id 'io.github.0ffz.github-packages' version '[1,2)'
    id "me.modmuss50.mod-publish-plugin" version "0.8.1"
    id "org.moddedmc.wiki.toolkit" version "0.2.4"
}

architectury {
    minecraft = project.minecraft_version
}

allprojects {
    group = maven_group
    version = mod_version + "+" + minecraft_version
}


wiki {
    docs {
        // The name of the object (examplemod) should match the registered wiki project ID (if it exists).
        "pyrite" {
            // The path to the folder containing the documentation metadata file (sinytra-wiki.json)
            root = file('docs')
        }
    }
}

forgix {
    group = "cc.cassian.pyrite"
    mergedJarName = "pyrite-${version}.jar"
    neoforge {
        projectName = "neoforge"
        jarLocation = "build/libs/pyrite-neoforge-${version}.jar"
    }

    fabric {
        projectName = "fabric"
        jarLocation = "build/libs/pyrite-fabric-${version}.jar"
    }
}

publishMods {
    file = file("Merged/"+forgix.getMergedJarName())
    String changelogString = new File("CHANGELOG.md")
    changelog = changelogString
    type = STABLE
    modLoaders.add("fabric")
    modLoaders.add("neoforge")

    modrinth {
        accessToken = providers.environmentVariable("MODRINTH_API_KEY")
        projectId = "qO4ozPoe"
        minecraftVersions.add(minecraft_version)
    }
    curseforge {
        accessToken = providers.environmentVariable("CURSEFORGE_API_KEY")
        projectId = "1101500"
        clientRequired = true
        serverRequired = true
        minecraftVersions.add(minecraft_version)
    }
}

subprojects {
    apply plugin: 'dev.architectury.loom'
    apply plugin: 'architectury-plugin'
    apply plugin: 'maven-publish'

    base {
        // Set up a suffixed format for the mod jar names, e.g. `example-fabric`.
        archivesName = "$rootProject.archives_name-$project.name"
    }

    repositories {
        // Add repositories to retrieve artifacts from in here.
        // You should only use this when depending on other mods because
        // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
        // See https://docs.gradle.org/current/userguide/declaring_repositories.html
        // for more information about repositories.
        maven { url 'https://maven.wispforest.io' }
        maven {
            name = "Fuzs Mod Resources"
            url = "https://raw.githubusercontent.com/Fuzss/modresources/main/maven/"
        }
        maven {
            name = "TerraformersMC"
            url = "https://maven.terraformersmc.com/"
        }
        maven githubPackage.invoke("The-Aether-Team/The-Aether")

    }

    dependencies {
        minecraft "net.minecraft:minecraft:$minecraft_version"
        mappings loom.layered {
            it.mappings("net.fabricmc:yarn:$minecraft_version+build.$yarn_mappings_build:v2")
            it.mappings("dev.architectury:yarn-mappings-patch-neoforge:$yarn_mappings_patch_neoforge_version")
        }
    }

    java {
        // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
        // if it is present.
        // If you remove this line, sources will not be generated.
        withSourcesJar()

        sourceCompatibility = JavaVersion.VERSION_21
        targetCompatibility = JavaVersion.VERSION_21
    }

    tasks.withType(JavaCompile).configureEach {
        it.options.release = 21
    }

    // Configure Maven publishing.
    publishing {
        publications {
            mavenJava(MavenPublication) {
                artifactId = base.archivesName.get()
                from components.java
            }
        }

        // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
        repositories {
            // Add repositories to publish to here.
            // Notice: This block does NOT have the same function as the block in the top level.
            // The repositories here will be used for publishing your artifact, not for
            // retrieving dependencies.
        }
    }
    build.finalizedBy(mergeJars)
    assemble.finalizedBy(mergeJars)
}