Add Nix package for PyQGIS API Documentation builder

Author: imincik

README.md

@@ -25,7 +25,7 @@ You can either:
 
 * export the PYTHONPATH yourself
 * export your QGIS build directory with ``export QGIS_BUILD_DIR=~/dev/QGIS/build``
-* or provide QGIS build directory as argument to the script: ``./build-docs.sh -qgis-build-dir ~/dev/QGIS/build``
+* or provide QGIS build directory as argument to the script: ``./scripts/build-docs.sh -qgis-build-dir ~/dev/QGIS/build``
 
 ### Testing & development
 

flake.lock

@@ -0,0 +1,93 @@
+{
+  description = "PyQGIS API Documentation";
+
+  # nixConfig = {
+  #   extra-substituters = [ "https://example.cachix.org" ];
+  #   extra-trusted-public-keys = [ "example.cachix.org-1:xxxx=" ];
+  # };
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+
+    # TODO: https://github.com/qgis/QGIS-Sysadmin-Documentation/issues/129
+    qgisLatest = {
+      url = "github:imincik/QGIS/nix-package-release-3_42";
+    };
+  };
+
+  outputs = inputs@{ self, nixpkgs, qgisLatest }:
+
+    let
+      # Flake system
+      supportedSystems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
+      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
+      nixpkgsFor = forAllSystems (system: import nixpkgs {
+        inherit system;
+        config.allowUnfree = true;
+      });
+
+    in
+    {
+      #
+      ### PACKAGES
+      #
+
+      packages = forAllSystems (system:
+        let
+          pkgs = nixpkgsFor.${system};
+
+        in
+        {
+          website-latest = pkgs.callPackage ./package.nix {
+            qgis = inputs.qgisLatest.packages.${system}.qgis;
+            qgisRepo = qgisLatest;
+          };
+        });
+
+
+      #
+      ### APPS
+      #
+
+      apps = forAllSystems (system:
+        let
+          pkgs = nixpkgsFor.${system};
+          inherit (nixpkgs) lib;
+
+          wwwLauncherLatest = pkgs.writeShellApplication {
+            name = "website";
+            runtimeInputs = [ pkgs.python3 ];
+            text = ''
+              exec ${lib.getExe pkgs.python3} \
+                -m http.server 8000 \
+                -d ${self.packages.${system}.website-latest}/
+            '';
+          };
+
+        in
+        rec {
+          website-latest = {
+            type = "app";
+            program = "${wwwLauncherLatest}/bin/website";
+          };
+          default = website-latest;
+        });
+
+
+      #
+      ### SHELLS
+      #
+
+      devShells = forAllSystems (system:
+        let
+          pkgs = nixpkgsFor.${system};
+
+        in
+        {
+          # Development environment
+          default = pkgs.mkShell {
+            buildInputs = [ ];
+          };
+        });
+    };
+}

flake.nix

@@ -0,0 +1,81 @@
+{ lib
+, stdenv
+
+, qgis
+, qgisRepo
+
+, graphviz
+, python3
+, python3Packages
+}:
+
+let
+  qgisPackage = qgis.override { withServer = true; };
+  qgisVersion =
+    let
+      v = builtins.splitVersion qgis.version;
+    in
+    builtins.elemAt v 0 + "." + builtins.elemAt v 1;
+in
+
+stdenv.mkDerivation {
+  name = "qgis-website-${qgisVersion}";
+
+  src = lib.cleanSourceWith {
+    src = ./.;
+    filter = (
+      path: type: (builtins.all (x: x != baseNameOf path) [
+        ".git"
+        ".github"
+        "flake.nix"
+        "flake.lock"
+        "package.nix"
+        "result"
+      ])
+    );
+  };
+
+  dontWrapQtApps = true;
+
+  buildInputs = with python3Packages; [
+    graphviz
+    python3
+    sphinx
+    sphinx-rtd-theme
+  ] ++ qgisPackage.passthru.unwrapped.pythonBuildInputs;
+
+  # Taken from
+  # https://github.com/qgis/pyqgis-api-docs-builder/blob/main/scripts/build-docs.sh
+  buildPhase = ''
+    # Build RST
+    mkdir -p temp
+    for module in "3d" "analysis" "core" "gui" "server"; do
+        CLASS_MAP_FILE="temp/$module/class_map.yaml"
+        mkdir -p temp/$module
+        cp ${qgisRepo}/python/$module/class_map.yaml $CLASS_MAP_FILE
+    done
+
+    export PYTHONPATH=$PYTHONPATH:${qgisPackage}/share/qgis/python
+
+    python3 ./scripts/make_api_rst.py --version ${qgisVersion}
+
+    mkdir api/${qgisVersion}/_static
+    cp -r _static/css api/${qgisVersion}/_static/css
+    cp -r _static/js api/${qgisVersion}/_static/js
+    cp _static/*.rst api/${qgisVersion}/
+
+    # Build HTML
+    sed -r "s/__QGIS_VERSION__/${qgisVersion}/g;" conf.in.py > api/${qgisVersion}/conf.py
+    sphinx-build -M html api/${qgisVersion} build/${qgisVersion} -T -j auto
+
+    # Move files around
+    rm -rf build/${qgisVersion}/doctrees
+    mv build/${qgisVersion}/html/* build/${qgisVersion}
+    rm -rf build/${qgisVersion}/html
+  '';
+
+  installPhase = ''
+    mkdir -p $out
+    cp -r build/* $out/
+  '';
+}