marlin/flake.nix at master · marlinprotocol/marlin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
{
  nixConfig = {
    extra-substituters = ["https://marlin.cachix.org"];
    extra-trusted-public-keys = ["marlin.cachix.org-1:Qgb4N/YJ9iX+wExt/+fbdSqQ6/GHaSvQ5xnvz5QTeD0="];
  };
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/release-25.11";
    crane = {
      url = "github:ipetkov/crane";
    };
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  outputs = {
    self,
    nixpkgs,
    crane,
    fenix,
  }: let
    systemBuilder = systemConfig: rec {
      attestation.server = import ./attestation/server {
        inherit nixpkgs systemConfig crane;
      };
      contracts.cvm-indexer = import ./contracts/cvm-indexer {
        inherit nixpkgs systemConfig crane;
      };
      enclaves.gauge = import ./enclaves/gauge {
        inherit nixpkgs systemConfig crane;
      };
      enclaves.testing.custom-attestations = import ./enclaves/testing/custom-attestations.nix {
        inherit nixpkgs systemConfig;
        nitrotpm-tools = external.nitrotpm-tools.default;
        gauge = enclaves.gauge.default;
        attestation-server-custom = attestation.server.custom.service;
      };
      enclaves.testing.green = import ./enclaves/testing/green.nix {
        inherit nixpkgs systemConfig;
        nitrotpm-tools = external.nitrotpm-tools.default;
        gauge = enclaves.gauge.default;
        keygen-x25519 = initialization.keygen.x25519.service;
        attestation-server = attestation.server.standard.service;
      };
      external.nitrotpm-tools = import ./external/nitrotpm-tools.nix {
        inherit nixpkgs systemConfig crane;
      };
      initialization.keygen = import ./initialization/keygen {
        inherit nixpkgs systemConfig crane;
      };
      kms.creator = import ./kms/creator {
        inherit nixpkgs systemConfig crane;
      };
      kms.creator-enclave = import ./kms/creator-enclave {
        inherit nixpkgs systemConfig;
        nitrotpm-tools = external.nitrotpm-tools.default;
        gauge = enclaves.gauge.default;
        keygen-secp256k1 = initialization.keygen.secp256k1.service;
        attestation-server = attestation.server.standard.service;
        kms-creator = kms.creator.service;
      };
      kms.creator-verifier = import ./kms/creator-verifier {
        inherit nixpkgs systemConfig crane;
      };
      kms.derive-server = import ./kms/derive-server {
        inherit nixpkgs systemConfig crane;
      };
      kms.root-server = import ./kms/root-server {
        inherit nixpkgs systemConfig crane;
      };
      kms.root-server-enclave = import ./kms/root-server-enclave {
        inherit nixpkgs systemConfig;
        nitrotpm-tools = external.nitrotpm-tools.default;
        keygen-secp256k1 = initialization.keygen.secp256k1.service;
        attestation-server = attestation.server.standard.service;
        kms-root-server = kms.root-server.service;
      };
      operator.limiter-ebpf = import ./operator/limiter-ebpf {
        inherit nixpkgs systemConfig;
      };
      operator.limiter-server = import ./operator/limiter-server {
        inherit nixpkgs systemConfig crane;
      };
      operator.setup-aws.limiter = import ./operator/setup-aws/limiter.nix {
        inherit nixpkgs systemConfig;
        limiter-ebpf = operator.limiter-ebpf.service;
        limiter-server = operator.limiter-server.service;
      };
    };
    serverBuilder = systemConfig: {
      operator.control-plane = import ./operator/control-plane {
        inherit nixpkgs systemConfig crane fenix;
      };
      operator.market-indexer-evm = import ./operator/market-indexer-evm {
        inherit nixpkgs systemConfig crane fenix;
      };
    };
    check = {
      system,
      packages,
    }: let
      pkgs = nixpkgs.legacyPackages.${system};

      # recursive function to find all derivations
      findDrvs = attrs:
        if pkgs.lib.isDerivation attrs
        then [attrs]
        else if builtins.isAttrs attrs
        then pkgs.lib.concatLists (pkgs.lib.mapAttrsToList (k: v: findDrvs v) attrs)
        else [];

      # get all derivations
      allDrvs = findDrvs packages.${system};

      # get paths but discard the dependency context
      # does only evaluation and prevents full build
      drvPaths = map (drv: builtins.unsafeDiscardStringContext drv.drvPath) allDrvs;
    in
      pkgs.runCommand "eval-all" {
        paths = builtins.concatStringsSep "\n" drvPaths;
      } ''
        echo "Checked evaluation for:"
        echo "$paths"
        touch $out
      '';
  in rec {
    formatter = {
      "x86_64-linux" = nixpkgs.legacyPackages."x86_64-linux".alejandra;
      "aarch64-linux" = nixpkgs.legacyPackages."aarch64-linux".alejandra;
    };
    legacyPackages = nixpkgs.lib.foldl' nixpkgs.lib.recursiveUpdate {} [
      {
        "x86_64-linux" = systemBuilder {
          system = "x86_64-linux";
          efi_arch = "x64";
          repart_arch = "x86-64";
        };
        "aarch64-linux" = systemBuilder {
          system = "aarch64-linux";
          efi_arch = "aa64";
          repart_arch = "arm64";
        };
      }
      {
        "x86_64-linux" = serverBuilder {
          system = "x86_64-linux";
          rust_target = "x86_64-unknown-linux-musl";
        };
        "aarch64-linux" = serverBuilder {
          system = "aarch64-linux";
          rust_target = "aarch64-unknown-linux-musl";
        };
      }
    ];
    # check if all derivations are valid
    # does NOT check if everything builds properly, too expensive
    # just preliminiary evaluation stage checks
    checks = {
      "x86_64-linux".eval-all = check {
        system = "x86_64-linux";
        packages = legacyPackages;
      };
      "aarch64-linux".eval-all = check {
        system = "aarch64-linux";
        packages = legacyPackages;
      };
    };
  };
}