Cannot add both IPv4 and IPv6 for same host

[qdii]

Describe the Bug

It is not possible to have two entries for the same host (one in IPv4 and one in IPv6)

Expected Behavior

When writing the following entries:

host { 'foo-v4':
  ensure => 'present',
  name   => 'foo.bar.com',
  ip     => '80.1.2.3',
}
host { 'foo-v6':
  ensure => 'present',
  name   => 'foo.bar.com',
  ip     => '2a01::1',
}

I expect the following entries to be created:

foo.bar.com 80.1.2.3
foo.bar.com 2a01::1

Instead I get an error:

Cannot alias Host[foo-v6] to ["foo.bar.com"] at (file: /etc/puppetlabs/code/environments/production/.../init.pp, line: 504); resource ["Host", "foo.bar.com"] already declared…

Steps to Reproduce

See above

Environment

• Version 7.27.0
• Platform Arch Linux

[joshcooper]

This is a long standing issue with this type and provider. Internally tracked as https://perforce.atlassian.net/browse/PA-5279

[joshcooper]

It's possible to manage dual-stack entries using augeas resources (which is not supported in Windows). The augeas resource is built into puppet-agent. The key is making the resource idempotent so it only creates/modifies the entry if it's not in the desired state. The trick is to use 01 which will be appended to the list of entries, but will never appear when the tree is loaded. See https://groups.google.com/g/puppet-users/c/AuarxMGr1oI/m/v6pQtJ9XOLIJ

# cat aug.pp 
augeas { 'examplev4':
  incl    => '/etc/hosts', 
  lens    => 'Hosts.lns',
  changes => [
    "ins 01 after *[last()]",
    "set 01/ipaddr 1.1.1.1",
    "set 01/canonical host.example.com",
   ],
   onlyif => "match *[ipaddr = '1.1.1.1'] size == 0",
}

augeas { 'examplev6':
  incl    => '/etc/hosts', 
  lens    => 'Hosts.lns',
  changes => [
    "ins 02 after *[last()]",
    "set 02/ipaddr 2001:db8:3333:4444:5555:6666:7777:8888",
    "set 02/canonical host.example.com",
   ],
   onlyif => "match *[ipaddr = '2001:db8:3333:4444:5555:6666:7777:8888'] size == 0",
}
# cat /etc/hosts 
127.0.0.1   localhost localhost.localdomain localhost4 localhost4.localdomain4
::1         localhost localhost.localdomain localhost6 localhost6.localdomain6
# puppet apply aug.pp 
Notice: Compiled catalog for XXX in environment production in 0.03 seconds
Notice: /Stage[main]/Main/Augeas[examplev4]/returns: executed successfully
Notice: /Stage[main]/Main/Augeas[examplev6]/returns: executed successfully
Notice: Applied catalog in 0.03 seconds
# puppet apply aug.pp 
Notice: Compiled catalog for XXX in environment production in 0.03 seconds
Notice: Applied catalog in 0.02 seconds

Also noting that the augeasproviders module cannot manage dual stack because it only implements a new provider for the existing host type, and seems to suffer from the same issue as the default ParsedFile-based provider.