build.gradle

/*
 * Copyright (c) 2022 Solana Mobile Inc.
 */

plugins {
    id 'com.android.application'
    id 'org.jetbrains.kotlin.android'
    id 'androidx.navigation.safeargs'
    id 'com.google.protobuf'
}

android {
    namespace 'com.solanamobile.seedvaultimpl'
    compileSdk 34

    defaultConfig {
        applicationId "com.solanamobile.seedvaultimpl"
        minSdk 31
        targetSdk 34
        versionCode 1
        versionName "1.0"

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_11
        targetCompatibility JavaVersion.VERSION_11
    }

    kotlinOptions {
        jvmTarget = '11'
    }

    buildFeatures {
        viewBinding true
    }
}

protobuf {
    protoc {
        def archSuffix = ''
        if (osdetector.os == "osx") {
            // Workaround: there are no published protoc binaries for Apple Silicon-based macs.
            // Apply a manual architecture to the artifact to select the osx-x86_64 variant, which
            // runs fine with Rosetta.
            archSuffix = ':osx-x86_64'
        }
        artifact = "com.google.protobuf:protoc:3.23.1$archSuffix"   // Download from repositories
    }
    generateProtoTasks {
        all().each { task ->
            task.builtins {
                java {
                    option "lite"
                }
            }
        }
    }
}

dependencies {
    implementation project(path: ':seedvault')
    implementation 'androidx.activity:activity-ktx:1.9.0'
    implementation 'androidx.appcompat:appcompat:1.7.0'
    implementation 'androidx.constraintlayout:constraintlayout:2.1.4'
    implementation 'androidx.core:core-ktx:1.13.1'
    implementation 'androidx.datastore:datastore:1.1.1'
    implementation 'androidx.fragment:fragment-ktx:1.8.1'
    implementation 'androidx.lifecycle:lifecycle-runtime-ktx:2.8.2'
    implementation 'androidx.lifecycle:lifecycle-viewmodel-ktx:2.8.2'
    implementation 'androidx.navigation:navigation-fragment-ktx:2.7.7'
    implementation 'androidx.navigation:navigation-ui-ktx:2.7.7'
    implementation 'androidx.recyclerview:recyclerview:1.3.2'
    implementation 'com.google.android.material:material:1.12.0'
    implementation 'com.google.protobuf:protobuf-java:4.27.2'
    implementation "com.goterl:lazysodium-android:5.1.0@aar"
    implementation "net.java.dev.jna:jna:5.14.0@aar"
    implementation 'org.jetbrains.kotlinx:kotlinx-coroutines-android:1.8.1'
    testImplementation 'junit:junit:4.13.2'
    androidTestImplementation 'androidx.test.ext:junit:1.2.1'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.6.1'
}