qjam/flake.nix at main · queue-jam/qjam · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
{
  description = "Music for the bold and free";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

  outputs =
    { self, ... }@inputs:
    let
      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];

      forEachSupportedSystem =
        f:
        inputs.nixpkgs.lib.genAttrs supportedSystems (
          system:
          f {
            pkgs = import inputs.nixpkgs { inherit system; };
          }
        );

      version = "3.13";

      concatMajorMinor =
        lib: v:
        lib.pipe v [
          lib.versions.splitVersion
          (lib.sublist 0 2)
          lib.concatStrings
        ];
    in
    {
      packages = forEachSupportedSystem (
        { pkgs }:
        let
          pythonName = "python${concatMajorMinor pkgs.lib version}";
          python = pkgs.${pythonName};

          runScript = pkgs.writeShellApplication {
            name = "run";
            runtimeInputs = [
              python
              python.pkgs.fastapi-cli
              python.pkgs.fastapi
              python.pkgs.yt-dlp
              python.pkgs.flask
              python.pkgs.pydantic
              python.pkgs.python-multipart
              pkgs.ffmpeg
            ];
            text = ''
              ROOT_DIR=$(git rev-parse --show-toplevel 2>/dev/null || echo ".")

              echo "Moving to project root: $ROOT_DIR"
              cd "$ROOT_DIR"

              exec fastapi dev backend
            '';
          };
        in
        {
          default = runScript;
        }
      );

      devShells = forEachSupportedSystem (
        { pkgs }:
        let
          pythonName = "python${concatMajorMinor pkgs.lib version}";
          python = pkgs.${pythonName};
        in
        {
          default = pkgs.mkShell {
            venvDir = ".venv";

            packages = [
              python
              python.pkgs.venvShellHook
              python.pkgs.fastapi-cli
              python.pkgs.fastapi
              python.pkgs.yt-dlp
              python.pkgs.flask
              python.pkgs.pydantic
              python.pkgs.python-multipart
              pkgs.gh
              pkgs.tmux
              pkgs.ffmpeg
              pkgs.prettier
              self.packages.${pkgs.system}.default
            ];

            postShellHook = ''
              venvVersionWarn() {
                  local venvDir=".venv"
                  if [ -d "$venvDir" ]; then
                      local venvVersion
                      venvVersion="$("$venvDir/bin/python" -c 'import platform; print(platform.python_version())')"
                      if [[ "$venvVersion" != "${python.version}" ]]; then
                          echo "Warning: Python version mismatch!"
                      fi
                  fi
              }
              venvVersionWarn
            '';
          };
        }
      );
    };
}