Refactoring: Gino is a single shared library and has a menuconfig

.githooks/hooks/pre-commit → .githooks/pre-commit

@@ -2,8 +2,6 @@
 #
 # Pre-commit hook to run clang-format on all C/C++ files
 # before they are commited.
-#
-# To enable this hook, rename this file to "pre-commit".
 
 if git rev-parse --verify HEAD >/dev/null 2>&1
 then

CMakeLists.txt

@@ -0,0 +1,155 @@
+cmake_minimum_required(VERSION 3.13)
+
+project(gino)
+
+include(FetchContent)
+
+include(config.default.cmake)
+if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/config.cmake)
+  include(config.cmake)
+endif()
+
+if(DEFINED GINO_INSTALL_DIR)
+  get_filename_component(GINO_INSTALL_DIR ${GINO_INSTALL_DIR} ABSOLUTE)
+  set(CMAKE_INSTALL_PREFIX ${GINO_INSTALL_DIR})
+else()
+  get_filename_component(CMAKE_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX} ABSOLUTE)
+  set(GINO_INSTALL_DIR ${CMAKE_INSTALL_PREFIX})
+endif()
+
+if(NOT DEFINED GINO_BUILD_TYPE)
+  set(GINO_BUILD_TYPE "Debug")
+endif()
+
+set(CMAKE_CXX_STANDARD 17)
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+
+find_package(LLVM 14 REQUIRED CONFIG)
+
+string(ASCII 27 Esc)
+set(Purple "${Esc}[35m")
+set(Green "${Esc}[32m")
+set(Red "${Esc}[31m")
+set(ColorReset "${Esc}[m")
+
+function(gino_acquire_option OPT)
+  if(${OPT} MATCHES "ON|On|on|1")
+    set(${OPT} ON PARENT_SCOPE)
+    message(STATUS "${Purple}Option${ColorReset} ${OPT} ${Green}ON${ColorReset}")
+  elseif(${OPT} MATCHES "OFF|Off|off|0")
+    set(${OPT} OFF PARENT_SCOPE)
+    message(STATUS "${Purple}Option${ColorReset} ${OPT} ${Red}OFF${ColorReset}")
+  elseif(${OPT} MATCHES "OFF|Off|off|0")
+  else()
+    message(FATAL_ERROR "${OPT} must be either ON or OFF")
+  endif()
+endfunction()
+
+message(STATUS "${Purple}Install directory${ColorReset} is ${CMAKE_INSTALL_PREFIX}")
+
+gino_acquire_option(GINO_TOOLS)
+
+if(NOT DEFINED NOELLE_INSTALL_DIR OR (NOELLE_INSTALL_DIR STREQUAL ""))
+  message(STATUS "${Purple}NOELLE_INSTALL_DIR${ColorReset} is not defined. Noelle will be fetched from GitHub.")
+  include(FetchContent)
+  set(NOELLE_INSTALL_DIR ${CMAKE_INSTALL_PREFIX})
+  FetchContent_Declare(
+      noelle
+      GIT_REPOSITORY  "https://github.com/arcana-lab/noelle.git"
+      GIT_TAG         master
+  )
+  FetchContent_MakeAvailable(noelle)
+  FetchContent_GetProperties(noelle)
+  file(
+    GLOB_RECURSE NOELLE_CORE_DIRS LIST_DIRECTORIES true
+    "${noelle_SOURCE_DIR}/src/core/*"
+    "${noelle_SOURCE_DIR}/src/tools/*"
+  )
+  foreach(dir ${NOELLE_CORE_DIRS})
+    if(IS_DIRECTORY ${dir} AND EXISTS "${dir}/include")
+      include_directories(${dir}/include)
+    endif()
+  endforeach()
+else()
+  message(STATUS "${Purple}NOELLE_INSTALL_DIR${ColorReset} is ${NOELLE_INSTALL_DIR}")
+  include_directories(${NOELLE_INSTALL_DIR}/include)
+endif()
+
+set(GINO_CMAKE_ROOT ${CMAKE_CURRENT_SOURCE_DIR})
+set(CMAKE_BUILD_TYPE ${GINO_BUILD_TYPE})
+
+get_filename_component(CMAKE_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX} REALPATH)
+get_filename_component(GINO_CMAKE_ROOT ${GINO_CMAKE_ROOT} REALPATH)
+
+file(READ ${GINO_CMAKE_ROOT}/VERSION GINO_VERSION)
+string(STRIP ${GINO_VERSION} GINO_VERSION)
+
+configure_file(enable.in enable @ONLY)
+install(
+  FILES ${CMAKE_CURRENT_BINARY_DIR}/enable
+  DESTINATION ${GINO_CMAKE_ROOT}
+)
+
+install(
+  PROGRAMS ${GINO_CMAKE_ROOT}/.githooks/pre-commit
+  DESTINATION ${GINO_CMAKE_ROOT}/.git/hooks
+)
+
+enable_language(C CXX)
+set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
+
+find_package(LLVM 14 REQUIRED CONFIG)
+include_directories(${LLVM_INCLUDE_DIRS})
+add_definitions(${LLVM_DEFINITIONS})
+link_directories(${LLVM_LIBRARY_DIRS})
+
+message(STATUS "Found LLVM ${LLVM_PACKAGE_VERSION}")
+message(STATUS "Using LLVMConfig.cmake in: ${LLVM_DIR}")
+
+# prepare the pass to be included in the source tree
+list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_DIR}")
+include(AddLLVM)
+include(HandleLLVMOptions)
+
+include_directories(
+  ${LLVM_INCLUDE_DIRS}
+)
+
+set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/)
+set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/)
+
+add_compile_options(${GINO_CXX_FLAGS})
+
+add_definitions(
+  -D__STDC_LIMIT_MACROS
+  -D__STDC_CONSTANT_MACROS
+)
+
+add_custom_target(
+  GinoCompileCommands ALL
+  COMMAND ${CMAKE_COMMAND} -E create_symlink
+    ${CMAKE_BINARY_DIR}/compile_commands.json
+    ${GINO_CMAKE_ROOT}/compile_commands.json
+)
+
+add_custom_target(gino_libraries)
+add_custom_target(gino_tool_libraries)
+set_target_properties(gino_libraries PROPERTIES NAMES "")
+set_target_properties(gino_tool_libraries PROPERTIES NAMES "")
+
+function(gino_component_declare name)
+  add_llvm_library(${name} MODULE)
+  get_target_property(names gino_libraries NAMES)
+  list(APPEND names ${name})
+  set_target_properties(gino_libraries PROPERTIES NAMES "${names}")
+endfunction()
+
+function(gino_tool_declare name)
+  add_llvm_library(${name} MODULE)
+  get_target_property(names gino_tool_libraries NAMES)
+  list(APPEND names ${name})
+  set_target_properties(gino_tool_libraries PROPERTIES NAMES "${names}")
+endfunction()
+
+add_subdirectory(src)
+add_subdirectory(bin)

Kconfig

@@ -0,0 +1,15 @@
+config GINO_INSTALL_DIR
+  string "Installation directory for Gino"
+  default "./install"
+
+config NOELLE_INSTALL_DIR
+  string "Pre-existing installation of Noelle. If empty, Noelle will be installed anew"
+  default ""
+
+config GINO_TOOLS
+  bool "Install all the tools build on top of Gino"
+  default y
+
+config GINO_BUILD_TYPE
+  string "Set build type for Gino"
+  default "Debug"

Makefile

@@ -1,27 +1,42 @@
-all: hooks src
+BUILD_DIR ?= build
+export GENERATOR ?= Unix Makefiles
+export JOBS ?= 16
+export MAKEFLAGS += --no-print-directory
+export KCONFIG_CONFIG = .config
+export MENUCONFIG_STYLE = aquatic
 
-src:
-	cd src ; make ; 
+all: install
 
-tests: src
-	cd tests ; make ;
+install: compile
+	cmake --install $(BUILD_DIR) 
 
-hooks:
-	make -C .githooks
+compile: $(BUILD_DIR)
+	cmake --build $(BUILD_DIR) -j$(JOBS) 
+
+build:
+	cmake -S . -B $(BUILD_DIR) -G "$(GENERATOR)" \
+		-DCMAKE_INSTALL_MESSAGE=LAZY \
+		-DCMAKE_INSTALL_PREFIX=install
+
+tests: install
+	$(MAKE) -C tests
 
 format:
-	cd src ; ./scripts/format_source_code.sh
+	find ./src -regex '.*\.[c|h]pp' | xargs clang-format -i
+
+menuconfig:
+	@python3 bin/menuconfig.py
 
-clean:
-	cd src ; make $@ ; 
-	cd tests ; make $@ ;
-	find ./ -name .clangd -exec rm -rv {} +
-	find ./ -name .cache -exec rm -rv {} +
+clean: uninstall
+	rm -rf $(BUILD_DIR)
+	rm -rf .config
+	$(MAKE) -C tests clean > /dev/null
+	rm -f compile_commands.json
+	rm -f config.cmake
 
-uninstall: clean
-	cd src ; make $@ ;
-	rm -f enable ;
-	rm -rf install ;
-	if test -d .githooks ; then cd .githooks ; make clean ; fi;
+uninstall:
+	-cat $(BUILD_DIR)/install_manifest.txt | xargs rm -f
+	rm -f enable
+	rm -f .git/hooks/pre-commit
 
-.PHONY: src tests hooks format clean uninstall
+.PHONY: all build install compile tests format clean uninstall