add get_by_view method to Map

Author: Guest0x0

builtin/builtin.mbti

@@ -269,6 +269,7 @@ impl Map {
   from_array[K : Hash + Eq, V](Array[(K, V)]) -> Self[K, V]
   from_iter[K : Hash + Eq, V](Iter[(K, V)]) -> Self[K, V]
   get[K : Hash + Eq, V](Self[K, V], K) -> V?
+  get_by_view[K, View : Hash + Eq, Value](Self[K, Value], View, view~ : (K) -> View) -> Value?
   get_or_default[K : Hash + Eq, V](Self[K, V], K, V) -> V
   get_or_init[K : Hash + Eq, V](Self[K, V], K, () -> V) -> V
   is_empty[K, V](Self[K, V]) -> Bool

builtin/linked_hash_map.mbt

@@ -194,6 +194,35 @@ pub fn Map::get[K : Hash + Eq, V](self : Map[K, V], key : K) -> V? {
   }
 }
 
+///|
+/// Get the value associated with the view of a key.
+/// When searching the map, instead of comparing keys directly,
+/// a view of keys, obtained by the parameter `view`, is used.
+/// This is useful for e.g. querying a `Map` of `String` with `@string.View`.
+///
+/// The `view` function and the `Hash` implementation of `View` should satisfy:
+/// ```skip
+/// view(key).hash() == key.hash() 
+/// ```
+#locals(view)
+pub fn Map::get_by_view[K, View : Hash + Eq, Value](
+  self : Map[K, Value],
+  key : View,
+  view~ : (K) -> View
+) -> Value? {
+  let hash = key.hash()
+  for i = 0, idx = hash & self.capacity_mask {
+    guard self.entries[idx] is Some(entry) else { break None }
+    if entry.hash == hash && view(entry.key) == key {
+      break Some(entry.value)
+    }
+    if i > entry.psl {
+      break None
+    }
+    continue i + 1, (idx + 1) & self.capacity_mask
+  }
+}
+
 ///|
 #deprecated("Use `get` instead. `op_get` will return `V` instead of `Option[V]` in the future.")
 pub fn Map::op_get[K : Hash + Eq, V](self : Map[K, V], key : K) -> V? {

builtin/linked_hash_map_test.mbt

@@ -60,3 +60,21 @@ test "map::contains_kv" {
   }
 
 }
+
+///|
+test "map::get_by_view::string_view" {
+  let map = { "a": 1, "b": 2, "c": 3 }
+  let str = "abcd"
+  fn slice(s : String, i, j) {
+    s.charcodes(start=i, end=j)
+  }
+
+  fn view(s : String) {
+    s[:]
+  }
+
+  inspect!(map.get_by_view(slice(str, 0, 1), view~), content="Some(1)")
+  inspect!(map.get_by_view(slice(str, 1, 2), view~), content="Some(2)")
+  inspect!(map.get_by_view(slice(str, 2, 3), view~), content="Some(3)")
+  inspect!(map.get_by_view(slice(str, 3, 4), view~), content="None")
+}