Add circular-buffer exercise (#515)

Author: keiravillekode

config.json

@@ -1059,6 +1059,14 @@
         "prerequisites": [],
         "difficulty": 6
       },
+      {
+        "slug": "circular-buffer",
+        "name": "Circular Buffer",
+        "uuid": "29e1dff8-b3bc-4b8a-b50b-bd05f9a9a42f",
+        "practices": [],
+        "prerequisites": [],
+        "difficulty": 6
+      },
       {
         "slug": "flower-field",
         "name": "Flower Field",

exercises/practice/circular-buffer/.docs/instructions.md

@@ -0,0 +1,58 @@
+# Instructions
+
+A circular buffer, cyclic buffer or ring buffer is a data structure that uses a single, fixed-size buffer as if it were connected end-to-end.
+
+A circular buffer first starts empty and of some predefined length.
+For example, this is a 7-element buffer:
+
+```text
+[ ][ ][ ][ ][ ][ ][ ]
+```
+
+Assume that a 1 is written into the middle of the buffer (exact starting location does not matter in a circular buffer):
+
+```text
+[ ][ ][ ][1][ ][ ][ ]
+```
+
+Then assume that two more elements are added — 2 & 3 — which get appended after the 1:
+
+```text
+[ ][ ][ ][1][2][3][ ]
+```
+
+If two elements are then removed from the buffer, the oldest values inside the buffer are removed.
+The two elements removed, in this case, are 1 & 2, leaving the buffer with just a 3:
+
+```text
+[ ][ ][ ][ ][ ][3][ ]
+```
+
+If the buffer has 7 elements then it is completely full:
+
+```text
+[5][6][7][8][9][3][4]
+```
+
+When the buffer is full an error will be raised, alerting the client that further writes are blocked until a slot becomes free.
+
+When the buffer is full, the client can opt to overwrite the oldest data with a forced write.
+In this case, two more elements — A & B — are added and they overwrite the 3 & 4:
+
+```text
+[5][6][7][8][9][A][B]
+```
+
+3 & 4 have been replaced by A & B making 5 now the oldest data in the buffer.
+Finally, if two elements are removed then what would be returned is 5 & 6 yielding the buffer:
+
+```text
+[ ][ ][7][8][9][A][B]
+```
+
+Because there is space available, if the client again uses overwrite to store C & D then the space where 5 & 6 were stored previously will be used not the location of 7 & 8.
+7 is still the oldest element and the buffer is once again full.
+
+```text
+[C][D][7][8][9][A][B]
+```

exercises/practice/circular-buffer/.meta/config.json

@@ -0,0 +1,19 @@
+{
+  "authors": [
+    "keiravillekode"
+  ],
+  "files": {
+    "solution": [
+      "circular_buffer.zig"
+    ],
+    "test": [
+      "test_circular_buffer.zig"
+    ],
+    "example": [
+      ".meta/example.zig"
+    ]
+  },
+  "blurb": "A data structure that uses a single, fixed-size buffer as if it were connected end-to-end.",
+  "source": "Wikipedia",
+  "source_url": "https://en.wikipedia.org/wiki/Circular_buffer"
+}

exercises/practice/circular-buffer/.meta/example.zig

@@ -0,0 +1,52 @@
+pub const BufferError = error{BufferOverflow};
+
+pub fn CircularBuffer(comptime T: type, comptime capacity: usize) type {
+    return struct {
+        const Self = @This();
+
+        items: [capacity]T = undefined,
+        read_index: usize = 0,
+        write_index: usize = 0,
+
+        /// Initializes a CircularBuffer
+        pub fn init() Self {
+            return .{};
+        }
+
+        /// Discards all items in the buffer.
+        pub fn clear(self: *Self) void {
+            self.write_index = self.read_index;
+        }
+
+        /// Extracts the oldest item from the buffer.
+        pub fn read(self: *Self) ?T {
+            if (self.read_index == self.write_index) {
+                return null;
+            }
+            const result = self.items[self.read_index];
+            self.read_index += 1;
+            if (self.read_index == capacity) {
+                self.read_index -= capacity;
+                self.write_index -= capacity;
+            }
+            return result;
+        }
+
+        /// Write `item` into the buffer.
+        pub fn write(self: *Self, item: T) BufferError!void {
+            if (self.write_index == self.read_index + capacity) {
+                return BufferError.BufferOverflow;
+            }
+            self.overwrite(item);
+        }
+
+        /// Write `item` into the buffer, replacing the oldest item if necessary.
+        pub fn overwrite(self: *Self, item: T) void {
+            if (self.write_index == self.read_index + capacity) {
+                _ = self.read();
+            }
+            self.items[self.write_index % capacity] = item;
+            self.write_index += 1;
+        }
+    };
+}

exercises/practice/circular-buffer/.meta/tests.toml

@@ -0,0 +1,52 @@
+# This is an auto-generated file.
+#
+# Regenerating this file via `configlet sync` will:
+# - Recreate every `description` key/value pair
+# - Recreate every `reimplements` key/value pair, where they exist in problem-specifications
+# - Remove any `include = true` key/value pair (an omitted `include` key implies inclusion)
+# - Preserve any other key/value pair
+#
+# As user-added comments (using the # character) will be removed when this file
+# is regenerated, comments can be added via a `comment` key.
+
+[28268ed4-4ff3-45f3-820e-895b44d53dfa]
+description = "reading empty buffer should fail"
+
+[2e6db04a-58a1-425d-ade8-ac30b5f318f3]
+description = "can read an item just written"
+
+[90741fe8-a448-45ce-be2b-de009a24c144]
+description = "each item may only be read once"
+
+[be0e62d5-da9c-47a8-b037-5db21827baa7]
+description = "items are read in the order they are written"
+
+[2af22046-3e44-4235-bfe6-05ba60439d38]
+description = "full buffer can't be written to"
+
+[547d192c-bbf0-4369-b8fa-fc37e71f2393]
+description = "a read frees up capacity for another write"
+
+[04a56659-3a81-4113-816b-6ecb659b4471]
+description = "read position is maintained even across multiple writes"
+
+[60c3a19a-81a7-43d7-bb0a-f07242b1111f]
+description = "items cleared out of buffer can't be read"
+
+[45f3ae89-3470-49f3-b50e-362e4b330a59]
+description = "clear frees up capacity for another write"
+
+[e1ac5170-a026-4725-bfbe-0cf332eddecd]
+description = "clear does nothing on empty buffer"
+
+[9c2d4f26-3ec7-453f-a895-7e7ff8ae7b5b]
+description = "overwrite acts like write on non-full buffer"
+
+[880f916b-5039-475c-bd5c-83463c36a147]
+description = "overwrite replaces the oldest item on full buffer"
+
+[bfecab5b-aca1-4fab-a2b0-cd4af2b053c3]
+description = "overwrite replaces the oldest item remaining in buffer following a read"
+
+[9cebe63a-c405-437b-8b62-e3fdc1ecec5a]
+description = "initial clear does not affect wrapping around"

exercises/practice/circular-buffer/circular_buffer.zig

@@ -0,0 +1,41 @@
+pub const BufferError = error{BufferOverflow};
+
+pub fn CircularBuffer(comptime T: type, comptime capacity: usize) type {
+    _ = capacity;
+    return struct {
+        const Self = @This();
+
+        // This struct, as well as its fields and methods, needs to be implemented.
+
+        /// Initializes a CircularBuffer
+        pub fn init() Self {
+            @compileError("please implement the init function");
+        }
+
+        /// Discards all items in the buffer.
+        pub fn clear(self: *Self) void {
+            _ = self;
+            @compileError("please implement the clear function");
+        }
+
+        /// Extracts the oldest item from the buffer.
+        pub fn read(self: *Self) ?T {
+            _ = self;
+            @compileError("please implement the read function");
+        }
+
+        /// Write `item` into the buffer.
+        pub fn write(self: *Self, item: T) BufferError!void {
+            _ = self;
+            _ = item;
+            @compileError("please implement the write function");
+        }
+
+        /// Write `item` into the buffer, replacing the oldest item if necessary.
+        pub fn overwrite(self: *Self, item: T) void {
+            _ = self;
+            _ = item;
+            @compileError("please implement the overwrite function");
+        }
+    };
+}

exercises/practice/circular-buffer/test_circular_buffer.zig

@@ -0,0 +1,120 @@
+const std = @import("std");
+const testing = std.testing;
+
+const circular_buffer = @import("circular_buffer.zig");
+const CircularBuffer = circular_buffer.CircularBuffer;
+const BufferError = circular_buffer.BufferError;
+
+test "reading empty buffer should fail" {
+    var cb = CircularBuffer(i16, 1).init();
+    try testing.expectEqual(null, cb.read());
+}
+
+test "can read an item just written" {
+    var cb = CircularBuffer(i16, 1).init();
+    try cb.write(1);
+    try testing.expectEqual(1, cb.read());
+}
+
+test "each item may only be read once" {
+    var cb = CircularBuffer(i16, 1).init();
+    try cb.write(1);
+    try testing.expectEqual(1, cb.read());
+    try testing.expectEqual(null, cb.read());
+}
+
+test "items are read in the order they are written" {
+    var cb = CircularBuffer(i16, 2).init();
+    try cb.write(1);
+    try cb.write(2);
+    try testing.expectEqual(1, cb.read());
+    try testing.expectEqual(2, cb.read());
+}
+
+test "full buffer can't be written to" {
+    var cb = CircularBuffer(i16, 1).init();
+    try cb.write(1);
+    try testing.expectError(BufferError.BufferOverflow, cb.write(2));
+}
+
+test "a read frees up capacity for another write" {
+    var cb = CircularBuffer(i16, 1).init();
+    try cb.write(1);
+    try testing.expectEqual(1, cb.read());
+    try cb.write(2);
+    try testing.expectEqual(2, cb.read());
+}
+
+test "read position is maintained even across multiple writes" {
+    var cb = CircularBuffer(i16, 3).init();
+    try cb.write(1);
+    try cb.write(2);
+    try testing.expectEqual(1, cb.read());
+    try cb.write(3);
+    try testing.expectEqual(2, cb.read());
+    try testing.expectEqual(3, cb.read());
+}
+
+test "items cleared out of buffer can't be read" {
+    var cb = CircularBuffer(i16, 1).init();
+    try cb.write(1);
+    cb.clear();
+    try testing.expectEqual(null, cb.read());
+}
+
+test "clear frees up capacity for another write" {
+    var cb = CircularBuffer(i16, 1).init();
+    try cb.write(1);
+    cb.clear();
+    try cb.write(2);
+    try testing.expectEqual(2, cb.read());
+}
+
+test "clear does nothing on empty buffer" {
+    var cb = CircularBuffer(i16, 1).init();
+    cb.clear();
+    try cb.write(1);
+    try testing.expectEqual(1, cb.read());
+}
+
+test "overwrite acts like write on non-full buffer" {
+    var cb = CircularBuffer(i16, 2).init();
+    try cb.write(1);
+    cb.overwrite(2);
+    try testing.expectEqual(1, cb.read());
+    try testing.expectEqual(2, cb.read());
+}
+
+test "overwrite replaces the oldest item on full buffer" {
+    var cb = CircularBuffer(i16, 2).init();
+    try cb.write(1);
+    try cb.write(2);
+    cb.overwrite(3);
+    try testing.expectEqual(2, cb.read());
+    try testing.expectEqual(3, cb.read());
+}
+
+test "overwrite replaces the oldest item remaining in buffer following a read" {
+    var cb = CircularBuffer(i16, 3).init();
+    try cb.write(1);
+    try cb.write(2);
+    try cb.write(3);
+    try testing.expectEqual(1, cb.read());
+    try cb.write(4);
+    cb.overwrite(5);
+    try testing.expectEqual(3, cb.read());
+    try testing.expectEqual(4, cb.read());
+    try testing.expectEqual(5, cb.read());
+}
+
+test "initial clear does not affect wrapping around" {
+    var cb = CircularBuffer(i16, 2).init();
+    cb.clear();
+    try cb.write(1);
+    try cb.write(2);
+    cb.overwrite(3);
+    cb.overwrite(4);
+    try testing.expectEqual(3, cb.read());
+    try testing.expectEqual(4, cb.read());
+    try testing.expectEqual(null, cb.read());
+}