lesscss-gradle-plugin/build.gradle at master · houbie/lesscss-gradle-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
/*
 * Copyright (c) 2014 Houbrechts IT
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.github.townsfolk:gradle-release:1.2'
    }
}

apply plugin: 'groovy'
apply plugin: 'maven'
apply plugin: 'signing'
apply plugin: 'release'

version = file('version.txt').text.split('=')[1].trim()
group = 'com.github.houbie'

sourceCompatibility = 1.6
targetCompatibility = 1.6

repositories {
    mavenCentral()
}

dependencies {
    compile localGroovy()
    compile gradleApi()
	compile 'com.github.houbie:lesscss:1.3.2-less-1.7.0'
    testCompile 'org.spockframework:spock-core:0.7-groovy-1.8'
}

jar {
    from 'LICENSE', 'NOTICE'
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allSource
    classifier = 'sources'
}

artifacts {
    archives jar
    archives javadocJar
    archives sourcesJar
}

//********* artifact signing and publishing *********

task uploadSnapshot(description: 'Uploads a snapshot to the Sonatype repository', dependsOn: uploadArchives)

// the release task spawns a new GradleBuild that doesn't contain release itself, but it contains createReleaseTag
def sonatypeRelease = gradle.startParameter.taskNames.contains('createReleaseTag')
def sonatypeSnapshot = gradle.startParameter.taskNames.contains('uploadSnapshot')
if (sonatypeRelease) {
    signing {
        sign configurations.archives
    }
}
def sonatypeRepositoryUrl = sonatypeRelease ? 'https://oss.sonatype.org/service/local/staging/deploy/maven2/' : 'https://oss.sonatype.org/content/repositories/snapshots/'

uploadArchives {
    repositories {
        if (!(sonatypeRelease || sonatypeSnapshot)) {
            mavenLocal()
        } else {
            mavenDeployer {
                if (sonatypeRelease) {
                    beforeDeployment { deployment -> signing.signPom(deployment) }
                }

                repository(url: sonatypeRepositoryUrl) {
                    authentication(userName: sonatypeUsername, password: sonatypePassword)
                }

                pom.project {
                    name project.name
                    packaging 'jar'
                    description 'Lesscss is a java wrapper for the JavaScript LESS to CSS compiler'
                    url 'https://github.com/houbie/lesscss'

                    scm {
                        url 'scm:git@github.com:houbie/lesscss-gradle-plugin.git'
                        connection 'scm:git@github.com:houbie/lesscss-gradle-plugin.git'
                        developerConnection 'scm:git@github.com:houbie/lesscss-gradle-plugin.git'
                    }

                    licenses {
                        license {
                            name 'The Apache Software License, Version 2.0'
                            url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                            distribution 'repo'
                        }
                    }

                    developers {
                        developer {
                            id 'houbie'
                            name 'Ivo Houbrechts'
                        }
                    }
                }
            }
        }
    }
}

//********* release plugin *********
release {
    versionPropertyFile = 'version.txt'
    versionPatterns = [
            // increment last digit before '-less-'
            /(\d+)-less-(.+$)/: { matcher, project -> matcher.replaceAll("${(matcher[0][1] as int) + 1}-less-${matcher[0][2]}") }
    ]
}

task updateReadme(description: 'Updates all the occurrences of the version in README.adoc') << {
    File readme = file('README.adoc')
    //replace all occurrences of x.y.z-less-a.b.c with the new release version
    def releaseVersion = "${project['release.oldVersion']}".replaceAll('-SNAPSHOT', '')
    readme.text = (readme.text =~ /\d\.\d(\.\d)?-less-\d\.\d(\.\d)?(-SNAPSHOT)?/).replaceAll("${releaseVersion}")
}

release.dependsOn clean
createReleaseTag.dependsOn uploadArchives
commitNewVersion.dependsOn updateReadme