How to debug no config file being generated?

[sezna]

Hi all, I'm filing this as a discussion instead of an issue because I'm pretty sure it is user error. I'm loving using the tool so far and greatly appreciate its continued maintenance.

I recently switched my channel to nixpks-unstable and nixvim main. Now, when I build my config, no init.lua or any nvim configuration is generated. My ~/.config is empty, and the output of echo stdpath("config)" points me to ~/.config/nvim which does not exist.

The end result is that my nvim instance has no configuration. I have not changed anything about the config other than my channel and the nixvim version. The issue is that I'm not sure how to begin debugging this issue -- if nixvim is not outputting a config file or a build error, I'm not sure where to start.

I've pasted my editor config below in case it helps:

{pkgs, lib, config, ...}:
  let
    nixvim = import (builtins.fetchGit {
      url = "https://github.com/nix-community/nixvim";
  });

  in {
    # begin neovim nixvim configuration
    imports = [
      nixvim.nixosModules.nixvim
    ];

    programs.nixvim = {
      enable = true;

      colorschemes.catppuccin.enable = true;
      plugins.lualine.enable = true;

      globals.mapleader = " ";

      opts = {
        updatetime = 100;
        number = true;
        tabstop = 2;
        shiftwidth = 2;
        grepprg = "rg --vimgrep";
        laststatus = 2;
        list = true;
        listchars = "tab:>-,trail:.";
        scrolloff = 10;
        shiftround = true;
        autoindent = true;
        colorcolumn = "120";
        cursorline = true;
        hlsearch = true;
        incsearch = true;
        ignorecase = true;
        smartcase = true;
        expandtab = true;
        undodir = "~/.config/nvim/.undo//";
      };

      keymaps =
      let normal = lib.mapAttrsToList(key: action: { mode = "n"; inherit action key; })
      {
        "<Space>" = "<NOP>";

        # Esc clears search results
        "<esc>" = ":noh<CR>";

        # Fix Y behavior
        Y = "Y$";

        # Back and forth between the two most recent files
        "<C-c>" = ":b#<CR>";

        # begin folke/trouble keybinds
        "<leader>xx" = "<cmd>Trouble diagnostics toggle<cr>";
        "<leader>xX" = "<cmd>Trouble symbols toggle filter.buf=0<cr>";
        "<leader>cs" = "<cmd>Trouble symbols toggle focus=false<cr>";
        "<leader>cl" = "<cmd>Trouble lsp toggle focus=false win.position=right<cr>";
        "<leader>xL" = "<cmd>Trouble loclist toggle<cr>";
        "<leader>xQ" = "<cmd>Trouble qflist toggle<cr>";
        "<leader>xe" = "<cmd>Trouble diagnostics filter.severity=vim.diagnostic.severity.ERROR<cr>";
        # end folke/trouble keybinds

        # begin LSP keybinds
        "<leader>ca" = ":RustLsp codeAction<cr>";
        # end LSP keybinds

      };

      visual = lib.mapAttrsToList(key: action: { mode = "v"; inherit action key; })
      {
      };

      insert = lib.mapAttrsToList(key: action: { mode = "i"; inherit action key; })
      {
        # jj for esc
        "jj" = "<Esc>";
      };

      in
        ( normal ++ visual ++ insert );


      plugins = {
        copilot-lua = {
          enable = true;
          filetypes.markdown = true;
          filetypes.rust = true;
          suggestion = { enabled = true; autoTrigger = true; };
        };
        # git-blame = { enable = true; };
        # cheatsheet.nvim = { enable = true; };
        # which-key = { enable = true; event = "VeryLazy"; };
        trouble = { enable = true; };
        diffview = { enable = true; };
        # TODO(alex) figure out octo keybinds
        octo = { enable = true; };
        rustaceanvim = { enable = true; };
        fzf-lua = {
          enable = true;
          keymaps = {
            "<leader>f" = {
              action = "git_files";
              options = { desc = "fzf git files"; };
            };
            "<leader>lg" = "live_grep";
          };
        };
      };
    };
    # end neovim nixvim configuration
}

[MattSturgeon]

when I build my config, no init.lua or any nvim configuration is generated. My ~/.config is empty,

This is intended. Other than the home-manager module, nixvim doesn't work by putting files in .config.

Instead, it works by "wrapping" nvim with a -u flag, that tells it to use a specific init.lua built by nixvim.

As a convenience, you can use the nixvim-print-init command that is installed by nixvim to view the content of the file. Alternatively, you can get the file path from nixvim's build.initSource and build.initFile options.

---

The end result is that my nvim instance has no configuration.

If running nvim isn't using your nixvim config, then you have a different issue.

Perhaps you are installing multiple neovims and the one that's taking priority on your PATH isn't the one built by nixvim?

Or perhaps you haven't rebooted into the newly built/activated nixos system?