Add analysis test

Signed-off-by: Luca Della Vedova <lucadv@intrinsic.ai>

Author: luca-della-vedova

test/BUILD.bazel

@@ -14,6 +14,7 @@ load("@workspace_default_features//:data.bzl", workspace_default_features_dep_da
 load("@workspace_hyphen_dep_aliases//:defs.bzl", workspace_hyphen_dep_aliases_aliases = "aliases")
 load("@workspace_renamed_path_dep_aliases//:defs.bzl", workspace_renamed_path_dep_aliases_aliases = "aliases")
 load("//:rustdoc_musl_unwind_test.bzl", "rustdoc_musl_unwind_link_flags_test")
+load("//:self_contained_linker_test.bzl", "self_contained_linker_aarch64_test", "self_contained_linker_x86_64_test")
 load("//:target_triple_constraints_test.bzl", "target_triple_constraints_test")
 load("//:verify_aliases.bzl", "verify_alias", "verify_alias_absent", "verify_crate_feature_absent", "verify_crate_feature_present", "verify_dep_absent", "verify_dep_present", "verify_dev_dep_absent")
 load("//:workspace_lints_test.bzl", "inherited_workspace_lints_test", "opted_out_workspace_lints_test", "package_lints_test")
@@ -36,6 +37,23 @@ sh_test(
     }),
 )
 
+rust_binary(
+    name = "self_contained_linker_sample_bin",
+    srcs = ["main.rs"],
+    edition = "2021",
+    tags = ["manual"],
+)
+
+self_contained_linker_x86_64_test(
+    name = "self_contained_linker_x86_64_test",
+    target_under_test = ":self_contained_linker_sample_bin",
+)
+
+self_contained_linker_aarch64_test(
+    name = "self_contained_linker_aarch64_test",
+    target_under_test = ":self_contained_linker_sample_bin",
+)
+
 cc_library(
     name = "rustdoc_musl_unwind_cc",
     srcs = ["rustdoc_musl_unwind.cc"],

test/self_contained_linker_test.bzl

@@ -0,0 +1,40 @@
+"""Analysis test verifying that Linux targets include rust-lld/gcc-ld in action inputs."""
+
+load("@bazel_skylib//lib:unittest.bzl", "analysistest", "asserts")
+
+def _get_action_by_mnemonic(env, tut, mnemonic):
+    actions = [action for action in tut.actions if action.mnemonic == mnemonic]
+    asserts.equals(
+        env,
+        1,
+        len(actions),
+        "Expected exactly one {} action, got {}".format(mnemonic, [action.mnemonic for action in tut.actions]),
+    )
+    return actions[0]
+
+def _self_contained_linker_inputs_test_impl(ctx):
+    env = analysistest.begin(ctx)
+    tut = analysistest.target_under_test(env)
+    action = _get_action_by_mnemonic(env, tut, "Rustc")
+
+    input_basenames = [f.basename for f in action.inputs.to_list()]
+    asserts.true(
+        env,
+        "rust-lld" in input_basenames,
+        "Expected 'rust-lld' in Rustc action inputs for Linux target, but it was missing.",
+    )
+    return analysistest.end(env)
+
+self_contained_linker_x86_64_test = analysistest.make(
+    _self_contained_linker_inputs_test_impl,
+    config_settings = {
+        "//command_line_option:platforms": str(Label("@rules_rs//rs/platforms:x86_64-unknown-linux-gnu")),
+    },
+)
+
+self_contained_linker_aarch64_test = analysistest.make(
+    _self_contained_linker_inputs_test_impl,
+    config_settings = {
+        "//command_line_option:platforms": str(Label("@rules_rs//rs/platforms:aarch64-unknown-linux-gnu")),
+    },
+)