forked from interchange/interchange
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathOrder.pm
2562 lines (2250 loc) · 61.3 KB
/
Order.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# Vend::Order - Interchange order routing routines
#
# Copyright (C) 2002-2009 Interchange Development Group
# Copyright (C) 1996-2002 Red Hat, Inc.
#
# This program was originally based on Vend 0.2 and 0.3
# Copyright 1995 by Andrew M. Wilcox <[email protected]>
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public
# License along with this program; if not, write to the Free
# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
# MA 02110-1301 USA.
package Vend::Order;
require Exporter;
$VERSION = '2.109';
@ISA = qw(Exporter);
@EXPORT = qw (
add_items
do_order
check_order
check_required
encrypt_standard_cc
mail_order
onfly
route_order
update_quantity
validate_whole_cc
);
push @EXPORT, qw (
send_mail
);
use Vend::Util;
use Vend::File;
use Vend::Interpolate;
use Vend::Session;
use Vend::Data;
use Text::ParseWords;
use Errno qw/:POSIX/;
use strict;
no warnings qw(uninitialized numeric);
use autouse 'Vend::Error' => qw/do_lockout/;
# Instance variables
my (
@Errors,
$Update,
$Fatal,
$And,
$Final,
$Success,
$Profile,
$Tables,
$Fail_page,
$Success_page,
$No_error,
$OrderCheck,
);
sub reset_order_vars {
@Errors = ();
$Update = 0;
$Fatal = 0;
undef $And;
$Final = 0;
undef $Success;
undef $Profile;
undef $Tables;
undef $Fail_page;
undef $Success_page;
undef $No_error;
# copy global order check routines
$OrderCheck = { %{$Global::OrderCheck || {} }};
# overlay any catalog order check routines
my $r;
if ($r = $Vend::Cfg->{CodeDef}{OrderCheck} and $r = $r->{Routine}) {
for (keys %$r) {
$OrderCheck->{$_} = $r->{$_};
}
}
return;
}
my %Parse = (
'&charge' => \&_charge,
'&credit_card' => \&_credit_card,
'&return' => \&_return,
'&update' => \&_update,
'&fatal' => \&_fatal,
'&and' => \&_and_check,
'&or' => \&_or_check,
'&format' => \&_format,
'&tables' => sub { $Tables = $_[1]; return 1; },
'&noerror' => sub { $No_error = $_[1] },
'&success' => sub { $Success_page = $_[1] },
'&fail' => sub { $Fail_page = $_[1] },
'&final' => \&_final,
'&calc' => sub { Vend::Interpolate::tag_calc($_[1]) },
'&perl' => sub { Vend::Interpolate::tag_perl($Tables, {}, $_[1]) },
'&test' => sub {
my($ref,$params) = @_;
$params =~ s/\s+//g;
return $params;
},
'&set' => sub {
my($ref,$params) = @_;
my ($var, $value) = split /\s+/, $params, 2;
$::Values->{$var} = $value;
return 1;
},
'&setcheck' => sub {
my($ref,$params) = @_;
my ($var, $value) = split /\s+/, $params, 2;
$::Values->{$var} = $value;
my $msg = errmsg("%s set failed.", $var);
return ($value, $var, $msg);
},
);
sub _update {
$Update = is_yes($_[1]);
return 1;
}
sub _fatal {
$Fatal = ( defined($_[1]) && ($_[1] =~ /^[yYtT1]/) ) ? 1 : 0;
return 1;
}
sub _final {
$Final = ( defined($_[1]) && ($_[1] =~ /^[yYtT1]/) ) ? 1 : 0;
return 1;
}
sub _return {
$Success = ( defined($_[1]) && ($_[1] =~ /^[yYtT1]/) ) ? 1 : 0;
}
sub _format {
my($ref, $params, $message) = @_;
no strict 'refs';
my ($routine, $var, $val) = split /\s+/, $params, 3;
my (@return);
#::logDebug("OrderCheck = $OrderCheck routine=$routine");
my $sub;
my @args;
if( $sub = $Parse{$routine}) {
@args = ($var, $val, $message);
undef $message;
}
elsif ($OrderCheck and $sub = $OrderCheck->{$routine}) {
#::logDebug("Using coderef OrderCheck = $sub");
@args = ($ref,$var,$val,$message);
undef $message;
}
elsif (defined &{"_$routine"}) {
$sub = \&{"_$routine"};
@args = ($ref,$var,$val,$message);
}
else {
return (undef, $var, errmsg("No format check routine for '%s'", $routine));
}
@return = $sub->(@args);
if(! $return[0] and $message) {
$return[2] = $message;
}
return @return;
}
sub chain_checks {
my ($or, $ref, $checks, $err, $vref) = @_;
my ($var, $val, $mess, $message);
my $result = 1;
$mess = "$checks $err";
while($mess =~ s/(\S+=\w+)[\s,]*//) {
my $check = $1;
($val, $var, $message) = do_check($check, $vref);
return undef if ! defined $var;
if($val and $or) {
1 while $mess =~ s/(\S+=\w+)[\s,]*//;
return ($val, $var, $message)
}
elsif ($val) {
$result = 1;
next;
}
else {
next if $or;
1 while $mess =~ s/(\S+=\w+)[\s,]*//;
return($val, $var, $mess);
}
}
return ($val, $var, $mess);
}
sub _and_check {
if(! length($_[1]) ) {
$And = 1;
return (1);
}
return chain_checks(0, @_);
}
sub _or_check {
if(! length($_[1]) ) {
$And = 0;
return (1);
}
return chain_checks(1, @_);
}
sub _charge {
my ($ref, $params, $message) = @_;
my $result;
my $opt;
if ($params =~ /^custom\s+/) {
$opt = {};
}
else {
$params =~ s/(\w+)\s*(.*)/$1/s;
$opt = get_option_hash($2);
}
eval {
$result = Vend::Payment::charge($params, $opt);
};
if($result) {
# do nothing, OK
}
elsif($@) {
my $msg = errmsg("Fatal error on charge operation '%s': %s", $params, $@);
::logError($msg);
$message = $msg;
}
elsif( $Vend::Session->{payment_error} ) {
# do nothing, no extended messages
$message = errmsg(
"Charge failed, reason: %s",
$Vend::Session->{payment_error},
)
if ! $message;
}
else {
$message = errmsg(
"Charge operation '%s' failed.",
($ref->{mv_cyber_mode} || $params),
)
if ! $message;
}
#::logDebug("charge result: result=$result params=$params message=$message");
return ($result, $params, $message);
}
sub _credit_card {
my($ref, $params) = @_;
my $subname;
my $sub;
my $opt;
$params =~ s/^\s+//;
$params =~ s/\s+$//;
# Make a copy if we need to keep the credit card number in memory for
# a while
# New or Compatibility to get options
if($params =~ /=/) { # New
$params =~ s/^\s*(\w+)(\s+|$)//
and $subname = $1;
$subname = 'standard' if ! $subname;
$opt = get_option_hash($params);
}
else { # Compat
$opt = {};
$opt->{keep} = 1 if $params =~ s/\s+keep//i;
if($params =~ s/\s+(.*)//) {
$opt->{accepted} = $1;
}
$subname = $params;
}
$sub = $subname eq 'standard'
? \&encrypt_standard_cc
: $Global::GlobalSub->{$subname};
if(! $sub) {
::logError("bad credit card check GlobalSub: '%s'", $subname);
return undef;
}
if($opt->{keep}) {
my (%cgi) = %$ref;
$ref = \%cgi;
}
eval {
@{$::Values}{ qw/
mv_credit_card_valid
mv_credit_card_info
mv_credit_card_exp_month
mv_credit_card_exp_year
mv_credit_card_exp_all
mv_credit_card_type
mv_credit_card_reference
mv_credit_card_error
/}
= $sub->($ref, undef, $opt );
};
if($@) {
::logError("credit card check (%s) error: %s", $subname, $@);
return undef;
}
elsif(! $::Values->{mv_credit_card_valid}) {
return (0, 'mv_credit_card_valid', $::Values->{mv_credit_card_error});
}
else {
return (1, 'mv_credit_card_valid');
}
}
sub valid_exp_date {
my ($expire) = @_;
my $month;
my $year;
if($expire) {
$expire =~ /(\d\d?)(.*)/;
$month = $1;
$year = $2;
$year =~ s/\D+//;
}
else {
$month = $CGI::values{mv_credit_card_exp_month};
$year = $CGI::values{mv_credit_card_exp_year};
}
return '' if $month !~ /^\d+$/ || $year !~ /^\d+$/;
return '' if $month <1 || $month > 12;
$year += ($year < 70) ? 2000 : 1900 if $year < 1900;
my (@now) = localtime();
$now[5] += 1900;
return '' if ($year < $now[5]) || ($year == $now[5] && $month <= $now[4]);
return 1;
}
sub validate_whole_cc {
my($mess) = join " ", @_;
$mess =~ s:[^\sA-Za-z0-9/]::g ;
my (@tok) = split /\s+/, $mess;
my($num,$expire) = ('', '', '');
for(@tok) {
next if /^[A-Za-z]/;
$num .= $_ if /^\d+$/;
$expire = $_ if m:/: ;
}
return 0 unless valid_exp_date($expire);
return luhn($num);
}
# Validate credit card routine
# by Jon Orwant, from Business::CreditCard and well-known algorithms
sub luhn {
my ($number,$min_digits) = @_;
my ($i, $sum, $weight);
$min_digits ||= 13;
$min_digits = 2 if $min_digits < 2;
$number =~ s/\D//g;
return 0 unless length($number) >= $min_digits && 0+$number;
for ($i = 0; $i < length($number) - 1; $i++) {
$weight = substr($number, -1 * ($i + 2), 1) * (2 - ($i % 2));
$sum += (($weight < 10) ? $weight : ($weight - 9));
}
return 1 if substr($number, -1) == (10 - $sum % 10) % 10;
return 0;
}
sub build_cc_info {
my ($cardinfo, $template) = @_;
if (ref $cardinfo eq 'SCALAR') {
$cardinfo = { MV_CREDIT_CARD_NUMBER => $$cardinfo };
} elsif (! ref $cardinfo) {
$cardinfo = { MV_CREDIT_CARD_NUMBER => $cardinfo };
} elsif (ref $cardinfo eq 'ARRAY') {
my $i = 0;
my %c = map { $_ => $cardinfo->[$i++] } qw(
MV_CREDIT_CARD_NUMBER
MV_CREDIT_CARD_EXP_MONTH
MV_CREDIT_CARD_EXP_YEAR
MV_CREDIT_CARD_CVV2
MV_CREDIT_CARD_TYPE
);
$cardinfo = \%c;
} elsif (ref $cardinfo ne 'HASH') {
return;
}
if(my $num = $cardinfo->{MV_CREDIT_CARD_NUMBER}) {
my @quads;
$num =~ s/\D//g;
@quads = $num =~ m{(\d\d\d\d)(\d\d\d\d)(\d\d\d\d)(\d+)};
$cardinfo->{MV_CREDIT_CARD_QUADS} = join "-", @quads;
}
$template = $template ||
$::Variable->{MV_CREDIT_CARD_INFO_TEMPLATE} ||
join("\t", qw(
{MV_CREDIT_CARD_TYPE}
{MV_CREDIT_CARD_NUMBER}
{MV_CREDIT_CARD_EXP_MONTH}/{MV_CREDIT_CARD_EXP_YEAR}
)) . "\n";
$cardinfo->{MV_CREDIT_CARD_TYPE} ||=
guess_cc_type($cardinfo->{MV_CREDIT_CARD_NUMBER});
return Vend::Interpolate::tag_attr_list($template, $cardinfo);
}
sub guess_cc_type {
my ($ccnum) = @_;
$ccnum =~ s/\D+//g;
my $country = $::Values->{$::Variable->{MV_COUNTRY_FIELD} || 'country'} || '';
if(my $subname = $Vend::Cfg->{SpecialSub}{guess_cc_type}) {
my $sub = $Vend::Cfg->{Sub}{$subname} || $Global::GlobalSub->{$subname};
my $guess;
if( $sub and $guess = $sub->($ccnum) ) {
return $guess;
}
}
# based on logic from Business::CreditCard
if ($ccnum eq '') { '' }
elsif (
$ccnum =~ /^4(?:\d{12}|\d{15})$/
)
{
return 'visa';
}
elsif (
$ccnum =~ /^5[1-5]\d{14}$/
or
( $ccnum =~ /^36\d{12}/ && $country =~ /^(US|CA)$/oi )
)
{ return 'mc' }
elsif (
$ccnum =~ /^6011\d{12}$/
or
$ccnum =~ /^65\d{14}$/o
or
( $ccnum =~ /^622\d{13}$/o && $country !~ /^CN$/i )
)
{ return 'discover' }
elsif ($ccnum =~ /^3[47]\d{10,13}$/)
{ return 'amex' }
elsif ($ccnum =~ /^3(?:6\d{12}|0[0-5]\d{11})$/)
{ return 'dinersclub' }
elsif ($ccnum =~ /^38\d{12}$/)
{ return 'carteblanche' }
elsif ($ccnum =~ /^2(?:014|149)\d{11}$/)
{ return 'enroute' }
elsif ($ccnum =~ /^(?:3\d{15}|2131\d{11}|1800\d{11})$/)
{ return 'jcb' }
elsif (
$ccnum =~ /^49(03(0[2-9]|3[5-9])|11(0[1-2]|7[4-9]|8[1-2])|36[0-9]{2})\d{10}(\d{2,3})?$/
or $ccnum =~ /^564182\d{10}(\d{2,3})?$/
or $ccnum =~ /^6(3(33[0-4][0-9])|759[0-9]{2})\d{10}(\d{2,3})?$/)
{ return 'switch' }
elsif ($ccnum =~ /^56\d{14}$/)
{ return 'bankcard' }
elsif ($ccnum =~ /^6(3(34[5-9][0-9])|767[0-9]{2})\d{10}(\d{2,3})?$/)
{ return 'solo' }
elsif ($ccnum =~ /^622\d{13}$/)
{ return 'chinaunionpay' }
else { return $::Variable->{MV_PAYMENT_OTHER_CARD} || 'other' }
}
# Takes a reference to a hash (usually %CGI::values) that contains
# the following:
#
# mv_credit_card_number The actual credit card number
# mv_credit_card_exp_all A combined expiration MM/YY
# mv_credit_card_exp_month Month only, used if _all not present
# mv_credit_card_exp_year Year only, used if _all not present
# mv_credit_card_cvv2 CVV2 verification number from back of card
# mv_credit_card_type A = Amex, D = Discover, etc. Attempts
# to guess from number if not there
# mv_credit_card_separate Causes mv_credit_card_info to contain only number, must
# then develop expiration from the above
sub encrypt_standard_cc {
my($ref, $nodelete, $opt) = @_;
my($valid, $info);
$opt = {} unless ref $opt;
my @deletes = qw /
mv_credit_card_type mv_credit_card_number
mv_credit_card_exp_year mv_credit_card_exp_month
mv_credit_card_force mv_credit_card_exp_reference
mv_credit_card_exp_all mv_credit_card_exp_separate
mv_credit_card_cvv2
/;
my $month = $ref->{mv_credit_card_exp_month} || '';
my $type = $ref->{mv_credit_card_type} || '';
my $num = $ref->{mv_credit_card_number} || '';
my $year = $ref->{mv_credit_card_exp_year} || '';
my $all = $ref->{mv_credit_card_exp_all} || '';
my $cvv2 = $ref->{mv_credit_card_cvv2} || '';
my $force = $ref->{mv_credit_card_force} || '';
my $separate = $ref->{mv_credit_card_separate} || $opt->{separate} || '';
delete @$ref{@deletes} unless ($opt->{nodelete} or $nodelete);
# remove unwanted chars from card number
$num =~ tr/0-9//cd;
# error will be pushed on this if present
my @return = (
'', # 0- Whether it is valid
'', # 1- Encrypted credit card information
'', # 2- Month
'', # 3- Year
'', # 4- Month/year
'', # 5- type
'', # 6- Reference number in form 41**1111
);
# Get the expiration
if ($all =~ m!(\d\d?)[-/](\d\d)(\d\d)?! ){
$month = $1;
$year = "$2$3";
}
elsif ($month >= 1 and $month <= 12 and $year) {
$all = "$month/$year";
}
else {
$all = '';
}
if ($all) {
$return[2] = $month;
$return[3] = $year;
$return[4] = $all;
}
else {
my $msg = errmsg("Can't figure out credit card expiration.");
$Vend::Session->{errors}{mv_credit_card_valid} = $msg;
push @return, $msg;
return @return;
}
if(! valid_exp_date($all) ) {
my $msg = errmsg("Card is expired.");
$Vend::Session->{errors}{mv_credit_card_valid} = $msg;
push @return, $msg;
return @return;
}
unless ($num) {
my $msg = errmsg("Missing credit card number");
$Vend::Session->{errors}{mv_credit_card_valid} = $msg;
push @return, $msg;
return @return;
}
$type = guess_cc_type($num) unless $type;
if ($type and $opt->{accepted} and $opt->{accepted} !~ /\b$type\b/i) {
my $msg = errmsg("Sorry, we don't accept credit card type '%s'.", $type);
$Vend::Session->{errors}{mv_credit_card_valid} = $msg;
push @return, $msg;
return @return;
}
elsif ($type) {
$return[5] = $type;
}
elsif(! $opt->{any}) {
my $msg = errmsg("Can't figure out credit card type from number.");
$Vend::Session->{errors}{mv_credit_card_valid} = $msg;
push @return, $msg;
return @return;
}
unless ($valid = luhn($num) || $force ) {
my $msg = errmsg("Credit card number fails LUHN-10 check.");
$Vend::Session->{errors}{mv_credit_card_valid} = $msg;
push @return, $msg;
return @return;
}
$return[0] = $valid;
my $check_string = $num;
$check_string =~ s/(\d\d).*(\d\d\d\d)$/$1**$2/;
my $encrypt_string = $separate ? $num :
build_cc_info( [$num, $month, $year, $cvv2, $type] );
$info = pgp_encrypt ($encrypt_string);
unless (defined $info) {
my $msg = errmsg("Credit card encryption failed: %s", $! );
$Vend::Session->{errors}{mv_credit_card_valid} = $msg;
push @return, $msg;
$return[0] = 0;
return @return;
}
$return[1] = $info;
$return[6] = $check_string;
return @return;
}
sub onfly {
my ($code, $qty, $opt) = @_;
my $item_text;
if (ref $opt) {
$item_text = $opt->{text} || '';
}
else {
$item_text = $opt;
$opt = {};
}
# return create_onfly() if $opt->{create};
my $joiner = $::Variable->{MV_ONFLY_JOINER} || '|';
my $split_fields= $::Variable->{MV_ONFLY_FIELDS} || undef;
$item_text =~ s/\s+$//;
$item_text =~ s/^\s+//;
my @parms;
my @fields;
$joiner = quotemeta $joiner;
@parms = split /$joiner|\0/, $item_text;
my ($k, $v);
my $item = {};
if(defined $split_fields) {
@fields = split /[,\s]+/, $split_fields;
@{$item}{@fields} = @parms;
}
else {
for(@parms) {
($k, $v) = split /=/, $_;
$item->{$k} = $v;
}
}
$item->{mv_price} = $item->{price}
if ! $item->{mv_price};
$item->{code} = $code if ! $item->{code};
$item->{quantity} = $qty if ! $item->{quantity};
return $item;
}
# Email the processed order. This is a legacy routine, not normally used
# any more. Order email is normally sent via Route.
sub mail_order {
my ($email, $order_no) = @_;
$email = $Vend::Cfg->{MailOrderTo} unless $email;
my($body, $ok);
my($subject);
# LEGACY
if ($::Values->{mv_order_report}) {
unless( allowed_file($::Values->{mv_order_report}) ) {
log_file_violation ($::Values->{mv_order_report}, 'mail_order');
return undef;
}
$body = readin($::Values->{mv_order_report})
}
# END LEGACY
$body = readfile($Vend::Cfg->{OrderReport})
if ! $body;
unless (defined $body) {
::logError(
q{Cannot find order report in:
OrderReport=%s
mv_order_report=%s
trying one more time. Fix this.},
$Vend::Cfg->{OrderReport},
$::Values->{mv_order_report},
);
unless( allowed_file($Vend::Cfg->{OrderReport}) ) {
log_file_violation($Vend::Cfg->{OrderReport}, 'mail_order');
return undef;
}
$body = readin($Vend::Cfg->{OrderReport});
return undef if ! $body;
}
return undef unless defined $body;
$order_no = update_order_number() unless $order_no;
$body = interpolate_html($body);
$body = pgp_encrypt($body) if $Vend::Cfg->{PGP};
track_order($order_no, $body);
$subject = $::Values->{mv_order_subject} || "ORDER %n";
if(defined $order_no) {
$subject =~ s/%n/$order_no/;
}
else { $subject =~ s/\s*%n\s*//g; }
$ok = send_mail($email, $subject, $body);
return $ok;
}
sub pgp_encrypt {
my($body, $key, $cmd) = @_;
#::logDebug("called pgp_encrypt key=$key cmd=$cmd");
$cmd = $Vend::Cfg->{EncryptProgram} unless $cmd;
$key = $Vend::Cfg->{EncryptKey} unless $key;
#::logDebug("pgp_encrypt using key=$key cmd=$cmd");
$key =~ s/,/ /g; # turn commas to spaces
$key =~ s/^\s+//; # strip leading spaces
$key =~ s/\s+$//; # strip trailing spaces
$key =~ s/\s+/ /g; # convert multiple spaces to single spaces
my @keys = split /\s/, $key;
my $keyparam;
if("\L$cmd" eq 'none') {
return ::errmsg("NEED ENCRYPTION ENABLED.");
}
elsif(! $key) {
return ::errmsg("NEED ENCRYPTION KEY POINTER.");
}
elsif($cmd =~ m{^(?:/\S+/)?\bgpg$}) {
$cmd .= " --batch --always-trust -e -a ";
$keyparam = ' -r ';
}
elsif($cmd =~ m{^(?:/\S+/)?pgpe$}) {
$cmd .= " -fat ";
$keyparam = ' -r ';
}
elsif($cmd =~ m{^(?:/\S+/)?\bpgp$}) {
$cmd .= " -fat - ";
$keyparam = ' ';
}
if($cmd =~ /[;|]/) {
die ::errmsg("Illegal character in encryption command: %s", $cmd);
}
$cmd =~ s/%%/:~PERCENT~:/g;
foreach my $thiskey (@keys) {
$thiskey =~ s/'/\\'/g;
$cmd .= "$keyparam '$thiskey' ";
}
$cmd =~ s/:~PERCENT~:/%/g;
#::logDebug("after pgp_encrypt key=$key cmd=$cmd");
my $fpre = $Vend::Cfg->{ScratchDir} . "/pgp.$Vend::Session->{id}.$$";
$cmd .= " >$fpre.out";
$cmd .= " 2>$fpre.err" unless $cmd =~ /2>/;
open(PGP, "|$cmd")
or die "Couldn't fork: $!";
print PGP $body;
close PGP;
if($?) {
my $errno = $?;
my $status = $errno;
if($status > 255) {
$status = $status >> 8;
$! = $status;
}
logError("PGP failed with error level %s, status %s: $!", $?, $status);
if($status) {
logError("PGP hard failure, command that failed: %s", $cmd);
return;
}
}
$body = readfile("$fpre.out");
unlink "$fpre.out";
unlink "$fpre.err";
return $body;
}
sub do_check {
local($_) = shift;
my $ref = \%CGI::values;
my $vref = shift || $::Values;
my $conditional_update;
my $parameter = $_;
my($var, $val, $m, $message);
if (/^&/) {
($var,$val) = split /[\s=]+/, $parameter, 2;
}
elsif ($parameter =~ /(\w+)[\s=]+(.*)/) {
my $k = $1;
my $v = $2;
$conditional_update = $Update;
$m = $v =~ s/\s+(.*)// ? $1 : undef;
($var,$val) =
('&format',
$v . ' ' . $k . ' ' . $vref->{$k}
);
}
else {
logError("Unknown order check '%s' in profile %s", $parameter, $Profile);
return undef;
}
$val =~ s/&#(\d+);/chr($1)/ge;
if ($Parse{$var}) {
## $vref added for chained checks only
($val, $var, $message) = $Parse{$var}->($ref, $val, $m, $vref);
}
else {
logError( "Unknown order check parameter in profile %s: %s=%s",
$Profile,
$var,
$val,
);
return undef;
}
#::logDebug("&Vend::Order::do_check returning val=$val, var=$var, message=$message");
if($conditional_update and $val) {
::update_values($var);
}
return ($val, $var, $message);
}
sub check_order {
my ($profiles, $vref, $individual) = @_;
reset_order_vars();
my $status;
$Vend::Session->{errors} = {}
unless ref $Vend::Session->{errors} eq 'HASH';
## Must have some security on mv_individual_profile because data
## lookups can be done via filter and/or unique
if($individual and ! delete($::Scratch->{mv_individual_profile})) {
::logError("Individual profile supplied without scratch authorization");
undef $individual;
}
#::logDebug("nextpage=$CGI::values{mv_nextpage}");
for my $profile (split /\0+/, $profiles) {
$status = check_order_each($profile, $vref, $individual);
# only do the individual checks once
undef $individual;
my $np = $CGI::values{mv_nextpage};
if ($status) {
if($Success_page) {
$np = $CGI::values{mv_nextpage} = $Success_page;
}
elsif ($CGI::values{mv_success_href}) {
$np = $CGI::values{mv_nextpage} = $CGI::values{mv_success_href};
}
my $f = $CGI::values{mv_success_form};
if($CGI::values{mv_success_zero}) {
%CGI::values = ();
$CGI::values{mv_nextpage} ||= $np;
}
if($f) {
my $r = Vend::Util::scalar_to_hash($f);
while (my ($k, $v) = each %$r) {
$CGI::values{$k} = $v;
}
}
}
else {
#::logDebug("Got to status=$status on profile=$profile");
if($Fail_page) {
$np = $CGI::values{mv_nextpage} = $Fail_page;
}
elsif ($CGI::values{mv_fail_href}) {
$np = $CGI::values{mv_nextpage} = $CGI::values{mv_fail_href};
}
my $f = $CGI::values{mv_fail_form};
if($CGI::values{mv_fail_zero}) {
%CGI::values = ();
$CGI::values{mv_nextpage} ||= $np;
}
if($f) {
my $r = Vend::Util::scalar_to_hash($f);
while (my ($k, $v) = each %$r) {
$CGI::values{$k} = $v;
}
}
}
if ($Final and ! scalar @{$Vend::Items}) {
$status = 0;
$::Values->{"mv_error_items"} =
$Vend::Session->{errors}{items} =
errmsg(
"You might want to order something! No items in cart.",
);
}
#::logDebug("FINISH checking profile $profile: Fatal=$Fatal Final=$Final Status=$status");
# first profile to fail prevents all other profiles from running
last unless $status;
}
my $errors = join "\n", @Errors;
#::logDebug("Errors after checking profile(s):\n$errors") if $errors;
$errors = '' unless defined $errors and ! $Success;
#::logDebug("status=$status nextpage=$CGI::values{mv_nextpage}");
return ($status, $Final, $errors);
}
sub check_order_each {
my ($profile, $vref, $individual) = @_;
my $params;
$Profile = $profile;
if(defined $Vend::Cfg->{OrderProfileName}->{$profile}) {
$profile = $Vend::Cfg->{OrderProfileName}->{$profile};
$params = $Vend::Cfg->{OrderProfile}->[$profile];
}
elsif($profile =~ /^\d+$/) {
$params = $Vend::Cfg->{OrderProfile}->[$profile];
}
elsif(defined $::Scratch->{$profile}) {
$params = $::Scratch->{$profile};
}
else {
::logError("Order profile %s not found", $profile);
return undef;
}
return undef unless $params;
$params = interpolate_html($params);
$params =~ s/\\\n//g;
$And = 1;
$Fatal = $Final = 0;
my($var,$val,$message);
my $status = 1;
my(@param) = split /[\r\n]+/, $params;
## Find marker for individual insertion
if($individual) {
my $mark;
my $i = -1;
for(@param) {
$i++;