initial commit

Author: wchristian

dist.ini

@@ -0,0 +1,50 @@
+name    = Array-Split
+author  = Christian Walde <[email protected]>
+license = WTFPL_2
+copyright_holder = Christian Walde
+copyright_year   = 2010
+
+[AutoVersion]
+[PkgVersion]
+[GatherDir]
+[ExecDir]
+[PruneCruft]
+[ManifestSkip]
+[AutoPrereqs]
+[MetaYAML]
+[License]
+[Readme]
+[PodWeaver]
+[ExtraTests]
+[PodCoverageTests]
+[PodSyntaxTests]
+[KwaliteeTests]
+[CompileTests]
+[PerlTidy]
+[MetaConfig]
+[MetaJSON]
+[CheckChangeLog]
+[NextRelease]
+[MakeMaker]
+[Manifest]
+[TestRelease]
+[ConfirmRelease]
+[FakeRelease]
+
+[Git::Check]
+[Git::Commit]
+[Git::Tag]
+[Git::Push]
+[Git::CommitBuild]
+
+[MetaNoIndex]
+dir = t
+dir = utils
+
+[Prereqs / TestRequires]
+Test::Simple = 0.96
+
+[MetaResources]
+repository.web  = http://github.com/wchristian/Array-Split
+repository.url  = http://github.com/wchristian/Array-Split.git
+repository.type = git

lib/Array/Split.pm

@@ -0,0 +1,63 @@
+use strict;
+use warnings;
+
+package Array::Split;
+
+# ABSTRACT: split an array into sub-arrays
+
+use Sub::Exporter::Simple qw( split_by split_into );
+use List::Util 'max';
+use POSIX 'ceil';
+
+=head1 SYNOPSIS
+
+    use Array::Split qw( split_by split_into );
+
+=head1 DESCRIPTION
+
+This module offers functions to separate all the elements of one array into multiple arrays.
+
+=head2 split_by ( $split_size, @original )
+
+Splits up the original array into sub-arrays containing the contents of the original. Each sub-array's size is the same
+or less than $split_size, with the last one usually being the one to have less if there are not enough elements in
+@original.
+
+=cut
+
+sub split_by {
+    my ( $split_size, @original ) = @_;
+
+    $split_size = ceil max( $split_size, 1 );
+
+    my @sub_arrays;
+    for my $element ( @original ) {
+        push @sub_arrays, [] if !@sub_arrays;
+        push @sub_arrays, [] if @{ $sub_arrays[-1] } >= $split_size;
+
+        push @{ $sub_arrays[-1] }, $element;
+    }
+
+    return @sub_arrays;
+}
+
+=head2 split_into ( $count, @original )
+
+Splits the given array into even-sized (as even as maths allow) sub-arrays. It tries to create as many sub-arrays as
+$count indicates, but will return less if there are not enough elements in @original.
+
+Returns a list of array references.
+
+=cut
+
+sub split_into {
+    my ( $count, @original ) = @_;
+
+    $count = max( $count, 1 );
+
+    my $size = ceil @original / $count;
+
+    return split_by( $size, @original );
+}
+
+1;

t/basic.t

@@ -0,0 +1,25 @@
+#!/usr/bin/perl
+use strict;
+use warnings;
+
+BEGIN {
+    use Cwd;
+    chdir '..' if getcwd =~ m@/t$@;
+    use lib 'lib';
+}
+
+package basic_tests;
+
+use Test::Most;
+
+use_ok( 'Array::Split', qw( split_by split_into ) );
+
+my @by_res = split_by( 2, ( 1, 2, 3, 4, 5 ) );
+is_deeply( \@by_res, [ [1, 2], [3, 4], [5] ] );
+
+my @into_res = split_into( 2, ( 1, 2, 3, 4, 5 ) );
+is_deeply( \@into_res, [ [1, 2, 3], [4, 5] ] );
+
+done_testing();
+
+exit;