sami_installer.iss

; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

#define SammyAppName "Sami Programming Language"
#define SammyAppVersion "3.1"
#define SammyAppPublisher "Sami Language Team"
#define SammyAppExeName "sami.exe"

[Setup]
AppId={{D86A3E5D-4A2D-4E15-99AB-9C78BC7193F1}
AppName={#SammyAppName}
AppVersion={#SammyAppVersion}
AppPublisher={#SammyAppPublisher}
DefaultDirName={autopf}\SamiLang
DefaultGroupName=SamiLang
DisableProgramGroupPage=yes
OutputDir=.
OutputBaseFilename=sami_setup
Compression=lzma
SolidCompression=yes
WizardStyle=modern
ChangesEnvironment=yes
PrivilegesRequired=admin
ChangesAssociations=yes
SetupIconFile={#SourcePath}\assets\sami_setup.ico
UninstallDisplayIcon={app}\sami_setup.ico

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"

[Tasks]
Name: "envPath"; Description: "Add Sami Programming Language to system PATH (recommended)"; GroupDescription: "Advanced Configuration:"; Flags: checkedonce
Name: "vscodeExt"; Description: "Install Sami Language support for Visual Studio Code Icons"; GroupDescription: "Editor Integrations:"; Flags: checkedonce

[Files]
Source: "target\release\sami.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "sami.ico"; DestDir: "{app}"; Flags: ignoreversion
Source: "sami_file.ico"; DestDir: "{app}"; Flags: ignoreversion
Source: "sami_setup.ico"; DestDir: "{app}"; Flags: ignoreversion
Source: "sami_docs.ico"; DestDir: "{app}"; Flags: ignoreversion
Source: "sami-vscode-extension\*"; DestDir: "{%USERPROFILE}\.vscode\extensions\sami-vscode-extension"; Flags: recursesubdirs createallsubdirs ignoreversion; Tasks: vscodeExt

[Icons]
Name: "{group}\{#SammyAppName}"; Filename: "{app}\{#SammyAppExeName}"; IconFilename: "{app}\sami.ico"
Name: "{group}\Uninstall {#SammyAppName}"; Filename: "{uninstallexe}"; IconFilename: "{app}\sami_setup.ico"

[Registry]
Root: HKLM; Subkey: "SYSTEM\CurrentControlSet\Control\Session Manager\Environment"; \
    ValueType: expandsz; ValueName: "Path"; ValueData: "{olddata};{app}"; \
    Check: NeedsAddPath; Flags: preservestringtype

; Windows File Association keys for .sa
Root: HKA; Subkey: "Software\Classes\.sa"; ValueType: string; ValueName: ""; ValueData: "SamiFile"; Flags: uninsdeletevalue
Root: HKA; Subkey: "Software\Classes\SamiFile"; ValueType: string; ValueName: ""; ValueData: "Sami Programming Language Script"; Flags: uninsdeletekey
Root: HKA; Subkey: "Software\Classes\SamiFile\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\sami_file.ico,0"; Flags: uninsdeletevalue
Root: HKA; Subkey: "Software\Classes\SamiFile\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\sami.exe"" ""run"" ""%1"""

; Windows File Association keys for .sadoc (Sami Language Documentation)
Root: HKA; Subkey: "Software\Classes\.sadoc"; ValueType: string; ValueName: ""; ValueData: "SamiDocs"; Flags: uninsdeletevalue
Root: HKA; Subkey: "Software\Classes\SamiDocs"; ValueType: string; ValueName: ""; ValueData: "Sami Programming Language Documentation"; Flags: uninsdeletekey
Root: HKA; Subkey: "Software\Classes\SamiDocs\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\sami_docs.ico,0"; Flags: uninsdeletevalue


[Run]
Filename: "{sys}\cmd.exe"; Parameters: "/c mcbuilder.exe"; Flags: runhidden


[Code]
function NeedsAddPath(): Boolean;
var
  OldPath: String;
begin
  if WizardIsTaskSelected('envPath') then
  begin
    if RegQueryStringValue(HKLM, 'SYSTEM\CurrentControlSet\Control\Session Manager\Environment', 'Path', OldPath) then
    begin
      // Look for ;installation_path; inside ;old_path;
      Result := Pos(';' + Uppercase(ExpandConstant('{app}')) + ';', ';' + Uppercase(OldPath) + ';') = 0;
    end
    else
      Result := True;
  end
  else
    Result := False;
end;