build.gradle

plugins {
    id 'net.fabricmc.fabric-loom' version '1.15.+'
    id 'maven-publish'
}

base.archivesName = project.archives_base_name
version = project.mod_version
group = project.maven_group

repositories {
    // Add repositories to retrieve artifacts from in here.
    // You should only use this when depending on other mods because
    // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
    // See https://docs.gradle.org/current/userguide/declaring_repositories.html
    // for more information about repositories.

    // For Mixin Squared
    maven { url = "https://maven.gnomecraft.net/releases" }
}

dependencies {
    // To change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    implementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Fabric API.  Very required since we require and mixin to FTAPI.
    implementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    // Mixin Squared to allow us to mixin directly to FTAPI's HBE mixin.
    include(implementation(annotationProcessor("com.github.bawnorton.mixinsquared:mixinsquared-fabric:${project.mixin_squared_version}")))
}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.release = 25
}

java {
    // If you remove this line, sources will not be generated.
    withSourcesJar()

    sourceCompatibility = JavaVersion.VERSION_25
    targetCompatibility = JavaVersion.VERSION_25
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.base.archivesName}"}
    }
}

// configure the maven publication
publishing {
    publications {
        create("mavenJava", MavenPublication) {
            groupId    = "${project.maven_group}"
            artifactId = "${project.archives_base_name}"
            version    = "${project.mod_version}"
            from components.java
        }
    }

    // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
    repositories {
        // Add repositories to publish to here.
        // Notice: This block does NOT have the same function as the block in the top level.
        // The repositories here will be used for publishing your artifact, not for
        // retrieving dependencies.

        maven { url = 'https://maven.gnomecraft.net/releases'
            credentials {
                username = project.findProperty("gpr.user") ?: System.getenv("GNOMECRAFT_USERNAME")
                password = project.findProperty("gpr.key") ?: System.getenv("GNOMECRAFT_TOKEN")
            }
        }
    }
}