forked from kubernetes-el/kubernetes-el
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathkubernetes-pods.el
202 lines (177 loc) · 8.27 KB
/
kubernetes-pods.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
;;; kubernetes-pods.el --- Rendering for Kubernetes pods -*- lexical-binding: t; -*-
;;; Commentary:
;;; Code:
(require 'dash)
(require 'seq)
(require 'kubernetes-ast)
(require 'kubernetes-loading-container)
(require 'kubernetes-modes)
(require 'kubernetes-props)
(require 'kubernetes-state)
(require 'kubernetes-utils)
(require 'kubernetes-yaml)
;; Components
(defconst kubernetes-pods--column-heading
["%-45s %-13s %5s %10s %6s" "Name Status Ready Restarts Age"])
(kubernetes-ast-define-component pod-view-detail (pod)
(-let* ((detail (lambda (k v)
(when v
`(key-value 12 ,k ,v))))
((&alist 'metadata (&alist 'namespace ns 'labels (&alist 'name label-name))
'status (&alist 'hostIP host-ip
'containerStatuses containers
'podIP pod-ip
'startTime start-time))
pod)
(containers (or containers (make-vector 0 '()))))
`(,(when label-name
`(section (selector nil)
(nav-prop (:selector ,label-name)
,(funcall detail "Label" (propertize label-name 'face 'kubernetes-selector)))))
,(when ns
`(section (namespace nil)
(nav-prop (:namespace-name ,ns)
(key-value 12 "Namespace" ,(propertize ns 'face 'kubernetes-namespace)))))
,(funcall detail "Host IP" host-ip)
,(funcall detail "Pod IP" pod-ip)
,(funcall detail "Started" start-time)
(header-with-count "Containers:" ,containers)
,(cons 'list (-map (-lambda ((&alist 'image image 'name name))
`((key-value 10 "Name" ,name)
(key-value 10 "Image" ,image)))
containers)))))
(kubernetes-ast-define-component pod-view-line (state pod)
(-let* ((current-time (kubernetes-state--get state 'current-time))
(marked-pods (kubernetes-state--get state 'marked-pods))
(pending-deletion (kubernetes-state--get state 'pods-pending-deletion))
((&alist 'metadata (&alist 'name name)
'status (&alist 'containerStatuses containers
'startTime start-time
'phase phase))
pod)
([(&alist 'restartCount restarts 'state pod-state)]
(or containers
(make-vector 1 (list '(restartCount . 0) '(state . '(failed . '(startedAt . nil)))))))
(start-time (or start-time (format-time-string "%Y-%m-%dT%TZ")))
(pod-state (or (alist-get 'reason (alist-get 'waiting pod-state) phase)
phase))
([fmt] kubernetes-pods--column-heading)
(list-fmt (split-string fmt))
(str
(concat
;; Name
(format (pop list-fmt) (kubernetes-utils-ellipsize name 43))
" "
;; Status
(let ((s (format (pop list-fmt) (kubernetes-utils-ellipsize pod-state 10))))
(if (equal pod-state "Running") (propertize s 'face 'kubernetes-dimmed) s))
" "
;; Ready
(format (pop list-fmt)
(let* ((n-ready (seq-count (-lambda ((it &as &alist 'ready r))
(eq r t))
containers))
(count-str (format "%s/%s" n-ready (seq-length containers))))
(if (zerop n-ready)
count-str
(propertize count-str 'face 'kubernetes-dimmed))))
" "
;; Restarts
(let ((s (format (pop list-fmt) restarts)))
(cond
((equal 0 restarts)
(propertize s 'face 'kubernetes-dimmed))
((<= kubernetes-pod-restart-warning-threshold restarts)
(propertize s 'face 'warning))
(t
s)))
" "
;; Age
(let ((start (apply #'encode-time (kubernetes-utils-parse-utc-timestamp start-time))))
(propertize (format (pop list-fmt) (kubernetes-utils-time-diff-string start current-time))
'face 'kubernetes-dimmed))))
(str (cond
((member (downcase pod-state) '("running" "containercreating" "terminated"))
str)
((member (downcase pod-state) '("runcontainererror" "crashloopbackoff"))
(propertize str 'face 'error))
(t
(propertize str 'face 'warning))))
(line `(line ,str)))
`(nav-prop (:pod-name ,name)
(copy-prop ,name
,(cond
((member name pending-deletion)
`(propertize (face kubernetes-pending-deletion) ,line))
((member name marked-pods)
`(mark-for-delete ,line))
(t
line))))))
(kubernetes-ast-define-component pod (state pod)
`(section (,(intern (kubernetes-state-resource-name pod)) t)
(heading (pod-view-line ,state ,pod))
(indent
(section (details nil)
(pod-view-detail ,pod)
(padding)))))
(defun kubernetes-pods--succeeded-job-pod-p (pod)
(unless kubernetes-pods-display-completed
(-let [(&alist 'status (&alist 'phase phase)) pod]
(equal phase "Succeeded"))))
(kubernetes-ast-define-component pods-list (state &optional hidden)
(-let (((&alist 'items pods) (kubernetes-state--get state 'pods))
([fmt labels] kubernetes-pods--column-heading))
`(section (pods-container ,hidden)
(header-with-count "Pods" ,pods)
(indent
(columnar-loading-container ,pods
,(propertize
(apply #'format fmt (split-string labels))
'face
'magit-section-heading)
,@(--map `(pod ,state ,it)
(-remove #'kubernetes-pods--succeeded-job-pod-p (append pods nil)))))
(padding))))
;; Requests and state management
(kubernetes-state-define-refreshers pods)
;; Displaying pods
(defun kubernetes-pods--read-name (state)
"Read a pod name from the user.
STATE is the current application state.
Update the pod state if it not set yet."
(-let* (((&alist 'items pods)
(or (kubernetes-state--get state 'pods)
(progn
(message "Getting pods...")
(let ((response (kubernetes-kubectl-await-on-async kubernetes-props state (-partial #'kubernetes-kubectl-get "pods"))))
(kubernetes-state-update-pods response)
response))))
(pods (append pods nil))
(names (-map #'kubernetes-state-resource-name pods)))
(completing-read "Pod: " names nil t)))
(defun kubernetes-pods-delete-marked (state)
(let ((names (kubernetes-state--get state 'marked-pods)))
(dolist (name names)
(kubernetes-state-delete-pod name)
(kubernetes-kubectl-delete "pod" name kubernetes-props state
(lambda (_)
(message "Deleting pod %s succeeded." name))
(lambda (_)
(message "Deleting pod %s failed" name)
(kubernetes-state-mark-pod name))))
(kubernetes-state-trigger-redraw)))
;; Interactive commands
;;;###autoload
(defun kubernetes-display-pod (pod-name state)
"Display information for a pod in a new window.
STATE is the current application state.
POD-NAME is the name of the pod to display."
(interactive (let ((state (kubernetes-state)))
(list (kubernetes-utils-read-pod-name state) state)))
(if-let (pod (kubernetes-state-lookup-pod pod-name state))
(select-window
(display-buffer
(kubernetes-yaml-make-buffer kubernetes-pod-buffer-name pod)))
(error "Unknown pod: %s" pod-name)))
(provide 'kubernetes-pods)
;;; kubernetes-pods.el ends here