agent-maintainer/justfile at main · douglasmonsky/agent-maintainer · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
# Canonical developer commands. All agent instructions should point here.
export PYTHONDONTWRITEBYTECODE := "1"
export PYTHONPATH := "src"

bootstrap:
    python3 -m agent_maintainer bootstrap

doctor:
    python3 -m agent_maintainer doctor

guidance:
    python3 -m agent_maintainer guidance

guidance-check:
    python3 -m agent_maintainer guidance --check

change-plan-check:
    python3 -m agent_maintainer change-plan check

config-reference:
    python3 -m agent_maintainer.config.reference

config-reference-check:
    python3 -m agent_maintainer.config.reference --check

verify:
    python3 -m agent_maintainer verify --profile full

verify-fast:
    python3 -m agent_maintainer verify --profile fast

verify-precommit:
    python3 -m agent_maintainer verify --profile precommit

verify-ci:
    python3 -m agent_maintainer verify --profile ci --base-ref origin/main --compare-branch origin/main

verify-security:
    python3 -m agent_maintainer verify --profile security

verify-manual:
    python3 -m agent_maintainer verify --profile manual

alias vf := verify-fast
alias vp := verify-precommit
alias v := verify
alias vc := verify-ci
alias vs := verify-security
alias vm := verify-manual
alias dl := refresh-dev-lock
alias wg := wait-github
alias wp := wait-pr
alias wv := wait-verifier

wait-github RUN_ID:
    python3 -m agent_maintainer wait github-run {{RUN_ID}}

wait-pr PR_NUMBER:
    python3 -m agent_maintainer wait github-pr {{PR_NUMBER}}

wait-verifier RUN_ID:
    python3 -m agent_maintainer wait verifier {{RUN_ID}}

release-check:
    PYTHON="$([ -x .venv/bin/python ] && printf '%s' .venv/bin/python || printf '%s' python3)"; AGENT_MAINTAINER_RUN_RELEASE_TESTS=1 "$PYTHON" -m pytest -m release tests/release -q

refresh-dev-lock:
    PYTHON="${PYTHON:-$([ -x .venv/bin/python ] && printf '%s' .venv/bin/python || printf '%s' python3)}"; case "$("$PYTHON" --version)" in "Python 3.13."*) ;; *) printf '%s\n' 'refresh-dev-lock requires Python 3.13' >&2; exit 1 ;; esac; "$PYTHON" -m piptools compile --allow-unsafe --resolver=backtracking --strip-extras --upgrade --output-file=config/dev-lock.txt config/dev-dependencies.in pyproject.toml

# Example for a flat package layout:
verify-flat PACKAGE:
    python3 -m agent_maintainer verify --profile full --source-root {{PACKAGE}} --coverage-source {{PACKAGE}} --package-path {{PACKAGE}} --test-root tests

verify-full-output:
    ruff format --check .
    ruff check .
    python3 -m agent_maintainer.runners.pyright
    pytest -q --tb=short --disable-warnings --cov=.codex/hooks --cov=.claude/hooks --cov=src/agent_maintainer --cov=src/archguard --cov-report=term-missing:skip-covered --cov-report=xml --cov-fail-under=90 tests
    radon cc .codex/hooks .claude/hooks src/agent_maintainer src/archguard -a -s
    radon mi .codex/hooks .claude/hooks src/agent_maintainer src/archguard -s
    xenon --max-absolute B --max-modules A --max-average A .codex/hooks .claude/hooks src/agent_maintainer src/archguard
    pylint .codex/hooks .claude/hooks src/agent_maintainer src/archguard --score=n
    python3 -m archguard tach-config --strict-root-module
    tach check --exact
    interrogate --fail-under=80 --ignore-init-method --ignore-init-module --ignore-private --ignore-semiprivate --ignore-magic .codex/hooks .claude/hooks src/agent_maintainer src/archguard
    deptry .
    vulture .codex/hooks .claude/hooks src/agent_maintainer src/archguard tests
    bandit -q -r .codex/hooks .claude/hooks src/agent_maintainer src/archguard
    markdownlint-cli2 "**/*.md"
    yamllint .github/workflows .pre-commit-config.yaml .markdownlint-cli2.yaml .yamllint zizmor.yml
    taplo fmt --check pyproject.toml tach.toml config/*.toml
    check-jsonschema --builtin-schema vendor.github-workflows .github/workflows/verify.yml .github/workflows/deep-verify.yml .github/workflows/java-gradle-live.yml .github/workflows/publish.yml
    pip-audit -r config/dev-lock.txt

clean-verify-logs:
    rm -rf .verify-logs coverage.xml .coverage htmlcov