tiny-ton/CMakeLists.txt at main · ganeshnj/tiny-ton · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
cmake_minimum_required(VERSION 3.20)
project(tiny-ton LANGUAGES CXX C)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

# --- LLVM / MLIR -----------------------------------------------------------
find_package(MLIR REQUIRED CONFIG)
find_package(LLVM REQUIRED CONFIG)

# LLVM 18 from apt.llvm.org exports zstd::libzstd_shared but libzstd-dev may
# not be installed.  Manually define the cmake target if the .so is present.
if(NOT TARGET zstd::libzstd_shared)
  find_library(ZSTD_LIB NAMES zstd zstd.so.1 libzstd.so.1.4.8
               HINTS /usr/lib/aarch64-linux-gnu)
  if(ZSTD_LIB)
    add_library(zstd::libzstd_shared SHARED IMPORTED)
    set_target_properties(zstd::libzstd_shared PROPERTIES
      IMPORTED_LOCATION "${ZSTD_LIB}")
    message(STATUS "Defined zstd::libzstd_shared -> ${ZSTD_LIB}")
  endif()
endif()

message(STATUS "Using MLIRConfig.cmake in: ${MLIR_DIR}")
message(STATUS "Using LLVMConfig.cmake in: ${LLVM_DIR}")

set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/bin)
set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/lib)
set(MLIR_BINARY_DIR ${CMAKE_BINARY_DIR})

list(APPEND CMAKE_MODULE_PATH "${MLIR_CMAKE_DIR}")
list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_DIR}")

include(TableGen)
include(AddLLVM)
include(AddMLIR)
include(HandleLLVMOptions)

include_directories(${LLVM_INCLUDE_DIRS})
include_directories(${MLIR_INCLUDE_DIRS})
include_directories(${PROJECT_SOURCE_DIR}/include)
include_directories(${PROJECT_BINARY_DIR}/include)

# --- CUDA (optional) --------------------------------------------------------
option(TTN_ENABLE_CUDA "Build CUDA/PTX backend for real GPU execution" OFF)
if(TTN_ENABLE_CUDA)
  find_package(CUDAToolkit REQUIRED)
  message(STATUS "CUDA toolkit found: ${CUDAToolkit_LIBRARY_DIR}")
  add_compile_definitions(TTN_ENABLE_CUDA)
endif()

# --- Sub-projects -----------------------------------------------------------
add_subdirectory(include)
add_subdirectory(lib)
add_subdirectory(tools)

# --- pybind11 bindings (optional) -------------------------------------------
option(TTN_ENABLE_PYTHON "Build Python bindings via pybind11" ON)
if(TTN_ENABLE_PYTHON)
  add_subdirectory(bindings)
endif()

# --- Testing (optional) -----------------------------------------------------
option(TTN_ENABLE_TESTS "Enable tests" ON)
if(TTN_ENABLE_TESTS)
  enable_testing()
  add_subdirectory(test)
endif()