forked from kubernetes-el/kubernetes-el
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathkubernetes-statefulsets.el
182 lines (155 loc) · 8.14 KB
/
kubernetes-statefulsets.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
;;; kubernetes-statefulsets.el --- Rendering for Kubernetes statefulsets. -*- lexical-binding: t; -*-
;;; Commentary:
;;; Code:
(require 'dash)
(require 'kubernetes-kubectl)
(require 'kubernetes-modes)
(require 'kubernetes-props)
(require 'kubernetes-state)
(require 'kubernetes-utils)
(require 'kubernetes-vars)
(require 'kubernetes-yaml)
;; Components
(defconst kubernetes-statefulsets--column-heading
["%-45s %10s %10s %10s %6s" "Name|Replicas|||Age"]
"The two empty headers are used to align statefulsets with deployments.")
(kubernetes-ast-define-component statefulset-detail (statefulset)
(-let [(&alist 'metadata (&alist 'namespace ns 'creationTimestamp time)
'spec (&alist 'selector (&alist 'matchLabels
(&alist 'name selector-name
'component component-name)
'matchExpressions match-expressions)))
statefulset]
`(,(when selector-name
`(section (selector nil)
(nav-prop (:selector ,selector-name)
(key-value 12 "Selector" ,(propertize selector-name 'face 'kubernetes-selector)))))
,(when component-name
`(section (component nil)
(nav-prop (:component ,component-name)
(key-value 12 "Component" ,(propertize component-name 'face 'kubernetes-component)))))
,(when match-expressions
`(section (expressions nil)
(heading "Match Expressions")
(indent ,(kubernetes-yaml-render match-expressions))))
(section (namespace nil)
(nav-prop (:namespace-name ,ns)
(key-value 12 "Namespace" ,(propertize ns 'face 'kubernetes-namespace))))
(key-value 12 "Created" ,time))))
(kubernetes-ast-define-component statefulset-line (state statefulset)
(-let* ((current-time (kubernetes-state--get state 'current-time))
(pending-deletion (kubernetes-state--get state 'statefulsets-pending-deletion))
(marked-statefulsets (kubernetes-state--get state 'marked-statefulsets))
((&alist 'metadata (&alist 'name name 'creationTimestamp created-time)
'spec (&alist 'replicas desired)
'status (&alist 'replicas current
'availableReplicas available
'updatedReplicas up-to-date))
statefulset)
(current (or current 0))
(desired (or desired 0))
(_available (or available 0))
(_up-to-date (or up-to-date 0))
([fmt] kubernetes-statefulsets--column-heading)
(list-fmt (split-string fmt))
(line `(line ,(concat
;; Name
(format (pop list-fmt) (kubernetes-utils-ellipsize name 43))
" "
;; Replicas (current/desired)
(let ((str (format "%s/%s" current desired))
(next (pop list-fmt)))
(cond
((zerop desired)
(format next str))
((zerop current)
(propertize (format next str) 'face 'warning))
((/= current desired)
(format next str))
(t
(propertize (format next str) 'face 'kubernetes-dimmed))))
" "
;; Up-to-date
(propertize (format (pop list-fmt) "") 'face 'warning)
" "
;; Available
(propertize (format (pop list-fmt) "") 'face 'kubernetes-dimmed)
" "
;; Age
(let ((start (apply #'encode-time (kubernetes-utils-parse-utc-timestamp created-time))))
(propertize (format (pop list-fmt) (kubernetes-utils-time-diff-string start current-time))
'face 'kubernetes-dimmed))))))
`(nav-prop (:statefulset-name ,name)
(copy-prop ,name
,(cond
((member name pending-deletion)
`(propertize (face kubernetes-pending-deletion) ,line))
((member name marked-statefulsets)
`(mark-for-delete ,line))
((zerop desired)
`(propertize (face kubernetes-dimmed) ,line))
(t
line))))))
(kubernetes-ast-define-component statefulset (state statefulset)
`(section (,(intern (kubernetes-state-resource-name statefulset)) t)
(heading (statefulset-line ,state ,statefulset))
(section (details nil)
(indent
(statefulset-detail ,statefulset)
(padding)))))
(kubernetes-ast-define-component statefulsets-list (state &optional hidden)
(-let (((state-set-p &as &alist 'items statefulsets)
(kubernetes-state--get state 'statefulsets))
([fmt labels] kubernetes-statefulsets--column-heading))
`(section (statefulsets-container ,hidden)
(header-with-count "Statefulsets" ,statefulsets)
(indent
(columnar-loading-container ,statefulsets
,(propertize
(apply #'format fmt (split-string labels "|"))
'face
'magit-section-heading)
,(--map `(statefulset ,state ,it) statefulsets)))
(padding))))
;; Requests and state management
(kubernetes-state-define-refreshers statefulsets)
(defun kubernetes-statefulsets-delete-marked (state)
(let ((names (kubernetes-state--get state 'marked-statefulsets)))
(dolist (name names)
(kubernetes-state-delete-statefulset name)
(kubernetes-kubectl-delete "statefulset" name kubernetes-props state
(lambda (_)
(message "Deleting statefulset %s succeeded." name))
(lambda (_)
(message "Deleting statefulset %s failed" name)
(kubernetes-state-mark-statefulset name))))
(kubernetes-state-trigger-redraw)))
;; Displaying statefulsets
(defun kubernetes-statefulsets--read-name (state)
"Read a statefulset name from the user.
STATE is the current application state.
Update the statefulset state if it not set yet."
(-let* (((&alist 'items statefulsets)
(or (kubernetes-state--get state 'statefulsets)
(progn
(message "Getting statefulsets...")
(let ((response (kubernetes-kubectl-await-on-async kubernetes-props state (-partial #'kubernetes-kubectl-get "statefulsets"))))
(kubernetes-state-update-statefulsets response)
response))))
(statefulsets (append statefulsets nil))
(names (-map #'kubernetes-state-resource-name statefulsets)))
(completing-read "Statefulset: " names nil t)))
;;;###autoload
(defun kubernetes-display-statefulset (statefulset-name state)
"Display information for a statefulset in a new window.
STATE is the current application state.
STATEFULSET-NAME is the name of the statefulset to display."
(interactive (let ((state (kubernetes-state)))
(list (kubernetes-statefulsets--read-name state) state)))
(if-let (statefulset (kubernetes-state-lookup-statefulset statefulset-name state))
(select-window
(display-buffer
(kubernetes-yaml-make-buffer kubernetes-display-statefulset-buffer-name statefulset)))
(error "Unknown statefulset: %s" statefulset-name)))
(provide 'kubernetes-statefulsets)
;;; kubernetes-statefulsets.el ends here