Move ECR to Bootstrap Module and Implement Core Infrastructure

.gitignore

@@ -39,3 +39,8 @@ out/
 /config.yml
 /src/main/resources/logback.xml
 docker-compose.yml
+
+### terraform ###
+.terraform/
+*.tfstate
+*.tfstate.*

terraform-bootstrap/main.tf

@@ -0,0 +1,80 @@
+terraform {
+  required_providers {
+    aws = {
+      source  = "hashicorp/aws"
+      version = "5.54.1"
+    }
+  }
+}
+
+provider "aws" {
+  region = "ap-northeast-2"
+}
+
+resource "aws_s3_bucket" "issuefy_bucket" {
+  bucket        = "issuefy-prod-terraform-state-ap-northeast-2"
+  force_destroy = false
+
+  tags = {
+    Name        = "issuefy-prod-terraform-state-ap-northeast-2"
+    Environment = "prod"
+    Owner       = "2024-iris"
+    Project     = "issuefy"
+    Service     = "infrastructure"
+  }
+}
+
+resource "aws_s3_bucket_versioning" "issuefy_bucket_versioning" {
+  bucket = aws_s3_bucket.issuefy_bucket.id
+
+  versioning_configuration {
+    status = "Enabled"
+  }
+}
+
+resource "aws_s3_bucket_lifecycle_configuration" "issuefy_bucket_lifecycle" {
+  bucket = aws_s3_bucket.issuefy_bucket.id
+
+  rule {
+    id     = "state-file-lifecycle"
+    status = "Enabled"
+
+    abort_incomplete_multipart_upload {
+      days_after_initiation = 7
+    }
+
+    noncurrent_version_expiration {
+      noncurrent_days = 90
+    }
+  }
+}
+
+resource "aws_dynamodb_table" "terraform_lock" {
+  name         = "issuefy-terraform-lock"
+  billing_mode = "PAY_PER_REQUEST"
+  hash_key     = "LockID"
+
+  attribute {
+    name = "LockID"
+    type = "S"
+  }
+
+  tags = {
+    Name        = "issuefy-terraform-lock"
+    Environment = "prod"
+    Owner       = "2024-iris"
+    Project     = "issuefy"
+    Service     = "infrastructure"
+  }
+}
+
+module "ecr" {
+  source = "../terraform/modules/ecr"
+
+  for_each = var.ecr_repositories
+
+  repository_name      = each.key
+  scan_on_push         = each.value.scan_on_push
+  image_tag_mutability = each.value.image_tag_mutability
+  tags                 = each.value.tags
+}

terraform-bootstrap/terraform.tfvars

@@ -0,0 +1,25 @@
+ecr_repositories = {
+  issuefy-was = {
+    scan_on_push         = false
+    image_tag_mutability = "MUTABLE"
+    tags = {
+      Service = "was"
+    }
+  }
+
+  issuefy-prometheus = {
+    scan_on_push         = false
+    image_tag_mutability = "MUTABLE"
+    tags = {
+      Service = "prometheus"
+    }
+  }
+
+  issuefy-web = {
+    scan_on_push         = false
+    image_tag_mutability = "MUTABLE"
+    tags = {
+      Service = "web"
+    }
+  }
+}

terraform-bootstrap/variavles.tf

@@ -0,0 +1,7 @@
+variable "ecr_repositories" {
+  type = map(object({
+    scan_on_push         = bool
+    image_tag_mutability = string
+    tags = map(string)
+  }))
+}

terraform/backend.tf

@@ -0,0 +1,9 @@
+terraform {
+  backend "s3" {
+    bucket         = "issuefy-prod-terraform-state-ap-northeast-2"
+    key            = "prod/terraform.tfstate"
+    region         = "ap-northeast-2"
+    encrypt        = true
+    dynamodb_table = "issuefy-terraform-lock"
+  }
+}