fix(#741): Added the ability to install the eoc package using flake.nix

README.md

@@ -28,6 +28,64 @@ brew tap objectionary/eoc https://github.com/objectionary/eoc
 brew install objectionary/eoc/[email protected]
 ```
 
+Or install it via [Nix flakes](https://nixos.wiki/wiki/Flakes):
+
+```bash
+nix run github:objectionary/eoc 
+```
+
+You can also include EOLANG in your own flake:
+
+```nix
+{
+  inputs = {
+    eoc.url = "github:objectionary/eolang";
+    nixpkgs.url = "github:nixos/nixpkgs/nixos-25.05";
+  };
+
+  outputs = { self, nixpkgs, eoc, ... }: {
+    nixConfigurations.<hostname> = nixpkgs.lib.nixosSystem {
+      modules = [
+        {
+          nixpkgs.config.packageOverrides = pkgs: {
+            eoc = eoc.packages.${system}.default;
+          };
+        }
+      ];
+    } 
+  };
+}
+```
+
+After that, select one of the methods for installing the package:
+
+```nix
+#configuration.nix (Global)
+{
+  environment.systemPackages = with pkgs; [
+    eoc
+  ];
+}
+```
+
+```nix
+#configuration.nix (For user)
+{
+  users.users.<your-user-name>.packages = with pkgs; [
+    eoc
+  ];
+}
+```
+
+```nix
+#home.nix (For home-manager)
+{
+  home.packages = with pkgs; [
+    eoc
+  ];
+}
+```
+
 Then, you write a simple [EO](https://www.eolang.org) program in `hello.eo` file
 in the current directory:
 

REUSE.toml

@@ -33,6 +33,7 @@ path = [
     "MANIFEST.MF",
     "README.md",
     "renovate.json",
+    "flake.lock"
 ]
 precedence = "override"
 SPDX-FileCopyrightText = "Copyright (c) 2025 Yegor Bugayenko"

flake.nix

@@ -0,0 +1,81 @@
+# SPDX-FileCopyrightText: Copyright (c) 2022-2025 Objectionary.com
+# SPDX-License-Identifier: MIT
+{
+  description = "Command-line toolkit for parsing, compiling, transpiling, optimizing, linking, dataizing, and running EOLANG programs";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.05";
+    flake-utils.url = "github:numtide/flake-utils";
+  };
+
+  outputs = { nixpkgs, flake-utils, ... }:
+    flake-utils.lib.eachDefaultSystem (system:
+      let
+        pkgs = import nixpkgs { inherit system; };
+        srcPatched = pkgs.runCommand "patched-src" {} ''
+          cp -r ${./.} $out
+          substituteInPlace $out/package.json \
+            --replace-quiet "\"node\": \"^25.0.0\"," ""
+        '';
+        lockHash = builtins.hashFile "sha512" ./package-lock.json;
+        packageJson = builtins.fromJSON (builtins.readFile ./package.json);
+        eolangBase = pkgs.buildNpmPackage {
+          pname = packageJson.name;
+          version = packageJson.version;
+          src = srcPatched;
+
+          buildInputs = [ pkgs.nodejs ];
+          dontNpmBuild = true;
+
+          installPhase = ''
+            mkdir -p $out/lib
+            cp -r . $out/lib
+            mkdir -p $out/bin
+            ln -s $out/lib/src/eoc.js $out/bin/eoc
+            chmod +x $out/bin/eoc
+          '';
+
+          npmDeps = pkgs.importNpmLock {
+            npmRoot = srcPatched;
+          };
+
+          npmConfigHook = pkgs.importNpmLock.npmConfigHook;
+
+          meta = with pkgs.lib; {
+            description = packageJson.description;
+            homepage = packageJson.homepage;
+            license = licenses.mit;
+            author = packageJson.author;
+          };
+        };
+
+        eolangWrapped = pkgs.writeShellScriptBin "eoc" ''
+          set -euo pipefail
+
+          EOC_STORE="${eolangBase}/lib"
+          EOC_STATE="$HOME/.eoc/lib"
+          EOC_HASH="${lockHash}"
+
+          mkdir -p "$EOC_STATE"
+
+          if [ ! -f "$EOC_STATE/.hash" ] || [ "$(cat $EOC_STATE/.hash)" != "$EOC_HASH" ]; then
+            rm -rf "$EOC_STATE/"
+            cp -r "$EOC_STORE/" "$EOC_STATE/"
+            chmod -R 755 "$EOC_STATE/"
+            echo "$EOC_HASH" > "$EOC_STATE/.hash"
+          fi
+
+          exec "${pkgs.nodejs}/bin/node" "$EOC_STATE/src/eoc.js" "$@"
+        '';
+
+      in {
+        packages.default = eolangWrapped;
+        meta = with pkgs.lib; {
+          description = packageJson.description;
+          homepage = packageJson.homepage;
+          license = licenses.mit;
+          author = packageJson.author;
+        };
+      }
+    );
+}