std.math.sign: Narrow integer return types to possible values

This may be a breaking change for callers that depend on the return type
being identical to the input type. For example, `sign(u32) * i8 + i8`
could now overflow. Callers can add an explicit type annotation to avoid
that situation.

If Zig ever allows small integer types to coerce to floats (see #18614),
then it might make sense to always return an integer. In the meantime,
I figured it would be too annoying for users dealing with floats.

Author: jayschwa

lib/std/math.zig

@@ -1735,12 +1735,24 @@ pub const F80 = struct {
     }
 };
 
+fn Sign(T: type) type {
+    return switch (@typeInfo(T)) {
+        .int => |int| IntFittingRange(if (int.signedness == .signed) -1 else 0, 1),
+        .vector => |vec| switch (@typeInfo(vec.child)) {
+            .int => |int| @Vector(vec.len, IntFittingRange(if (int.signedness == .signed) -1 else 0, 1)),
+            else => T,
+        },
+        else => T,
+    };
+}
+
 /// Returns -1, 0, or 1.
 /// Supports integer and float types and vectors of integer and float types.
 /// Unsigned integer types will always return 0 or 1.
+/// Returned integer types are narrowed to fit the possible values.
 /// Branchless.
-pub inline fn sign(i: anytype) @TypeOf(i) {
-    const T = @TypeOf(i);
+pub inline fn sign(i: anytype) Sign(@TypeOf(i)) {
+    const T = Sign(@TypeOf(i));
     return switch (@typeInfo(T)) {
         .int, .comptime_int => @as(T, @intFromBool(i > 0)) - @as(T, @intFromBool(i < 0)),
         .float, .comptime_float => @as(T, @floatFromInt(@intFromBool(i > 0))) - @as(T, @floatFromInt(@intFromBool(i < 0))),
@@ -1751,10 +1763,10 @@ pub inline fn sign(i: anytype) @TypeOf(i) {
                     const one: T = @splat(1);
                     break :blk @select(vinfo.child, i > zero, one, zero) - @select(vinfo.child, i < zero, one, zero);
                 },
-                else => @compileError("Expected vector of ints or floats, found " ++ @typeName(T)),
+                else => @compileError("Expected a vector of ints or floats, found " ++ @typeName(@TypeOf(i))),
             }
         },
-        else => @compileError("Expected an int, float or vector of one, found " ++ @typeName(T)),
+        else => @compileError("Expected an int, float, or a vector of one, found " ++ @typeName(@TypeOf(i))),
     };
 }