ai-integrations/java/spring-ai/build.gradle at main · temporalio/ai-integrations · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
plugins {
    id 'java-library'
    id 'maven-publish'
    id 'com.diffplug.spotless' version '7.0.2'
}

description = 'Temporal Spring AI integration (Public Preview)'
def latestDependencies = providers.gradleProperty('dependencyMode').getOrElse('locked') == 'latest'
ext {
    javaRelease = 17
    temporalVersion = latestDependencies ? '1.+' : '1.40.0'
    springAiVersion = latestDependencies ? '2.+' : '2.0.1'
    springBootVersion = providers.gradleProperty('springBootVersion').getOrElse('4.0.8')
    if (latestDependencies) {
        springBootVersion = springBootVersion.tokenize('.')[0] + '.+'
    }
    latestDependencyGroups = ['io.temporal', 'org.springframework.ai', 'org.springframework.boot']
}

apply from: '../_shared/java.gradle'

dependencies {
    api platform("org.springframework.boot:spring-boot-dependencies:$springBootVersion")
    api platform("org.springframework.ai:spring-ai-bom:$springAiVersion")
    // Consumers supply the SDK, including when using its shaded artifact.
    compileOnly "io.temporal:temporal-sdk:$temporalVersion"
    compileOnly "io.temporal:temporal-spring-boot-autoconfigure:$temporalVersion"
    compileOnly 'com.google.code.findbugs:jsr305:3.0.2'
    api 'org.springframework.boot:spring-boot-autoconfigure'
    api 'org.springframework.ai:spring-ai-client-chat'
    implementation 'org.springframework.boot:spring-boot-starter'
    compileOnly 'org.springframework.ai:spring-ai-rag'
    compileOnly 'org.springframework.ai:spring-ai-mcp'
    // Classify native provider failures without requiring a provider at runtime.
    compileOnly 'org.springframework.ai:spring-ai-openai'

    testImplementation "io.temporal:temporal-sdk:$temporalVersion"
    testImplementation "io.temporal:temporal-testing:$temporalVersion"
    testImplementation "io.temporal:temporal-spring-boot-starter:$temporalVersion"
    testImplementation 'org.mockito:mockito-core:5.14.2'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.ai:spring-ai-rag'
    testImplementation 'org.springframework.ai:spring-ai-mcp'
    testImplementation('org.springframework.ai:spring-ai-starter-mcp-client') {
        // The integration's compatibility matrix supplies its own Boot starter version.
        exclude group: 'org.springframework.boot', module: 'spring-boot-starter'
    }
    testImplementation 'org.springframework.ai:spring-ai-retry'
    testImplementation 'org.springframework.ai:spring-ai-openai'
    testImplementation 'org.springframework.ai:spring-ai-anthropic'
    testRuntimeOnly 'ch.qos.logback:logback-classic'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

test {
    // Launch the local stdio MCP server with the same dependencies as the test.
    doFirst {
        systemProperty 'mcp.test.classpath', sourceSets.test.runtimeClasspath.asPath
    }
}