Setup of volume for i2sstream

[honza540]

Hello Phil,

PLEASE, I am desperately trying to change the volume of the i2s stream. I tried to expand and combine your samples, but in the end, I failed :-(
I simplified my code to the bone and believe that the final change will be really minor (I assume like 3 lines sorting what stream moves to somewhere). Originally, I wanted to apply the FIR bandpass filtering, but that is something I gave up... I wanted to ask you if you would be so kind as to adjust my short code, please. Currently the output volume does not react to the volume setting at all.

Thank you in advance and wish you a good day.
Best regards, Jan

CODE (board = az-delivery-devkit-v4):

#include <Arduino.h>
#include "AudioTools.h"

AudioWAVServer server("XXX", "XXX");

I2SStream i2sStream;
VolumeStream volumeStream;
StreamCopy copier(volumeStream, i2sStream);

ConverterFillLeftAndRight<int16_t> filler(LeftIsEmpty); // fill both channels - or change to RightIsEmpty

// FilteredStream<int16_t, int16_t> filtered(i2sStream, channels);  // Defiles the filter as BaseConverter
// float fir_coeffs[] = { 0.0209967345, 0.0960112308, 0.1460005493, 0.0960112308, 0.0209967345};

void setupAudioTools();


void setup()
{
  Serial.begin(115200);
  Serial.print(F("starting audio tool"));
  setupAudioTools();
}

void loop()
{
  // copier.copy();
  server.copy();  
}


void setupAudioTools()
{
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Error);
  auto i2sConfig = i2sStream.defaultConfig(RX_MODE);
  i2sConfig.i2s_format = I2S_MSB_FORMAT; // if quality is bad change to I2S_LSB_FORMAT https://github.com/pschatzmann/arduino-audio-tools/issues/23
  i2sConfig.sample_rate = 22050;         // 8000; //16000; //22050;
  i2sConfig.channels = 1;
  i2sConfig.bits_per_sample = 16;
  i2sStream.begin(i2sConfig);
  Serial.println(F("I2S started"));

  // filtered.setFilter(0, new FIR<int16_t>(fir_coeffs));  //FIR - IIR

  // set initial volume
  auto volumeStreamConfig = volumeStream.defaultConfig();
  volumeStreamConfig.copyFrom(i2sConfig);
  volumeStreamConfig.allow_boost = true;
  volumeStream.begin(volumeStreamConfig);
  volumeStream.setVolume(8); // very loud

  server.begin(i2sStream, i2sConfig, &filler);
  // server.begin(volumeStream, volumeStreamConfig);
}

[pschatzmann]

Try to draw the chain and you will realize that you forgot to specify where the result of the VolumeStream should go!
Use VolumeStream volumeStream(i2sStream);

[honza540]

Thanks for a hint, I really tried :-(
I also added "new" output EncodedAudioStream, but still no success :-(

What is also strange, that despise I use allow_boost = true together with volumeStream.setVolume(2.5);
I got: [E] VolumeStream.h : 193 - Invalid volume: 2.500000
BUT from "ValumeStream.h" I can read, that actually 4 is the highest value:
if(factor > 4.0) factor = 4.0;//factor can only be >1 if allow_boost == true TODO: should we update volume_values[channel] if factor got clipped to 4.0?

Anyway, so I tried to "draw it" and is follows:

I2SStream i2sStream -> StreamCopy copier(volumeStream, i2sStream) -> VolumeStream volumeStream(finalStream) -> EncodedAudioStream finalStream -> server.begin(finalStream, &filler)

What the hell am I missing? ;-(
...and there is not even the bandpass filter added....

#include <Arduino.h>
#include "AudioTools.h"

AudioWAVServer server("ZSA", "5401010131");

I2SStream i2sStream;
EncodedAudioStream finalStream;
VolumeStream volumeStream(finalStream);
StreamCopy copier(volumeStream, i2sStream);

ConverterFillLeftAndRight<int16_t> filler(LeftIsEmpty); // fill both channels - or change to RightIsEmpty

// FilteredStream<int16_t, int16_t> filtered(i2sStream, channels);  // Defiles the filter as BaseConverter
// float fir_coeffs[] = { 0.0209967345, 0.0960112308, 0.1460005493, 0.0960112308, 0.0209967345};

void setupAudioTools();


void setup()
{
  Serial.begin(115200);
  Serial.println(F("starting audio tool"));
  setupAudioTools();
}

void loop()
{
  // copier.copy();
  server.copy();  
}


void setupAudioTools()
{
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Error);
  auto i2sStreamConfig = i2sStream.defaultConfig(RX_MODE);
  i2sStreamConfig.i2s_format = I2S_MSB_FORMAT; // if quality is bad change to I2S_LSB_FORMAT https://github.com/pschatzmann/arduino-audio-tools/issues/23
  i2sStreamConfig.sample_rate = 22050;         // 8000; //16000; //22050;
  i2sStreamConfig.channels = 1;
  i2sStreamConfig.bits_per_sample = 16;
  i2sStream.begin(i2sStreamConfig);
  Serial.println(F("I2S started"));

  // filtered.setFilter(0, new FIR<int16_t>(fir_coeffs));  //FIR - IIR

  // set initial volume
  auto volumeStreamConfig = volumeStream.defaultConfig();
  volumeStreamConfig.copyFrom(i2sStreamConfig);
  volumeStreamConfig.allow_boost = true;
  volumeStream.setVolume(2.5); // very loud
  volumeStream.begin(volumeStreamConfig);

  finalStream.begin(i2sStreamConfig);

  server.begin(finalStream, &filler);
  // server.begin(i2sStream, i2sStreamConfig, &filler);
  // server.begin(volumeStream, volumeStreamConfig);
}

[pschatzmann]

Oh No: I just noticed that you want to use the AudioWAVServer class. Your unnecessary StreamCopy was confusing me first.

Lets take this example as starting point: Which implements the following chain I2SStream -> AudioWAVServer.

AudioWAVServer is using readBytes() to get the data from I2SStream.

If you want to add a VolumeStream you need to extend the chain to I2SStream -> VolumeStream -> AudioWAVServer which would require

  VolumeStream volumeStream(i2sStream);  // volumeStream is reading data from i2sStream

and

   server.begin(volumeStream, config, &filler); // server is reading data from volumeStream

[honza540]

Hi Phil,
First, I want to thank you for "stabilising my thinking" - the code is working now. Actually, I was at this stage earlier, but I quit because the volume boost did not produce the expected volume boost... Now I can see, when I apply a volume factor 0.05 it is significantly lower volume, but when I apply anything from 1 to N, it is not boosting the output. As I understood from the code (maybe I am wrong), with the allow_boost = true the characteristic is also switched into linear mode, so the output volume coefficient should be even "stronger" than in exponential mode, right? I cannot see any more progress with values over 1.0; the final output sound is still very weak (voice from microphone INMP441 - I barely hear my voice while talking to the mic from a 50cm distance). Could that be the reason...? I do not know :-(

Could this be a bug in the library at the end? I am using lib version 1.1.0

working with lower loudness, but cannot make it really loud:

#include <Arduino.h>
#include "AudioTools.h"

AudioWAVServer server("ZSA", "5401010131");

I2SStream i2sStream;
VolumeStream volumeStream(i2sStream);


ConverterFillLeftAndRight<int16_t> filler(LeftIsEmpty);

void setupAudioTools();


void setup()
{
  Serial.begin(115200);
  Serial.println(F("starting audio tool"));
  setupAudioTools();
}

void loop()
{
  server.copy();
}


void setupAudioTools()
{
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Error);
  auto i2sStreamConfig = i2sStream.defaultConfig(RX_MODE);
  i2sStreamConfig.i2s_format = I2S_MSB_FORMAT;
  i2sStreamConfig.sample_rate = 22050;
  i2sStreamConfig.channels = 1;
  i2sStreamConfig.bits_per_sample = 16;
  i2sStream.begin(i2sStreamConfig);
  Serial.println(F("I2S started"));

  auto volumeStreamConfig = volumeStream.defaultConfig();
  volumeStreamConfig.copyFrom(i2sStreamConfig);
  volumeStreamConfig.allow_boost = true;
  volumeStream.begin(volumeStreamConfig);

  //I would like to make it very loud, but the boost is not working probbaly, just cannot make it really loud here :-(
  volumeStream.setVolume(0.5);

  Serial.println(String(volumeStream.volume()));
  server.begin(volumeStream, volumeStreamConfig, &filler);
}

[honza540]

Hi, I started using the very last library version and it works as expected. Thak you for all the hints and help. Have a great day Phil.

Kind regards, Jan