Installing FDS flake on NixOS

[Jacob577]

FDS flake on NixOS

My servers all run NixOS because of a variety of reasons, however, a clean install of FDS would be using flakes and building from source. I figured, if I have this problem, there might be others as well, so please find the solution below to a problem others might have when installing FSD on NixOS:

Add as a normal flake flake.nix.

{
  description = "Fire Dynamics Simulator (FDS) from NIST";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.11";
  };

  outputs = { self, nixpkgs }:
    let
      system = "x86_64-linux";
      pkgs = import nixpkgs { inherit system; };
    in {
      packages.${system} = rec {
        fds = pkgs.stdenv.mkDerivation rec {
          pname = "fds";
          version = "6.9.1"; #Update to your version

          src = pkgs.fetchFromGitHub {
            owner = "firemodels";
            repo = "fds";
            rev = "FDS-${version}";
            hash = "sha256-hHK0vQytlN98g3nYxgWXvJ4wZtCuELksdRt5VAs6YGU="; #Update to your download specific hash
          };

          nativeBuildInputs = with pkgs; [
            bash
            gfortran
            openmpi
            which
          ];

          postPatch = ''
            substituteInPlace Build/makefile \
              --replace-fail "/bin/bash" "${pkgs.bash}/bin/bash"
          '';

          buildPhase = ''
            runHook preBuild

            cd Build/ompi_gnu_linux
            make -j4 VPATH="../../Source" -f ../makefile ompi_gnu_linux

            runHook postBuild
          '';

          installPhase = ''
            runHook preInstall

            mkdir -p $out/bin

            if [ ! -x ./fds_ompi_gnu_linux ]; then
              echo "Expected binary not found in $(pwd)"
              ls -la
              exit 1
            fi

            install -m755 ./fds_ompi_gnu_linux $out/bin/fds

            runHook postInstall
          '';

          meta = with pkgs.lib; {
            description = "Fire Dynamics Simulator (FDS)";
            homepage = "https://pages.nist.gov/firemodels/fds/";
            license = licenses.publicDomain;
            platforms = platforms.linux;
            mainProgram = "fds";
          };
        };

        default = fds;
      };
    };
}

The reason I run NixOS on my simulation machines is that it is reproducible everywhere on everything, nearly unbreakable and hard to bloat, hence it is somewhat guaranteed to last longer than other Linux installs. They tend to get progressively more bloated as people are testing other software without deleting or without adequate garbage collection.

Thanks for your time and consideration,

Action I wish from the FDS team are essentially none, the code is here for others to use and I'll happily share this to potentially help out the team creating the beloved Fire Dynamics Simulator.