test for scan consistency

Signed-off-by: Sarthak Aggarwal <[email protected]>

Author: sarthakaggarwal97

tests/integration/scan-consistency-on-failover.tcl

@@ -0,0 +1,115 @@
+start_server {tags {"scan-consistency-on-failover external:skip"}} {
+
+    set fixed_seed "00112233445566778899aabbccddeeff"
+    set shared_overrides [list appendonly no save "" db-hash-seed $fixed_seed]
+
+    start_server [list overrides $shared_overrides] {
+        set primary_host [srv 0 host]
+        set primary_port [srv 0 port]
+
+        start_server [list overrides $shared_overrides] {
+            set replica_host [srv 0 host]
+            set replica_port [srv 0 port]
+
+            set primary [srv -1 client]
+            set replica [srv 0 client]
+
+            $primary flushall
+            $replica replicaof $primary_host $primary_port
+
+            wait_for_sync $replica 200 50
+
+            set n 2000
+            for {set i 0} {$i < $n} {incr i} {
+                $primary set "k:$i" x
+            }
+            for {set i 0} {$i < $n} {incr i} {
+                $primary sadd s "m:$i"
+                $primary hset h "f:$i" v
+                $primary zadd z $i "z:$i"
+            }
+
+            wait_for_condition 200 50 {
+                [$replica dbsize] == [$primary dbsize]
+            } else {
+                fail "replica did not catch up dbsize"
+            }
+
+            # ensuring both instances have finished rehashing.
+            wait_for_condition 200 50 {
+                ![string match {Hash table 1 stats} [$primary debug htstats 0]] &&
+                ![string match {Hash table 1 stats} [$replica debug htstats 0]]
+            } else {
+                fail "hash tables still rehashing"
+            }
+
+            # SCAN across failover
+            set cur 0
+            set steps 0
+            set seen {}
+
+            while {1} {
+                set res [$primary scan $cur count 100]
+                set cur [lindex $res 0]
+                set keys [lindex $res 1]
+                foreach k $keys {
+                    if {[string match "k:*" $k]} {
+                        dict set seen $k 1
+                    }
+                }
+                incr steps
+
+                # After a few pages, promote the replica
+                if {$steps == 5} {
+                    $replica replicaof no one
+                    wait_for_condition 100 50 {
+                        ([string match {*master*} [$replica info replication]])
+                    } else {
+                        fail "replica did not promote to master"
+                    }
+                    break
+                }
+            }
+
+            set resume_cur $cur
+
+            # Resume SCAN on the new primary using the SAME cursor.
+            if {$resume_cur ne "0"} {
+                set res [$replica scan $resume_cur count 100]
+                set cur [lindex $res 0]
+                set keys [lindex $res 1]
+                foreach k $keys {
+                    if {[string match "k:*" $k]} {
+                        dict set seen $k 1
+                    }
+                }
+            }
+
+            # Perform a full SCAN sweep to ensure all keys are covered.
+            set cur 0
+            set failover_steps 0
+            while {1} {
+                set res [$replica scan $cur count 100]
+                set cur [lindex $res 0]
+                set keys [lindex $res 1]
+                foreach k $keys {
+                    if {[string match "k:*" $k]} {
+                        dict set seen $k 1
+                    }
+                }
+                incr failover_steps
+                if {$cur eq "0"} break
+
+                # safety guardrail incase scan doesn't end
+                if {$failover_steps > 200} {
+                    fail "SCAN did not complete after failover"
+                }
+            }
+
+            set all_keys [$replica keys "k:*"]
+            assert_equal $n [llength $all_keys]
+            assert_equal [lsort $all_keys] [lsort [dict keys $seen]]
+
+        }
+    }
+}