build.gradle

/*
 * Copyright 2024 Broadcom. All rights reserved.
 */

plugins {
  id 'java-library'
  id 'distribution'
  id 'maven-publish'
  id 'org.jreleaser' version '1.17.0'
}

// COMPILE THINGS ////////////////////////////////////////////

import groovy.xml.*
import org.gradle.util.VersionNumber

targetCompatibility = '1.8'

group 'dev.gemfire'
version '0.1.5'

ext {
  gemfireVersion = '10.1.1'
}

repositories {
  mavenCentral()

  maven {
    name = 'Broadcom Repository'
    url = project.findProperty("commercialRepository") ?: "https://packages.broadcom.com/artifactory/gemfire"
    credentials {
      username = System.getenv("COMMERCIAL_MAVEN_USERNAME")
      password = System.getenv("COMMERCIAL_MAVEN_PASSWORD")
    }
  }
}

java {
  withSourcesJar()
  withJavadocJar()
}

test {
  useJUnit()
  testLogging {
    lifecycle {
      events("passed", "skipped", "failed")
      exceptionFormat = "full"
    }
  }
}

configurations {
  distribution
  implementation.extendsFrom(distribution)
}

dependencies {
  api("com.vmware.gemfire:gemfire-core:${gemfireVersion}")

  implementation("com.vmware.gemfire:gemfire-membership:${gemfireVersion}")
  implementation("com.vmware.gemfire:gemfire-logging:${gemfireVersion}")
  implementation("com.vmware.gemfire:gemfire-log4j:${gemfireVersion}")

  distribution('org.apache.commons:commons-collections4:4.4')

  testImplementation('org.assertj:assertj-core:3.24.2')
  testImplementation("com.vmware.gemfire:gemfire-junit:${gemfireVersion}")
  testImplementation("com.vmware.gemfire:gemfire-dunit:${gemfireVersion}")
}

final jbossModuleName = "${project.group}.${project.name}:${VersionNumber.parse(project.version).major}"
tasks.register("generateModuleXml") { task ->
  final file = file(task.temporaryDir.toPath().resolve("module.xml"))
  doLast {
    file.withWriter { writer ->
      def xml = new MarkupBuilder(new IndentPrinter(writer, "  ", true))
      xml.doubleQuotes = true
      xml.mkp.xmlDeclaration(version: '1.0', encoding: 'utf-8')
      xml.module(xmlns: 'urn:jboss:module:1.9', 'name': jbossModuleName) {
        resources {
          'resource-root'('path': tasks.named('jar').get().outputs.files.singleFile.name)
          configurations.distribution.files.forEach() { dep ->
            'resource-root'('path': dep.name)
          }
        }
        delegate.dependencies {
          module('name': 'java.se', 'export': 'false', 'optional': 'false', 'services': 'import')
          module('name': 'gemfire', 'export': 'false', 'optional': 'false', 'services': 'import')
        }
      }
    }
  }
  outputs.file(file)
}

// BUNDLING THINGS ////////////////////////////////

distributions {
  extension {
    distributionBaseName = distributionPrefix
    contents {
      with copySpec {
        into(jbossModuleName.replaceAll('[.:]', '/'))
        from(jar)
        from(configurations.distribution)
        from(generateModuleXml)
      }
      with copySpec {
        from('src/main/dist')
      }
    }
  }
}

// RELEASE THINGS ////////////////////////////////

jreleaser {
  project {
    description = 'GemFire Distributed Types'
    copyright = 'Copyright 2024 Broadcom. All rights reserved.'
    website = 'must not be blank'
    docsUrl = 'must not be blank'
    license = 'must not be blank'
    authors = ['must not be blank']
  }
  signing {
    active = 'ALWAYS'
    armored = true
    verify = false
    mode = 'COMMAND'
  }

  deploy {
    maven {
      mavenCentral {
        sonatype {
          active = 'ALWAYS'
          url = 'https://central.sonatype.com/api/v1/publisher'
          stagingRepository('build/staging-deploy')
          applyMavenCentralRules = true
          stage = 'UPLOAD'
        }
      }
    }
  }

  distributions {
    extension {
      distributionType = 'BINARY'
      artifact {
        path = "build/distributions/gemfire-distributed-types-{{projectVersion}}.gfm"
      }
    }
  }

  release {
    github {
      repoOwner = 'gemfire'
      name = 'gemfire-distributed-types'
      draft = true
      skipTag = false
    }
  }
}

publishing {
  publications {
    maven(MavenPublication) {
      pom {
        name = "${project.group}:${project.name}"
        description = 'A collection of distributed types for use wih GemFire'
        url = 'https://github.com/gemfire/gemfire-distributed-typed'
        developers {
          developer {
            name = 'Jens Deppe'
            email = 'jens.deppe@broadcom.com'
            organization = 'Broadcom'
            organizationUrl = 'https://broadcom.com'
          }
        }
        licenses {
          license {
            name = 'The Apache License, Version 2.0'
            url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
          }
        }
        scm {
          url = 'https://github.com/gemfire/gemfire-distributed-types'
          connection = 'scm:git:git://github.com/gemfire/gemfire-distributed-types.git'
          developerConnection = 'scm:git:ssh://github.com:gemfire/gemfire-distributed-types.git'
        }
      }

      from components.java
      artifact tasks.named('extensionDistZip')
    }
  }

  repositories {
    maven {
      url = layout.buildDirectory.dir('staging-deploy')
    }
  }
}

extensionDistZip {
  eachFile { file ->
    String path = file.relativePath
    file.setPath(path.substring(path.indexOf("/")+1,path.length()))
  }
  archiveExtension.set("gfm")
}

javadoc {
  configure( options ) {
    tags(
        'todo:X"',
        'apiNote:a:API Note:',
        'implSpec:a:Implementation Requirements:',
        'implNote:a:Implementation Note:'
    )
  }
}