media-sound/lms: add 3.77.0

Signed-off-by: David Roman <stkw0@disroot.org>

Author: stkw0

media-sound/lms/Manifest

@@ -1 +1,2 @@
 DIST lms-3.76.0.tar.gz 639354 BLAKE2B 9d7dace2caafcb7fab06945e2c4e4eacb6a7d5eebb36ef6cfeb2180240a1cfb5bef94771cc19e839d159aa99750136dc675f40aa12692ede50d4be3622b81709 SHA512 f04402f79650f2b41f59e6bd52d65a5dad16e6537521c8fcb4356d9d131f4e4b57c4b8635f61ec58f11ae38b370d7d1720287d8ac1d3b117e1d4f3b047b2b763
+DIST lms-3.77.0.tar.gz 3611834 BLAKE2B d5defb4e133b9278bd0be0db7259199c540140af4bb139e36efe97b58ecb509f9a015a307a3c994bad7fdd5617451c25c90a5d93d25ef653881ff9a12b85cd0b SHA512 4448707a92e7049dd11fbe59af58d059c965a5b61d13ea9382acf858c1df0a70e8f4d395ff84e067615a8591026595943119495ef1c8bb03de4099c99efc4285

media-sound/lms/lms-3.77.0.ebuild

@@ -0,0 +1,70 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake pam systemd
+
+DESCRIPTION="Lightweight Music Server."
+HOMEPAGE="https://lms-demo.poupon.dev/ https://github.com/epoupon/lms"
+SRC_URI="https://github.com/epoupon/lms/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test jukebox +stb"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-arch/libarchive
+	acct-user/lms
+	dev-cpp/wt:=
+	dev-libs/boost:=
+	dev-libs/libconfig[cxx]
+	dev-libs/pugixml:=
+	media-libs/taglib:=
+	media-video/ffmpeg[lame,opus]
+	sys-libs/pam
+
+	jukebox? ( media-libs/libpulse )
+	!stb? ( media-gfx/graphicsmagick )
+
+"
+
+DEPEND="
+	${RDEPEND}
+	dev-libs/xxhash
+	stb? ( dev-libs/stb )
+"
+
+BDEPEND="
+	test? ( dev-cpp/gtest )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DLMS_IMAGE_BACKEND=$(usex stb stb graphicsmagick)
+		-DENABLE_TESTS=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	systemd_newunit conf/systemd/default.service lms.service
+	newinitd "${FILESDIR}/lms.init" lms
+	dopamd conf/pam/lms
+	mv "${ED}/usr/share/lms/lms.conf" "${ED}/etc/lms.conf" || die
+
+	# Already installed in the proper directory
+	rm "${ED}/usr/share/lms/default.service" || die
+	rm "${ED}/usr/share/lms/lms" || die
+
+	keepdir /var/log/lms
+	fowners -R lms:lms /var/log/lms
+
+	keepdir /var/lms
+	fowners lms:lms /var/lms
+}