[CMakeLists.txt] Updating to no longer using an ancient way of importing Eigen3.

Author: Murilo M. Marinho

CMakeLists.txt

@@ -1,15 +1,19 @@
 # Updated 2025.05 to 3.10 since compatibility with CMake < 3.10 will be removed from a future version of CMake.
 cmake_minimum_required(VERSION 3.10)
+
+# Added in case users want to build this library as STATIC
 # https://cmake.org/cmake/help/latest/variable/BUILD_SHARED_LIBS.html
 option(BUILD_SHARED_LIBS "Build using shared libraries" ON)
 
 if(WIN32)
     set(CMAKE_TOOLCHAIN_FILE C:/vcpkg/scripts/buildsystems/vcpkg.cmake)
+    # A must so that we don't need to manually export each public part of the library
     set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS ON)
 endif()
 
 project(dqrobotics)
-set (CMAKE_CXX_STANDARD 11)
+
+find_package(Eigen3 REQUIRED)
 
 # As of 2025.05, Not using GLOB_RECURSE as it's explicitly discouraged.
 # https://stackoverflow.com/questions/3201154/automatically-add-all-files-in-a-folder-to-a-target-using-cmake
@@ -50,57 +54,49 @@ add_library(dqrobotics
     src/robots/FrankaEmikaPandaRobot.cpp
     )
 
-target_include_directories(
+set_property(TARGET dqrobotics PROPERTY CXX_STANDARD 17)
+
+target_include_directories(dqrobotics PUBLIC
         include
 )
 
-if(UNIX AND NOT APPLE)
-    find_package(Eigen3 REQUIRED)
-    include_directories(${EIGEN3_INCLUDE_DIR})
-    add_compile_options(-Werror=return-type -Wall -Wextra -Wmissing-declarations -Wredundant-decls -Woverloaded-virtual)
-endif()
-
-if(APPLE)
-    include_directories(
-            /usr/local/include/
-            /usr/local/include/eigen3
-            # Most recent versions of brew install here
-            /opt/homebrew/include
-            /opt/homebrew/include/eigen3)
-    add_compile_options(-Werror=return-type -Wall -Wextra -Wmissing-declarations -Wredundant-decls -Woverloaded-virtual)
+if(UNIX)
+    # WIN32 does not accept these flags
+    add_compile_options(-Werror=return-type -Wall -Wextra -Wmissing-declarations -Wredundant-decls -Woverloaded-virtual -fPIC)
 endif()
 
 if(WIN32)
-    add_definitions(-D_USE_MATH_DEFINES)
-    find_package(Eigen3 CONFIG REQUIRED)
-    include_directories(${EIGEN3_INCLUDE_DIR})
+    # https://learn.microsoft.com/en-us/cpp/c-runtime-library/math-constants?view=msvc-170
+    target_compile_definitions(dqrobotics PUBLIC
+            _USE_MATH_DEFINES
+    )
 endif()
 
+target_link_libraries(dqrobotics PUBLIC
+        Eigen3::Eigen
+)
+
 set_target_properties(dqrobotics
     PROPERTIES PUBLIC_HEADER
     include/dqrobotics/DQ.h
     )
 
 install(TARGETS dqrobotics
-# https://stackoverflow.com/questions/21592361/cmake-install-is-not-installing-libraries-on-windows    
+    # https://stackoverflow.com/questions/21592361/cmake-install-is-not-installing-libraries-on-windows
 	RUNTIME DESTINATION "bin"
     LIBRARY DESTINATION "lib"
 	ARCHIVE DESTINATION "lib"
     PUBLIC_HEADER DESTINATION "include/dqrobotics"
-    PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ)
-
-################################################################
-# INSTALL HEADERS IN SUBFOLDERS
-################################################################
+    PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
+)
 
 install(DIRECTORY
     include/
-    DESTINATION "include")
-
-################################################################
-# INSTALL SOURCE FILES (So that the debugger can find them)
-################################################################
+    DESTINATION "include"
+)
 
+# Install source files so that the debugger can find them
 install(DIRECTORY
     src/
-    DESTINATION "src/dqrobotics")
+    DESTINATION "src/dqrobotics"
+)

include/dqrobotics/DQ.h

@@ -42,11 +42,7 @@ This file is part of DQ Robotics.
 */
 #pragma once
 
-#ifdef _WIN32
 #include <Eigen/Dense>
-#else
-#include <eigen3/Eigen/Dense>
-#endif
 
 #include <iostream>
 using namespace Eigen;

include/dqrobotics/utils/DQ_LinearAlgebra.h

@@ -21,12 +21,7 @@ This file is part of DQ Robotics.
 - Murilo M. Marinho ([email protected])
 */
 
-#ifdef _WIN32
 #include <Eigen/Dense>
-#else
-#include <eigen3/Eigen/Dense>
-#endif
-
 #include <tuple>
 
 using namespace Eigen;