Respect existing capitalization in defmodule completion

apps/remote_control/lib/lexical/remote_control.ex

@@ -50,6 +50,10 @@ defmodule Lexical.RemoteControl do
 
   defdelegate modules_with_prefix(prefix, predicate), to: RemoteControl.Modules, as: :with_prefix
 
+  defdelegate adjust_module_name_capitalization(name),
+    to: RemoteControl.Modules,
+    as: :adjust_name_capitalization
+
   defdelegate docs(module, opts \\ []), to: CodeIntelligence.Docs, as: :for_module
 
   defdelegate register_listener(listener_pid, message_types), to: RemoteControl.Dispatch

apps/remote_control/lib/lexical/remote_control/api.ex

@@ -93,6 +93,10 @@ defmodule Lexical.RemoteControl.Api do
     RemoteControl.call(project, RemoteControl, :modules_with_prefix, [prefix, predicate])
   end
 
+  def adjust_module_name_capitalization(%Project{} = project, name) when is_binary(name) do
+    RemoteControl.call(project, RemoteControl, :adjust_module_name_capitalization, [name])
+  end
+
   @spec docs(Project.t(), module()) :: {:ok, CodeIntelligence.Docs.t()} | {:error, any()}
   def docs(%Project{} = project, module, opts \\ []) when is_atom(module) do
     RemoteControl.call(project, RemoteControl, :docs, [module, opts])

apps/remote_control/lib/lexical/remote_control/modules.ex

@@ -197,6 +197,41 @@ defmodule Lexical.RemoteControl.Modules do
     with_prefix("Elixir." <> prefix, mfa)
   end
 
+  @doc """
+  Adjusts module name capitalization to existing modules' names in the project.
+
+  For example, when passed `Project.Http.Server`, it returns:
+  - `Project.HTTP.Server`, if there's any module named `Project.HTTP` or `Project.HTTP.*`
+  - `Project.Http.Server` otherwise
+  """
+  @spec adjust_name_capitalization(String.t()) :: String.t()
+  def adjust_name_capitalization(name) do
+    name_downcase = String.downcase(name)
+    name_split = String.split(name, ".")
+    project_modules = all_modules()
+
+    closest_name_split =
+      project_modules
+      |> Enum.map(fn {module_string, _already_loaded?} ->
+        with "Elixir." <> ms <- module_string, do: ms
+      end)
+      |> Enum.max_by(fn module_string ->
+        :binary.longest_common_prefix([String.downcase(module_string), name_downcase])
+      end)
+      |> String.split(".")
+
+    prefix =
+      closest_name_split
+      |> Enum.zip(name_split)
+      |> Enum.take_while(fn {closest_name, name} ->
+        String.downcase(closest_name) == String.downcase(name)
+      end)
+      |> Enum.map(fn {closest_name, _name} -> closest_name end)
+
+    suffix = Enum.drop(name_split, length(prefix))
+    Enum.join(prefix ++ suffix, ".")
+  end
+
   defp apply_predicate(module_arg, {invoked_module, function, args}) do
     apply(invoked_module, function, [module_arg | args])
   end

apps/remote_control/test/fixtures/project/lib/other_modules.ex

@@ -12,3 +12,6 @@ defmodule Project.Baz do
   def baz do
   end
 end
+
+defmodule Project.HTTP.Server do
+end

apps/remote_control/test/lexical/remote_control/modules_test.exs

@@ -49,4 +49,15 @@ defmodule Lexical.RemoteControl.ModulesTest do
                Modules.with_prefix("GenEvent", {Kernel, :macro_exported?, [:__using__, 1]})
     end
   end
+
+  describe "case adjustment" do
+    test "doesn't change name if no prefix exists" do
+      name = "NonExistent.Module.Foo"
+      assert name == Modules.adjust_name_capitalization(name)
+    end
+
+    test "changes name if the prefix exists" do
+      assert "GenEvent.Foo.Bar" == Modules.adjust_name_capitalization("Genevent.Foo.Bar")
+    end
+  end
 end

apps/server/lib/lexical/server/code_intelligence/completion/translations/macro.ex

@@ -36,6 +36,9 @@ defmodule Lexical.Server.CodeIntelligence.Completion.Translations.Macro do
     label = "defmodule (define a module)"
     suggestion = suggest_module_name(env.document)
 
+    suggestion =
+      Lexical.RemoteControl.Api.adjust_module_name_capitalization(env.project, suggestion)
+
     snippet = """
     defmodule ${1:#{suggestion}} do
       $0

apps/server/test/lexical/server/code_intelligence/completion/translations/macro_test.exs

@@ -299,6 +299,23 @@ defmodule Lexical.Server.CodeIntelligence.Completion.Translations.MacroTest do
              """
     end
 
+    test "defmodule requiring capitalization adjustment", %{project: project} do
+      assert {:ok, completion} =
+               project
+               |> complete("defmodule|", path: "/lib/project/http/server/helper.ex")
+               |> fetch_completion("defmodule ")
+
+      assert completion.detail
+      assert completion.label == "defmodule (define a module)"
+      assert completion.insert_text_format == :snippet
+
+      assert apply_completion(completion) == """
+             defmodule ${1:Project.HTTP.Server.Helper} do
+               $0
+             end\
+             """
+    end
+
     test "defprotocol only has a single completion", %{project: project} do
       assert {:ok, completion} =
                project