feat(extract_variable,vim): add extract variable for vim

Author: alquerci

autoload/refactoring_toolbox/extract_variable/adapters/vim_language.vim

@@ -0,0 +1,17 @@
+call refactoring_toolbox#adapters#vim#begin_script()
+
+function refactoring_toolbox#extract_variable#adapters#vim_language#make()
+    return s:self
+endfunction
+
+let s:self = #{}
+
+function s:self.makeVariableUsage(name)
+    return 'l:'.a:name
+endfunction
+
+function s:self.makeAssignation(name, value)
+    return 'let l:'.a:name.' = '.a:value
+endfunction
+
+call refactoring_toolbox#adapters#vim#end_script()

autoload/refactoring_toolbox/extract_variable/main.vim

@@ -27,4 +27,13 @@ function refactoring_toolbox#extract_variable#main#extractVariableForTypescript(
     \ )
 endfunction
 
+function refactoring_toolbox#extract_variable#main#extractVariableForVim() range
+    call refactoring_toolbox#usage#increment('VimExtractVariable')
+
+    call refactoring_toolbox#extract_variable#variable_extractor#execute(
+        \ refactoring_toolbox#adapters#input#make(),
+        \ refactoring_toolbox#extract_variable#adapters#vim_language#make(),
+    \ )
+endfunction
+
 call refactoring_toolbox#adapters#vim#end_script()

bin/test

@@ -28,4 +28,4 @@ installVader ()
 
 installVader
 
-vim -esNu tests/fixtures/vimrc -c 'Vader! -x '"${1-tests/**}"
+vim -esNu tests/fixtures/vimrc -c 'Vader! -x -q '"${1-tests/**}"

ftplugin/vim/refactoring-toolbox.vim

@@ -0,0 +1,63 @@
+try
+    call refactoring_toolbox#adapters#vim#begin_ftplugin('refactoring_toolbox')
+catch /plugin_loaded/
+    finish
+endtry
+
+function s:registerMappings()
+    if s:mappingIsEnabled()
+        call s:addBufferVisualMapping(
+            \ '<LocalLeader>ev',
+            \ '<Plug>refactoring_toolbox_vim_ExtractVariable',
+            \ 'refactoring_toolbox#extract_variable#main#extractVariableForVim()'
+        \ )
+    endif
+endfunction
+
+function s:mappingIsEnabled()
+    return !exists('no_plugin_maps') && !exists('no_typescript_maps')
+endfunction
+
+function s:addBufferNormalMapping(keys, name, executeFunction)
+    if !hasmapto(a:name, 'n')
+        call s:addUniqueBufferNormalMapping(a:keys, a:name)
+    endif
+
+    call s:addUniqueScriptAndBufferNormalMapping(a:name, ':call '.a:executeFunction.'<Enter>')
+endfunction
+
+function s:addUniqueBufferNormalMapping(left, right)
+    execute 'nmap <buffer> <unique> '.a:left.' '.a:right
+
+    call refactoring_toolbox#adapters#vim#appendFileTypeUndo('nunmap <buffer> '.a:left)
+endfunction
+
+function s:addUniqueScriptAndBufferNormalMapping(left, right)
+    execute 'nnoremap <script> <buffer> <unique> '.a:left.' '.a:right
+
+    call refactoring_toolbox#adapters#vim#appendFileTypeUndo('nunmap <script> <buffer> '.a:left)
+endfunction
+
+function s:addBufferVisualMapping(keys, name, executeFunction)
+    if !hasmapto(a:name, 'v')
+        call s:addUniqueBufferVisualMapping(a:keys, a:name)
+    endif
+
+    call s:addUniqueScriptAndBufferVisualMapping(a:name, ':call '.a:executeFunction.'<Enter>')
+endfunction
+
+function s:addUniqueBufferVisualMapping(left, right)
+    execute 'vmap <buffer> <unique> '.a:left.' '.a:right
+
+    call refactoring_toolbox#adapters#vim#appendFileTypeUndo('vunmap <buffer> '.a:left)
+endfunction
+
+function s:addUniqueScriptAndBufferVisualMapping(left, right)
+    execute 'vnoremap <script> <buffer> <unique> '.a:left.' '.a:right
+
+    call refactoring_toolbox#adapters#vim#appendFileTypeUndo('vunmap <script> <buffer> '.a:left)
+endfunction
+
+call s:registerMappings()
+
+call refactoring_toolbox#adapters#vim#end_ftplugin()

tests/extract_variable/vim.vader

@@ -0,0 +1,21 @@
+Given vim:
+
+  function s:someFunction()
+
+      return 42
+  endfunction
+
+Do:
+  /42\<Enter>
+  viw
+  ;ev
+  someVariable\<Enter>
+
+Expect:
+
+  function s:someFunction()
+
+      let l:someVariable = 42
+
+      return l:someVariable
+  endfunction