tkbar/justfile at main · tkr-sh/tkbar · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
set shell := ["nu", "-c"]

# Enter in a nix-shell to dev
[group: 'dev']
env:
    nix develop -c nu

# Watch
[group: 'dev']
w:
    bacon run-long

[group: 'dev']
nix-w:
    nix develop -c "bacon"

# Run
[group: 'dev']
run: css
    cargo run

[group: 'dev']
nix-run:
    nix develop -c "cargo" "run"

# Build stylesheets from SCSS
[group: 'check']
css:
    nu ./scripts/css.nu

# Check + auto-format (local convenience)
[group: 'check']
check:
    cargo check
    cargo fmt
    try { cargo nextest run }
    cargo clippy
    taplo fmt

[group: 'check']
fix: &&fmt
    cargo clippy --fix --allow-staged

[group: 'check']
fmt: &&doc
    cargo fmt
    taplo fmt ...(fd -e toml | lines | where { $in != 'docs/config.toml' })

[group: 'doc']
doc:
    cargo run --bin doc --features doc
    taplo fmt --config ./docs/taplo.toml ./docs/taplo.toml

# --- CI checks (non-destructive, --locked) ---

# Run the Dagger CI pipeline locally (needs docker or podman)
[group: 'ci']
dagger:
    cargo build --release -p tkbar-ci
    dagger run target/release/tkbar-ci

[group: 'ci']
release version:
    nu ./scripts/release.nu {{version}}

[group: 'ci']
ci-css:
    nu ./scripts/ci-css.nu

[group: 'ci']
ci-fmt:
    cargo fmt --check
    taplo fmt --check ...(fd -e toml | lines | where { $in != 'docs/config.toml' })
    taplo fmt --check --config ./docs/taplo.toml ./docs/config.toml

[group: 'ci']
ci-check:
    cargo check --locked --workspace

[group: 'ci']
ci-deny:
    cargo deny --exclude tkbar-ci check advisories bans licenses sources

[group: 'ci']
ci-machete:
    cargo machete

[group: 'ci']
ci-clippy-features:
    cargo clippy --locked --no-default-features --features config,hyprland,black,wifi,cli -- -Dwarnings
    cargo clippy --locked --no-default-features --features red -- -Dwarnings
    cargo clippy --locked --no-default-features --features config,sway,black -- -Dwarnings
    cargo clippy --locked --no-default-features --features doc,purple --bin doc -- -Dwarnings

[group: 'ci']
ci-clippy:
    cargo clippy --locked --workspace -- -Dwarnings

[group: 'ci']
ci-test:
    cargo nextest run --workspace