-
Notifications
You must be signed in to change notification settings - Fork 79
/
Copy pathconfigure.ac
1598 lines (1465 loc) · 54.5 KB
/
configure.ac
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
dnl Process this file with autoconf to produce a configure script.
AC_PREREQ([2.69])
AC_INIT([Exult],[1.11.0git],[],[exult],[https://exult.info/])
AC_CONFIG_SRCDIR([exult.cc])
# ---------------------------------------------------------------------
# System/version info
# ---------------------------------------------------------------------
# check host/target systems
# (build = system we're building on, host = system we're building for,
# target = system the program we're building will build for)
AC_CANONICAL_HOST
AC_CANONICAL_TARGET
AM_INIT_AUTOMAKE([-Wno-portability])
AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Package Name])
AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Package Version])
AC_CONFIG_HEADERS([config.h])
AC_CONFIG_MACRO_DIR([m4])
AH_BOTTOM([
#define USE_FMOPL_MIDI
])
# ---------------------------------------------------------------------
# Host system settings
# ---------------------------------------------------------------------
AC_EXEEXT
SYSLIBS=""
ICON_FILE=""
EXE_TARGET="exult$EXEEXT"
EXULT_DATADIR="$datadir/exult"
ARCH=""
# Default C anc C++ compiler set
cxx_compilers="g++ clang++ c++ gpp aCC CC cxx cc++ cl.exe FCC KCC RCC xlC_r xlC"
# determine windowing system from 'host'
AC_MSG_CHECKING([windowing system])
HOME_CFGDIR="${XDG_CONFIG_HOME:-${HOME}/.config}"
HOME_SHRDIR="${XDG_DATA_HOME:-${HOME}/.local/share}"
case "$host_os" in
linux-android*)
# Android cross compiled from Linux, supported.
AC_DEFINE(ANDROID, 1, [Using Android])
ARCH=android
AC_MSG_RESULT([Android])
CXXFLAGS="$CXXFLAGS -pthread"
;;
linux*)
# Linux, supported.
WINDOWING_SYSTEM="-DXWIN"
AC_MSG_RESULT([X11 (GNU/Linux)])
CXXFLAGS="$CXXFLAGS -pthread"
;;
mingw32*)
# Windows as MinGW, placeholder, true build by Makefile.mingw.
WINDOWING_SYSTEM="-D_WIN32"
AC_DEFINE(MINGW, 1, [Using MinGW])
AC_MSG_RESULT([Win32 (mingw32)])
CXXFLAGS="$CXXFLAGS -D_USE_MATH_DEFINES -pthread"
SYSLIBS="-luuid -lole32 -lwinmm -lstdc++ -lws2_32"
ICON_FILE="win32/exultico.o"
;;
cygwin*)
# Windows as Cygwin, placeholder, true build by Makefile.mingw.
WINDOWING_SYSTEM="-D_WIN32"
AC_DEFINE(CYGWIN, 1, [Using Cygwin])
AC_MSG_RESULT([Win32 (cygwin)])
CXXFLAGS="$CXXFLAGS -mno-cygwin -pthread"
SYSLIBS="-lwinmm"
ICON_FILE="win32/exultico.o"
;;
openbsd*)
# OpenBSD, placeholder.
WINDOWING_SYSTEM="-DXWIN"
AC_DEFINE(OPENBSD, 1, [Using OpenBSD])
AC_MSG_RESULT([X11 (OpenBSD)])
CXXFLAGS="$CXXFLAGS -pthread"
SYSLIBS="-L/usr/X11R6/lib -lX11 -lXext -lXxf86vm -lXxf86dga"
;;
freebsd*)
# FreeBSD, supported.
WINDOWING_SYSTEM="-DXWIN"
AC_DEFINE(FREEBSD, 1, [Using FreeBSD])
AC_MSG_RESULT([X11 (FreeBSD)])
CXXFLAGS="$CXXFLAGS -pthread"
;;
netbsd*)
# NetBSD, placeholder.
WINDOWING_SYSTEM="-DXWIN"
AC_MSG_RESULT([X11 (NetBSD)])
CXXFLAGS="$CXXFLAGS -pthread"
;;
solaris*)
# Solaris, placeholder.
WINDOWING_SYSTEM="-DXWIN"
AC_MSG_RESULT([X11 (Solaris)])
CXXFLAGS="$CXXFLAGS -pthread"
SYSLIBS="-lsocket"
;;
darwin*)
# MacOS as Darwin, supported.
dnl
dnl We have a problem here: both Mac OS X and Darwin report
dnl the same signature "powerpc-apple-darwin*" - so we have
dnl to do more to distinguish them. Plain Darwin will propably
dnl use X-Windows; and it is of course lacking Cocoa. For
dnl now I am lazy and do not add proper detection code.
dnl
WINDOWING_SYSTEM="-DMACOSX"
AC_DEFINE(MACOSX, 1, [Using MacOSX])
AC_MSG_RESULT([Mac OS X])
SYSLIBS="-framework CoreFoundation -framework AudioUnit -framework AudioToolbox -framework CoreMIDI"
CXXFLAGS="$CXXFLAGS -stdlib=libc++ -pthread"
EXULT_DATADIR="/Library/Application\ Support/Exult/data"
HOME_CFGDIR="${HOME}/Library/Application\ Support"
ARCH=macosx
dnl swap around clang for OSX
cxx_compilers="clang++ g++ c++ gpp aCC CC cxx cc++ cl.exe FCC KCC RCC xlC_r xlC"
;;
*)
WINDOWING_SYSTEM="-DXWIN"
AC_MSG_RESULT([not sure... guessing X11])
;;
esac
if echo $host_os | grep "cygwin\|mingw" > /dev/null 2>&1; then
AC_CHECK_TOOL([WINDRES], [windres])
if test "x$WINDRES" = "x"; then
AC_MSG_ERROR([windres could not be found, please make sure this program is within your path.])
fi
fi
AC_SUBST(WINDRES)
AM_CONDITIONAL(MACOSX, test x$ARCH = xmacosx)
AM_CONDITIONAL(ANDROID, test x$ARCH = xandroid)
# ---------------------------------------------------------------------
# Compilers and other tools
# ---------------------------------------------------------------------
AC_PROG_AWK
AC_PROG_CXX([$cxx_compilers])
AC_LANG([C++])
AX_CXX_COMPILE_STDCXX([17], [noext], [mandatory])
AC_PROG_CXXCPP
AC_PROG_INSTALL
dnl autoconf 2.69 AC_PROG_LEX has no parameters
dnl autoconf 2.70 AC_PROG_LEX prints a deprecation warning without params
m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [1], [dnl
dnl autoconf >= 2.70
AC_PROG_LEX([noyywrap])
], [
dnl autoconf < 2.70
AM_PROG_LEX
])
AC_PROG_YACC
AM_CONDITIONAL(LEXYACC, test -n "$YACC")
LT_INIT
AC_SUBST(LIBTOOL_DEPS)
# ---------------------------------------------------------------------
# Checks for integer types with specific sizes.
# ---------------------------------------------------------------------
AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, intptr_t],
[], [AC_MSG_ERROR([*** Cannot find suitably-sized signed integers!])],
[#include <cstdint>])
AC_CHECK_TYPES([uint8_t, uint16_t, uint32_t, uint64_t, uintptr_t],
[], [AC_MSG_ERROR([*** Cannot find suitably-sized unsigned integers!])],
[#include <cstdint>])
# ---------------------------------------------------------------------
# Checks for header files.
# ---------------------------------------------------------------------
AC_HEADER_DIRENT
AC_CHECK_HEADERS(limits.h sys/time.h unistd.h)
AC_CHECK_HEADERS(sys/types.h sys/socket.h netdb.h)
AC_CHECK_HEADERS(sys/wait.h signal.h getopt.h)
# ---------------------------------------------------------------------
# Checks for typedefs, structures, and compiler characteristics.
# ---------------------------------------------------------------------
AC_C_CONST
AC_C_INLINE
AC_TYPE_SIZE_T
AC_CHECK_HEADERS([sys/time.h])
AC_STRUCT_TM
# ---------------------------------------------------------------------
# Checks for library functions
# ---------------------------------------------------------------------
dnl Disabled this for now (undefined in autoconf < 2.5)
dnl AC_FUNC_MALLOC
AC_FUNC_MEMCMP
AC_CHECK_FUNCS([atexit dup2 getcwd isascii memchr memmove memset mkdir pow select socket strcasecmp strchr strstr strtol strtoul getopt_long])
AC_MSG_CHECKING([for getaddrinfo()])
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
#if HAVE_SYS_TYPES_H
#include <sys/types.h>
#endif
#if HAVE_SYS_SOCKET_H
#include <sys/socket.h>
#endif
#if HAVE_NETDB_H
#include <netdb.h>
#endif
]], [[
struct addrinfo a;
//getaddrinfo(0, 0, 0, 0);
]])],[ac_cv_func_getaddrinfo=yes],[ac_cv_func_getaddrinfo=no])
AC_MSG_RESULT($ac_cv_func_getaddrinfo)
if test x$ac_cv_func_getaddrinfo = xyes ; then
AC_DEFINE(HAVE_GETADDRINFO, 1, [Have addrinfo/getaddrinfo])
fi
AC_MSG_CHECKING([for mkstemp()])
AC_LINK_IFELSE([AC_LANG_PROGRAM([[
#if HAVE_UNISTD_H
#include <unistd.h>
#endif
#include <stdlib.h>
]], [[
mkstemp(0);
]])],[ac_cv_func_mkstemp=yes],[ac_cv_func_mkstemp=no])
AC_MSG_RESULT($ac_cv_func_mkstemp)
if test x$ac_cv_func_mkstemp = xyes ; then
AC_DEFINE(HAVE_MKSTEMP, 1, [Have mkstemp])
fi
# do we need special X11 libraries?
AC_MSG_CHECKING([for special X11 libraries])
if test x$x_libraries = xNONE; then
AC_MSG_RESULT(no)
unset x_libraries
else
x_libraries="-L$x_libraries -lX11 -lXext"
AC_MSG_RESULT($x_libraries)
AC_SUBST(x_libraries)
fi
# ---------------------------------------------------------------------
# Build Android APK?
# Note: version numbers checked in this section are known-good baselines,
# the working minimums have not been tested
# ---------------------------------------------------------------------
AM_CONDITIONAL(ANDROID_APK, false)
AC_ARG_ENABLE(android-apk, AS_HELP_STRING([--enable-android-apk=debug|release], [Build an Android APK @<:@default no@:>@]),enable_android_apk="$enableval",enable_android_apk=no)
AC_MSG_CHECKING([whether to build an Android APK])
if test x$enable_android_apk != xno; then
AC_MSG_RESULT($enable_android_apk)
# Needed to stage the sources in an out-of-tree build directory
AC_PROG_MKDIR_P
AC_PROG_LN_S
# Needed to download and patch SDL sources
AC_CHECK_PROGS(GIT, git)
if test -z "$GIT"; then
AC_MSG_ERROR([not found])
fi
AC_CHECK_PROGS(PATCH, patch)
if test -z "$PATCH"; then
AC_MSG_ERROR([not found])
fi
# Check for gradle
# TODO: any reasonable way to use the gradle bundled with android studio?
AC_CHECK_PROGS(GRADLE, gradle)
if test -z "$GRADLE"; then
AC_MSG_ERROR([not found])
fi
# Checking against a known-good baseline gradle version
AC_MSG_CHECKING([gradle version])
gradle_version=`$GRADLE --version | grep Gradle | awk '{print $2;}' | tr -d '\r\n'`
AX_COMPARE_VERSION([$gradle_version], [ge], [8.9], [dnl
dnl $gradle_version >= 8.9
AC_MSG_RESULT([found $gradle_version >= 8.9])
], [
dnl $gradle_version < 8.9
AC_MSG_ERROR([found $gradle_version < 8.9])
])
# Check for javac and java
AX_PROG_JAVAC
AX_PROG_JAVA
# Check for required Java version
AC_MSG_CHECKING([java version])
java_version=`$JAVAC -version | grep javac | awk '{print $2;}' | tr -d '\r\n'`
AX_COMPARE_VERSION([$java_version], [ge], [17], [dnl
dnl $gradle_version >= 17
AC_MSG_RESULT([found $java_version >= 17])
], [
dnl $java_version < 17
AC_MSG_ERROR([found $java_version < 17])
])
# Use sdkmanager to check Android package versions.
AC_PATH_PROGS(SDKMANAGER, sdkmanager)
# Check for required Android SDK version.
AC_ARG_WITH(android_sdk,
AS_HELP_STRING([--with-android-sdk=sdk_version], [Android SDK version @<:@default 34@:>@]),
[with_android_sdk="$withval"],[with_android_sdk=34])
ANDROID_SDK_VERSION="$with_android_sdk"
AC_MSG_CHECKING([for Android SDK $ANDROID_SDK_VERSION])
if $SDKMANAGER --list|grep -q "platforms;android-$ANDROID_SDK_VERSION"; then
AC_MSG_RESULT([yes])
else
AC_MSG_ERROR([$ANDROID_SDK_VERSION is not a valid Android SDK version.])
fi
AC_SUBST(ANDROID_SDK_VERSION, $ANDROID_SDK_VERSION)
# Check for required Android SDK Build-Tools version.
AC_ARG_WITH(android_build_tools,
AS_HELP_STRING([--with-android-build-tools=build_tools_version], [Android build tools version @<:@default 34.0.0@:>@]),
[with_android_build_tools="$withval"],[with_android_build_tools=34.0.0])
ANDROID_BUILD_TOOLS_VERSION="$with_android_build_tools"
AC_MSG_CHECKING([for Android SDK Build-Tools $ANDROID_BUILD_TOOLS_VERSION])
if $SDKMANAGER --list|grep -q "build-tools;$ANDROID_BUILD_TOOLS_VERSION"; then
AC_MSG_RESULT([yes])
else
AC_MSG_ERROR([$ANDROID_BUILD_TOOLS_VERSION is not a valid Android build tools version.])
fi
AC_SUBST(ANDROID_BUILD_TOOLS_VERSION, $ANDROID_BUILD_TOOLS_VERSION)
# Check for required Android NDK version.
AC_ARG_WITH(android_ndk,
AS_HELP_STRING([--with-android-ndk=ndk_version], [Android NDK version @<:@default 27.2.12479018@:>@]),
[with_android_sdk="$withval"],[with_android_ndk=27.2.12479018])
ANDROID_NDK_VERSION="$with_android_ndk"
AC_MSG_CHECKING([for Android NDK $ANDROID_NDK_VERSION])
if $SDKMANAGER --list|grep -q "ndk;$ANDROID_NDK_VERSION"; then
AC_MSG_RESULT([yes])
else
AC_MSG_ERROR([$ANDROID_NDK_VERSION is not a valid Android NDK version.])
fi
AC_SUBST(ANDROID_NDK_VERSION, $ANDROID_NDK_VERSION)
# Check for required Android CMake version.
AC_ARG_WITH(android_cmake,
AS_HELP_STRING([--with-android-cmake=cmake_version], [Android CMake version @<:@default 3.22.1@:>@]),
[with_android_cmake="$withval"],[with_android_cmake=3.22.1])
ANDROID_CMAKE_VERSION="$with_android_cmake"
AC_MSG_CHECKING([for Android CMake $ANDROID_CMAKE_VERSION])
if $SDKMANAGER --list|grep -q "cmake;$ANDROID_CMAKE_VERSION"; then
AC_MSG_RESULT([yes])
else
AC_MSG_ERROR([$ANDROID_CMAKE_VERSION is not a valid Android CMake version.])
fi
AC_SUBST(ANDROID_CMAKE_VERSION, $ANDROID_CMAKE_VERSION)
# Pass down SDK directory, keep _HOME and _SDK_ROOT in sync
AC_SUBST(ANDROID_HOME, `AS_DIRNAME(["$SDKMANAGER"])`/../../..)
AC_SUBST(ANDROID_SDK_ROOT, $ANDROID_HOME)
# Enable Android APK build
AM_CONDITIONAL(ANDROID_APK, true)
AC_SUBST(APK_BUILD_TYPE, $enable_android_apk)
if test x$enable_android_apk = xrelease; then
# The apk filename has an additional suffix for release builds
AC_SUBST(APK_SUFFIX, -unsigned)
fi
# The APK building uses its own build system
# so disable everything except generating the data files
if test x$enable_android_apk != xno; then
enable_exult=no
enable_tools=no
fi
# When building a debug apk, enable Exult's debug_level "messages"
# which can be overriden with "--with-debug="
if test x$enable_android_apk = xdebug; then
AC_SUBST(EXULT_ANDROID_DEBUG, messages)
fi
# Build a single Android architecture
AC_ARG_WITH(android_arch,
AS_HELP_STRING([--with-android-arch=ARCH], [Android build single arch @<:@default x86, x86_64, armeabi-v7a, arm64-v8a@:>@]),
[with_android_arch="$withval"],)
if test "x$with_android_arch" != x; then
ANDROID_ARCHITECTURE="abiFilters "\"$with_android_arch"\""
AC_SUBST(ANDROID_ARCHITECTURE, $ANDROID_ARCHITECTURE)
fi
else
AC_MSG_RESULT(no)
fi
# ---------------------------------------------------------------------
# Build Exult at all
# This is meant to facilitate building the tools on the host
# system for posterior cross-compilation
# ---------------------------------------------------------------------
AC_ARG_ENABLE(exult, AS_HELP_STRING([--enable-exult], [Build Exult @<:@default yes@:>@]),,enable_exult=yes)
# ---------------------------------------------------------------------
# Build Exult as a library?
# ---------------------------------------------------------------------
AM_CONDITIONAL(BUILD_SHAPES, false)
AC_ARG_ENABLE(libexult, AS_HELP_STRING([--enable-libexult], [Build Exult as a library @<:@default no@:>@]),,enable_libexult=no)
if test x$enable_libexult = xyes -a x$enable_exult = xno; then
AC_MSG_ERROR([*** It is not possible build Exult as a library if building Exult is disabled ***])
else
AC_MSG_CHECKING([whether to build Exult])
if test x$enable_libexult = xyes; then
AC_MSG_RESULT(as a library)
AM_CONDITIONAL(BUILD_EXULT, true)
AM_CONDITIONAL(BUILD_LIBEXULT, true)
AM_CONDITIONAL(BUILD_SHAPES, true)
elif test x$enable_exult = xyes; then
AC_MSG_RESULT(yes)
AM_CONDITIONAL(BUILD_EXULT, true)
AM_CONDITIONAL(BUILD_LIBEXULT, false)
AM_CONDITIONAL(BUILD_SHAPES, true)
else
AC_MSG_RESULT(no)
AM_CONDITIONAL(BUILD_EXULT, false)
AM_CONDITIONAL(BUILD_LIBEXULT, false)
fi
fi
# ---------------------------------------------------------------------
# Statically link libraries?
# ---------------------------------------------------------------------
AC_ARG_ENABLE(static-libraries, AS_HELP_STRING([--enable-static-libraries], [Enable static linking of libraries]),,enable_static_libs=no)
AC_MSG_CHECKING([if we want to statically compile libraries])
if test x$enable_static_libs != xno; then
if test x$ARCH != xmacosx; then
# Assuming GCC. This is probably not portable.
STATIC_LD="-static"
LDFLAGS="$LDFLAGS -static"
else
AC_MSG_ERROR([*** static linking is not supported on macOS])
fi
AC_MSG_RESULT(yes)
else
AC_MSG_RESULT(no)
fi
# ---------------------------------------------------------------------
# Check for pkg-config
# ---------------------------------------------------------------------
if test x$enable_android_apk = xno; then
PKG_PROG_PKG_CONFIG
if test x$PKG_CONFIG = x; then
AC_MSG_ERROR([*** To Build Exult 1.9+, pkg-config is required. ***])
fi
fi
# ---------------------------------------------------------------------
# SDL
# ---------------------------------------------------------------------
if test x$enable_android_apk = xno; then
PKG_CHECK_MODULES(SDL, sdl2 >= 2.0.16, , AC_MSG_ERROR([[*** SDL not found!]]))
AC_DEFINE(HAVE_SDL_H, 1, [Define to 1 if you have the "SDL.h" header file])
AM_CONDITIONAL(HAVE_SDL, true)
else
AM_CONDITIONAL(HAVE_SDL, false)
fi
# ---------------------------------------------------------------------
# libpng
# ---------------------------------------------------------------------
if test x$ARCH != xandroid; then
PKG_CHECK_MODULES(PNG, libpng, have_png=yes, have_png=no)
else
have_png=no
fi
if test x$have_png = xyes; then
AM_CONDITIONAL(HAVE_PNG, true)
AC_DEFINE(HAVE_PNG_H, 1, [Define to 1 if you have the <png.h> header file.])
else
AM_CONDITIONAL(HAVE_PNG, false)
fi
# ---------------------------------------------------------------------
# libogg, libvorbis, libvorbisfile
# ---------------------------------------------------------------------
if test x$enable_android_apk = xno -a x$enable_exult = xyes; then
PKG_CHECK_MODULES(OGG, ogg >= 1.0 vorbis >= 1.0.1 vorbisfile, , AC_MSG_ERROR([*** must have Ogg/Vorbis installed!]))
fi
# ---------------------------------------------------------------------
# Mac OS X code signing
# ---------------------------------------------------------------------
AM_CONDITIONAL(WITH_OSX_CODE_SIGNATURE, false)
AC_ARG_WITH(macosx-code-signature,
AS_HELP_STRING([--with-macosx-code-signature=identity], [identity for code signing (macOS bundles only) @<:@default "Developer ID Application"@:>@]),
[with_macosx_code_signature="$withval"],
[with_macosx_code_signature=""])
if test x$ARCH = xmacosx; then
if test x"$with_macosx_code_signature" != x; then
if test x"$with_macosx_code_signature" = xyes; then
with_macosx_code_signature="Developer ID Application"
fi
AM_CONDITIONAL(WITH_OSX_CODE_SIGNATURE, true)
OSX_CODE_SIGNATURE="$with_macosx_code_signature"
AC_SUBST(OSX_CODE_SIGNATURE)
fi
fi
AM_CONDITIONAL(WITH_OSX_INSTALLER_SIGNATURE, false)
AC_ARG_WITH(macosx-installer-signature,
AS_HELP_STRING([--with-macosx-installer-signature=identity], [identity for code signing macOS installers @<:@default "Developer ID Installer"@:>@]),
[with_macosx_installer_signature="$withval"],
[with_macosx_installer_signature=""])
if test x$ARCH = xmacosx; then
if test x"$with_macosx_installer_signature" != x; then
if test x"$with_macosx_installer_signature" = xyes; then
with_macosx_installer_signature="Developer ID Installer"
fi
AM_CONDITIONAL(WITH_OSX_INSTALLER_SIGNATURE, true)
OSX_INSTALLER_SIGNATURE="$with_macosx_installer_signature"
AC_SUBST(OSX_INSTALLER_SIGNATURE)
fi
fi
# ---------------------------------------------------------------------
# Optional components
# ---------------------------------------------------------------------
# Timidity MIDI driver
AC_ARG_ENABLE(timidity_midi, AS_HELP_STRING([--disable-timidity-midi], [Disable timidity midi support]),,enable_timidity_midi=yes)
AC_ARG_WITH(timidity, AS_HELP_STRING([--with-timidity=path], [path to timidity.cfg (optional)]),,)
AC_MSG_CHECKING([if we can use timidity midi])
if test x$enable_timidity_midi = xyes; then
AC_MSG_RESULT(yes)
AC_DEFINE(USE_TIMIDITY_MIDI, 1, [Enable timidity midi])
if test x$with_timidity != x; then
if test ! -d $with_timidity; then
with_timidity=`echo "$with_timidity" | sed 's/timidity.cfg//'`
fi
AC_DEFINE_UNQUOTED(DEFAULT_TIMIDITY_PATH, "$with_timidity", [Default timidity path])
fi
else
AC_MSG_RESULT(no)
fi
# ALSA MIDI driver
AC_ARG_ENABLE(alsa, AS_HELP_STRING([--disable-alsa], [Disable ALSA midi support]),,enable_alsa=yes)
AC_MSG_CHECKING([if we want to use alsa midi])
if test x$enable_alsa = xyes; then
AC_MSG_RESULT(yes)
PKG_CHECK_MODULES(ALSA, alsa, have_alsa=yes, have_alsa=no)
AC_MSG_CHECKING([if we can use alsa midi])
if test x$have_alsa = xyes; then
AC_MSG_RESULT(yes)
AC_DEFINE(USE_ALSA_MIDI, 1, [Enable ALSA midi])
else
AC_MSG_RESULT([no; alsa not installed])
fi
else
AC_MSG_RESULT(no)
fi
# FluidSynth and FluidLite MIDI driver
AC_ARG_ENABLE(fluidsynth,
AS_HELP_STRING([--enable-fluidsynth@<:@=yes|lite|no@:>@],
[Enable fluidsynth midi support, lite for fluidlite, @<:@default yes@:>@]),,enable_fluidsynth=yes)
AC_MSG_CHECKING([if we want to use fluidsynth midi])
if test x$enable_fluidsynth = xyes; then
AC_MSG_RESULT(yes)
PKG_CHECK_MODULES(FLUIDSYNTH, fluidsynth, have_fluidsynth=yes, have_fluidsynth=no)
PKG_CHECK_MODULES(FLUIDLITE, fluidlite, have_fluidlite=yes, have_fluidlite=no)
AC_MSG_CHECKING([if we can use fluidsynth midi])
if test x$have_fluidsynth = xyes; then
AC_MSG_RESULT(yes)
AC_DEFINE(USE_FLUIDSYNTH_MIDI, 1, [Enable fluidsynth midi])
AC_DEFINE(USING_FLUIDSYNTH, 1,[Using FluidSynth])
FLUID_CFLAGS="$FLUIDSYNTH_CFLAGS"
FLUID_LIBS="$FLUIDSYNTH_LIBS"
elif test x$have_fluidlite = xyes; then
AC_MSG_RESULT([no, using fluidlite])
AC_DEFINE(USE_FLUIDSYNTH_MIDI, 1, [Enable fluidsynth midi])
AC_DEFINE(USING_FLUIDLITE, 1,[Using FluidLite])
FLUID_CFLAGS="$FLUIDLITE_CFLAGS"
FLUID_LIBS="$FLUIDLITE_LIBS"
enable_fluidsynth=lite
else
AC_MSG_RESULT([no; fluidsynth or fluidlite not installed])
fi
elif test x$enable_fluidsynth = xlite; then
AC_MSG_RESULT([yes, using fluidlite])
PKG_CHECK_MODULES(FLUIDLITE, fluidlite, have_fluidlite=yes, have_fluidlite=no)
PKG_CHECK_MODULES(FLUIDSYNTH, fluidsynth, have_fluidsynth=yes, have_fluidsynth=no)
AC_MSG_CHECKING([if we can use fluidlite midi])
if test x$have_fluidlite = xyes; then
AC_MSG_RESULT([yes, using fluidlite])
AC_DEFINE(USE_FLUIDSYNTH_MIDI, 1, [Enable fluidsynth midi])
AC_DEFINE(USING_FLUIDLITE, 1,[Using FluidLite])
FLUID_CFLAGS="$FLUIDLITE_CFLAGS"
FLUID_LIBS="$FLUIDLITE_LIBS"
elif test x$have_fluidsynth = xyes; then
AC_MSG_RESULT([no, using fluidsynth instead])
AC_DEFINE(USE_FLUIDSYNTH_MIDI, 1, [Enable fluidsynth midi])
AC_DEFINE(USING_FLUIDSYNTH, 1,[Using FluidSynth])
FLUID_CFLAGS="$FLUIDSYNTH_CFLAGS"
FLUID_LIBS="$FLUIDSYNTH_LIBS"
enable_fluidsynth=yes
else
AC_MSG_RESULT([no; fluidlite or fluidsynth not installed])
fi
else
AC_MSG_RESULT(no)
enable_fluidsynth=no
fi
AC_SUBST([FLUID_CFLAGS])
AC_SUBST([FLUID_LIBS])
# mt32emu midi driver
AC_ARG_ENABLE(mt32emu, AS_HELP_STRING([--disable-mt32emu], [Disable mt32emu midi support]),,enable_mt32emu=yes)
AC_MSG_CHECKING([if we want to use mt32emu midi])
if test x$enable_mt32emu = xyes; then
AC_MSG_RESULT(yes)
PKG_CHECK_MODULES(MT32EMU, mt32emu, have_mt32emu=yes, have_mt32emu=no)
AC_MSG_CHECKING([if we can use mt32emu midi])
if test x$have_mt32emu = xyes; then
AC_MSG_RESULT(yes)
AC_DEFINE(USE_MT32EMU_MIDI, 1, [Enable mt32emu])
AM_CONDITIONAL(BUILD_MT32EMU, true)
else
AC_MSG_RESULT([no; mt32emu not installed])
AM_CONDITIONAL(BUILD_MT32EMU, false)
fi
else
AC_MSG_RESULT(no)
AM_CONDITIONAL(BUILD_MT32EMU, false)
fi
# dylibbundler and create-dmg on macOS
if test x$ARCH = xmacosx; then
AC_CHECK_PROG(has_dylibbundler, dylibbundler, yes)
if test x$has_dylibbundler != xyes; then
echo "Warning: Bundling a shared Exult app on macOS requires dylibbundler:"
echo " https://github.com/auriamg/macdylibbundler"
fi
AC_CHECK_PROG(has_create_dmg, create-dmg, yes)
if test x$has_create_dmg != xyes; then
echo "Warning: Creating disk images on macOS requires create-dmg:"
echo " https://github.com/create-dmg/create-dmg"
fi
fi
# zipped savegame support
AC_ARG_ENABLE(zip-support, AS_HELP_STRING([--enable-zip-support], [Enable zipped savegame support @<:@default yes@:>@]),,enable_zip_support=yes)
AC_MSG_CHECKING([if we want to use zipped savegame support])
if test x$enable_zip_support = xyes ; then
AC_MSG_RESULT(yes)
# disabled for now (non-portable):
# link statically against zlib if using gcc
# if test x$GCC = xyes ; then
# ZLIB_LIBS="-Wl,-Bstatic -lz -Wl,-Bdynamic"
# else
if test x$enable_static_libs = xno -o x$ARCH != xmacosx; then
PKG_CHECK_MODULES(ZLIB, zlib, have_zlib=yes, have_zlib=no)
else
have_zlib=yes
fi
# fi
AC_MSG_CHECKING([if we can use zipped savegame support])
if test x$have_zlib = xyes; then
AC_MSG_RESULT(yes)
AC_DEFINE(HAVE_ZIP_SUPPORT, 1, [Have zip support])
else
AC_MSG_RESULT([no; zlib not installed])
fi
else
AC_MSG_RESULT(no)
fi
# HQnX scaler
AC_ARG_ENABLE(all_hq_scalers, AS_HELP_STRING([--enable-all-hq-scalers], [Enable hq2x, hq3x, hq4x scaler support @<:@default yes@:>@]),,enable_all_hq_scalers=yes)
AC_MSG_CHECKING([if we should build all hq scalers])
if test x$enable_all_hq_scalers = xyes; then
enable_hq2x=yes
enable_hq3x=yes
enable_hq4x=yes
AC_MSG_RESULT(yes)
else
AC_MSG_RESULT(no)
fi
# HQ2X scaler
AC_ARG_ENABLE(hq2x, AS_HELP_STRING([--enable-hq2x],[Enable hq2x scaler support @<:@default no@:>@]),,enable_hq2x=no)
AC_MSG_CHECKING(if we should build the hq2x scaler)
if test x$enable_hq2x = xyes; then
AC_MSG_RESULT(yes)
AC_DEFINE(USE_HQ2X_SCALER, 1, [Build hq2x scaler])
else
AC_MSG_RESULT(no)
fi
# HQ3X scaler
AC_ARG_ENABLE(hq3x, AS_HELP_STRING([--enable-hq3x],[Enable hq3x scaler support @<:@default no@:>@]),,enable_hq3x=no)
AC_MSG_CHECKING(if we should build the hq3x scaler)
if test x$enable_hq3x = xyes; then
AC_MSG_RESULT(yes)
AC_DEFINE(USE_HQ3X_SCALER, 1, [Build hq3x scaler])
else
AC_MSG_RESULT(no)
fi
# HQ4X scaler
AC_ARG_ENABLE(hq4x, AS_HELP_STRING([--enable-hq4x],[Enable hq4x scaler support @<:@default no@:>@]),,enable_hq4x=no)
AC_MSG_CHECKING(if we should build the hq4x scaler)
if test x$enable_hq4x = xyes; then
AC_MSG_RESULT(yes)
AC_DEFINE(USE_HQ4X_SCALER, 1, [Build hq4x scaler])
else
AC_MSG_RESULT(no)
fi
# NxBR scalers
AC_ARG_ENABLE(nxbr, AS_HELP_STRING([--enable-nxbr],[Enable 2xBR, 3xBR and 4xBR scaler support @<:@default yes@:>@]),,enable_nxbr=yes)
AC_MSG_CHECKING([if we should build the 2xBR, 3xBR and 4xBR scalers])
if test x$enable_nxbr = xyes; then
AC_MSG_RESULT(yes)
AC_DEFINE(USE_XBR_SCALER, 1, [Build NxBR scalers])
else
AC_MSG_RESULT(no)
fi
# Midi Sfx
AC_ARG_ENABLE(midi-sfx, AS_HELP_STRING([--enable-midi-sfx], [Support for Midi Sfx (sounds horrible) @<:@default no@:>@]),,enable_midi_sfx=no)
AC_MSG_CHECKING([whether to enable midi sfx])
if test x$enable_midi_sfx = xyes; then
AC_DEFINE(ENABLE_MIDISFX, 1, [Enable Midi Sfx])
AC_MSG_RESULT(yes)
else
AC_MSG_RESULT(no)
fi
# ---------------------------------------------------------------------
# Exult Studio
# ---------------------------------------------------------------------
AC_ARG_ENABLE(exult-studio, AS_HELP_STRING([--enable-exult-studio], [Build Exult Studio @<:@default no@:>@]),,enable_exult_studio=no)
if test x$enable_android_apk = xyes; then
enable_exult_studio=no
fi
# library dependencies
AC_MSG_CHECKING([if we want to build Exult Studio])
if test x$enable_exult_studio = xyes; then
AC_MSG_RESULT(yes)
# Icu
PKG_CHECK_MODULES(ICU, icu-uc, have_icu=yes, have_icu=no)
# Gtk
PKG_CHECK_MODULES(GTK, gtk+-3.0 >= 3.16, have_gtk=yes, have_gtk=no)
# Freetype2 (optional, used in ExultStudio, shapes/fontgen.cc)
PKG_CHECK_MODULES(FREETYPE2, freetype2, have_freetype=yes, have_freetype=no)
if test x$have_freetype = xyes; then
AC_DEFINE(HAVE_FREETYPE2, 1, [Have freetype2])
fi
else
AC_MSG_RESULT(no)
fi
# Exult Studio
if test x$enable_exult_studio = xyes; then
AC_MSG_CHECKING([if we can build Exult Studio])
if test x$have_gtk = xno; then
AC_MSG_RESULT([no; gtk+ is not installed])
echo "Exult Studio requires the GTK+ (aka the GIMP Tool Kit), but it is not installed."
echo "Please try again, either with the GTK+ installed as 3.16 or newer, or with '--disable-exult-studio'."
exit 1
fi
if test x$have_icu = xno; then
AC_MSG_RESULT([no; icu is not installed])
echo "Exult Studio requires the ICU (aka the International Components for Unicode), but it is not installed."
echo "Please try again, either with the ICU installed, or with '--disable-exult-studio'."
exit 1
fi
if test x$have_png = xno; then
AC_MSG_RESULT([no; libpng is not installed])
echo "Exult Studio requires the PNG (aka the Portable Network Graphics), but it is not installed."
echo "Please try again, either with the PNG installed, or with '--disable-exult-studio'."
exit 1
fi
if test x$ARCH = xmacosx; then
AC_MSG_RESULT(yes)
AC_CHECK_PROG(has_gtk_mac_bundler, gtk-mac-bundler, yes)
if test x$has_gtk_mac_bundler != xyes; then
echo "Warning: Bundling Exult Studio on macOS requires GTK Mac Bundler"
echo " https://gitlab.gnome.org/GNOME/gtk-mac-bundler"
fi
else
AC_MSG_RESULT(yes)
fi
AM_CONDITIONAL(BUILD_STUDIO, true)
AM_CONDITIONAL(BUILD_SHAPES, true)
else
AM_CONDITIONAL(BUILD_STUDIO, false)
fi
# support for Exult Studio
AC_ARG_ENABLE(exult-studio-support, AS_HELP_STRING([--enable-exult-studio-support], [Build Exult Studio support into Exult @<:@default no@:>@]),,enable_exult_studio_support=no)
AC_MSG_CHECKING([if we want to build support for Exult Studio])
if test x$enable_exult_studio_support = xyes -o x$enable_exult_studio = xyes; then
# Implicitly, --enable-exult-studio drags --enable-exult-studio-support
enable_exult_studio_support=yes
AC_MSG_RESULT(yes)
AC_MSG_CHECKING([if we can build support for Exult Studio])
if test "$WINDOWING_SYSTEM" != -DXWIN -a "$WINDOWING_SYSTEM" != -D_WIN32 -a "$WINDOWING_SYSTEM" != -DMACOSX; then
AC_MSG_RESULT([no; windowing system "$WINDOWING_SYSTEM" not supported])
enable_exult_studio_support=no
else
AC_MSG_RESULT(yes)
AC_DEFINE(USE_EXULTSTUDIO, 1, [Use Exult Studio])
fi
else
AC_MSG_RESULT(no)
fi
# ---------------------------------------------------------------------
# External features
# ---------------------------------------------------------------------
# Build any external programs?
AM_CONDITIONAL(HAVE_SDL_IMAGE, false)
AC_ARG_ENABLE(tools, AS_HELP_STRING([--disable-tools], [Only build the main program]),,enable_tools=yes)
AC_MSG_CHECKING([whether to build only the main program])
if test x$enable_tools = xno; then
AC_MSG_RESULT(yes)
AM_CONDITIONAL(BUILD_TOOLS, false)
enable_gimp_plugin=no
enable_compiler=no
else
AM_CONDITIONAL(BUILD_TOOLS, true)
AC_MSG_RESULT(no)
PKG_CHECK_MODULES(SDL_IMAGE, SDL2_image, have_sdl_image=yes, have_sdl_image=no)
if test x$have_sdl_image = xyes; then
AM_CONDITIONAL(HAVE_SDL_IMAGE, true)
else
AC_MSG_WARN([Unable to find SDL2_image library (https://github.com/libsdl-org/SDL_image)])
AC_MSG_WARN([Tools mockup and smooth disabled])
fi
fi
# Build compiler?
AC_ARG_ENABLE(compiler, AS_HELP_STRING([--enable-compiler], [Build the usecode compiler @<:@default no@:>@]),,enable_compiler=no)
AC_MSG_CHECKING([whether to build the usecode compiler])
if test x$enable_compiler = xno; then
AC_MSG_RESULT(no)
AM_CONDITIONAL(BUILD_COMPILER, false)
else
AC_MSG_RESULT(yes)
AM_CONDITIONAL(BUILD_COMPILER, true)
fi
# Build data files?
AC_ARG_ENABLE(data, AS_HELP_STRING([--enable-data], [Create the data files @<:@default yes@:>@]),,enable_data=yes)
AC_MSG_CHECKING([whether to build the data files])
if test x$enable_data = xno; then
AC_MSG_RESULT(no)
AM_CONDITIONAL(DATA_FILES, false)
else
AM_CONDITIONAL(DATA_FILES, true)
AC_MSG_RESULT(yes)
fi
# Build mods?
AC_ARG_ENABLE(mods, AS_HELP_STRING([--enable-mods], [Build the Exult mods (requires usecode compiler) @<:@default no@:>@]),,enable_mods=no)
AC_MSG_CHECKING([whether to build the Exult mods])
if test x$enable_mods = xno -o x$enable_compiler = xno; then
AC_MSG_RESULT(no)
AM_CONDITIONAL(BUILD_MODS, false)
else
AM_CONDITIONAL(BUILD_MODS, true)
AC_MSG_RESULT(yes)
fi
# Usecode debugger
AC_ARG_WITH([usecode-debugger],
AS_HELP_STRING([--with-usecode-debugger=no|console|yes],
[Experimental and buggy support for usecode debugging @<:@default no@:>@]),
[enable_usecode_debugger="$withval"], [enable_usecode_debugger="no"])
AC_MSG_CHECKING([whether to enable the usecode debugger])
if test x$enable_usecode_debugger = xconsole -o x$enable_usecode_debugger = xyes; then
AC_MSG_RESULT(yes)
if test x$enable_usecode_debugger = xconsole; then
AC_DEFINE(USECODE_CONSOLE_DEBUGGER, 1, [Enable Usecode debugging on console])
elif test x$enable_exult_studio != xyes; then
echo "But we are not building Exult Studio."
echo "Please try again, either with '--enable-exult-studio', or without the usecode debugger"
exit 1
elif test x$enable_exult_studio_support != xyes; then
echo "But we are not building Exult with Exult Studio support."
echo "Please try again, either with '--enable-exult-studio-support', or without the usecode debugger"
exit 1
fi
AC_DEFINE(USECODE_DEBUGGER, 1, [Enable Usecode debugging])
else
AC_MSG_RESULT(no)
fi
# Usecode container
AC_ARG_ENABLE(usecode-container, AS_HELP_STRING([--enable-usecode-container], [Enable display of usecode container for debugging purposes @<:@default no@:>@]),,enable_usecode_container=no)
AC_MSG_CHECKING([whether to display the usecode container in Gumps])
if test x$enable_usecode_container = xyes; then
AC_MSG_RESULT(yes)
AC_DEFINE(SHOW_USECODE_CONTAINER, 1, [Display Usecode container])
else
AC_MSG_RESULT(no)
fi
# Show non-readied objects
AC_ARG_ENABLE(nonreadied-objects, AS_HELP_STRING([--enable-nonreadied-objects], [Enable display of non-readied objects for debugging purposes @<:@default no@:>@]),,enable_nonreadied_objects=no)
AC_MSG_CHECKING([whether to display non-readied objects in Gumps])
if test x$enable_nonreadied_objects = xyes; then
AC_MSG_RESULT(yes)
AC_DEFINE(SHOW_NONREADIED_OBJECTS, 1, [Display non-readied objects])
else
AC_MSG_RESULT(no)
fi
# shp-thumbnailer
AC_ARG_ENABLE(shp-thumbnailer, AS_HELP_STRING([--enable-shp-thumbnailer@<:@=yes|system|local|user|ingame|no@:>@],
[Build Exult SHP Thumbnailer, yes or system and local for system (local) install (requires root), user for user install, ingame for Exult ingame install (requires XDG_DATA_DIRS) @<:@default no@:>@]),,enable_shp_thumbnailer=no)
AC_MSG_CHECKING([if we want to build the Exult SHP Thumbnailer])
if test x$enable_shp_thumbnailer != xno; then
AC_MSG_RESULT(yes)
# needs Gdk-Pixbuf
PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0, have_gdk_pixbuf=yes, have_gdk_pixbuf=no)
AC_MSG_CHECKING([if we can build the Exult SHP Thumbnailer])
if test x$have_gdk_pixbuf = xno; then
AC_MSG_RESULT([no; gdk-pixbuf is not installed])
echo "The Exult shp thumbnailer requires Gdk-Pixbuf."
echo "Please try again, either with Gdk-Pixbuf-2.0, or with '--disable-shp-thumbnailer'."
exit 1
fi
if test x$have_png = xno; then
AC_MSG_RESULT([no; libpng is not installed])
echo "The Exult shp thumbnailer requires the PNG (aka the Portable Network Graphics)."
echo "Please try again, either with the PNG installed, or with '--disable-shp-thumbnailer'."
exit 1
fi
AC_MSG_RESULT(yes)
AM_CONDITIONAL(BUILD_EXULT_THUMB, true)
if test x$enable_shp_thumbnailer == xlocal; then
EXULT_THUMB_PREFIX="/usr/local/share"
elif test x$enable_shp_thumbnailer == xuser; then
EXULT_THUMB_PREFIX="${HOME_SHRDIR}"
elif test x$enable_shp_thumbnailer == xingame; then
EXULT_THUMB_PREFIX="${datadir}"
else
EXULT_THUMB_PREFIX="/usr/share"
fi
AC_SUBST(EXULT_THUMB_PREFIX)
else
AM_CONDITIONAL(BUILD_EXULT_THUMB, false)
AC_MSG_RESULT(no)
fi
# Aseprite plugin
AM_CONDITIONAL(BUILD_ASEPRITE_PLUGIN, false)
AC_ARG_ENABLE(aseprite-plugin,
AS_HELP_STRING([--enable-aseprite-plugin], [Build the Aseprite plugin @<:@default no@:>@]),, enable_aseprite_plugin=no)
AC_MSG_CHECKING([whether to build the Aseprite plugin])
if test x$enable_aseprite_plugin = xyes; then
AC_MSG_RESULT(yes)
if test x$have_png = xno; then
echo "The Aseprite Plugin requires the PNG (aka the Portable Network Graphics)."
echo "Please try again, either with the PNG installed, or with '--disable_aseprite_plugin'."
exit 1
fi
AM_CONDITIONAL(BUILD_ASEPRITE_PLUGIN, true)
else
AC_MSG_RESULT(no)
fi